Przykład użycia kodu XML w programie ActionScript: ładowanie danych RSS z Internetu

Klasa RSSParser zawiera metodę xmlLoaded(), która konwertuje wejściowe dane RSS, przechowywane w zmiennej rssXML, na ciąg zawierający wynik w formacie HTML, rssOutput.

W pobliżu początku metody wybierana jest domyślna przestrzeń nazw XML, o ile źródłowe dane RSS wskazują domyślną przestrzeń nazw:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

Następne wiersze zawierają pętlę analizującą wszystkie właściwości podrzędne item w danych źródłowych XML:

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

Pierwsze trzy wiersze przypisują zmiennym wartości reprezentujące tytuł, opis i łącze z właściwości item danych XML. Następny wiersz zawiera wywołanie metody buildItemHTML() w celu pobrania danych HTML w postaci obiektu XMLList, z parametrami w postaci trzech nowych zmiennych typu String.

Dane HTML (obiekt XMLList) mają następującą postać:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

W pierwszym wierszu metody anulowany jest wybór domyślnej przestrzeni nazw xml:

default xml namespace = new Namespace();

Dyrektywa default xml namespace ma zasięg bloku funkcyjnego. Oznacza to, że zasięgiem tej deklaracji jest metoda buildItemHTML().

W następnych wierszach obiekt XMLList jest konstruowany na podstawie argumentów typu String przekazanych do funkcji:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Obiekt XMLList reprezentuje ciąg znaków odpowiedni do wyświetlania w polu tekstowym HTML w środowisku ActionScript.

Metoda xmlLoaded() pobiera wartość zwracaną przez metodę buildItemHTML() i konwertuje ją na ciąg znaków:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

Metoda xmlLoaded() przypisuje wartość zmiennej rssTitle typu String na podstawie informacji zawartych w źródłowych danych RSS (XML):

rssTitle = rssXML.channel.title.toString();

Na koniec metoda xmlLoaded() generuje zdarzenie, powiadamiając w ten sposób aplikację, że dane zostały przeanalizowane i są dostępne:

            dataWritten = new Event("dataWritten", true);