Składanie i transformowanie obiektów XML

Flash Player 9 i nowsze wersje, Adobe AIR 1.0 i nowsze wersje

Metody prependChild() oraz appendChild() umożliwiają dodanie właściwości odpowiednio na początku lub na końcu listy właściwości obiektu XML, co ilustruje poniższy przykład:

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Metody insertChildBefore() i insertChildAfter() umożliwiają dodanie właściwości odpowiednio przed lub po określonej właściwości:

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Poniższy przykład ilustruje możliwość użycia nawiasów sześciennych ( { i } ) do przekazywania danych przez odwołanie (z innych zmiennych) podczas konstruowania obiektów XML:

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Do obiektu XML można przypisywać właściwości i atrybuty za pomocą operatora =, co przedstawiono poniżej:

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Obiektowi XML o nazwie x zostaną przypisane dane:

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Operatory + i += umożliwiają konkatenację obiektów XMLList:

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Powyższy kod przypisuje obiektowi XMLList o nazwie xList następujące dane:

<a>test1</a> 
<b>test2</b> 
<c>test3</c>