Obiekty udostępnione

Obiekty współużytkowane pod względem działania przypominają pliki cookie przeglądarki. Klasa SharedObject umożliwia zapisywanie danych na lokalnym dysku twardym użytkownika i odwoływanie się do tych danych w tej samej sesji lub w późniejszych sesjach. Aplikacje mają dostęp wyłącznie do swoich własnych danych w obiektach SharedObject i tylko wtedy, gdy działają w tej samej domenie. Dane nie są przesyłane na serwer i nie są dostępne dla innych aplikacji działających w innych domenach, mogą być jednak udostępniane aplikacjom z tej samej domeny.

Aby utworzyć obiekt SharedObject , należy użyć metody SharedObject.getLocal() , której składnia jest następująca:

SharedObject.getLocal("objectName" [, pathname]): SharedObject

W poniższym przykładzie tworzony jest obiekt współużytkowany o nazwie mySO:

public var mySO:SharedObject; 
mySO = SharedObject.getLocal("preferences");

Powoduje to utworzenie na komputerze klienta pliku o nazwie preferences.sol.

Określenie lokalny oznacza położenie obiektu współużytkowanego. W tym przypadku odtwarzacz Adobe® Flash® Player zapisze plik obiektu SharedObject lokalnie w katalogu głównym użytkownika.

Gdy tworzony jest obiekt współużytkowany, program Flash Player tworzy nowy katalog dla aplikacji i domeny wewnątrz obszaru izolowanego. Tworzy również plik *.sol, w którym przechowywane są dane obiektu SharedObject. Domyślne położenie tego pliku to podkatalog w katalogu głównym użytkownika. W poniższej tabeli przedstawiono domyślne położenia tego katalogu:

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects

c:/Users/username/AppData/Roaming/Macromedia/Flash Player/#SharedObjects

/Users/username/Library/Preferences/Macromedia/Flash Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

/home/username/.macromedia/Flash_Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

Poniżej katalogu #SharedObjects znajduje się katalog o losowej nazwie. Poniżej znajduje się katalog o nazwie zgodnej z nazwą hosta, następnie ścieżka do aplikacji, a na końcu plik *.sol.

Na przykład, jeśli w systemie Windows XP wywołano aplikację o nazwie MyApp.swf na hoście lokalnym w podkatalogu o nazwie /sos, program Flash Player zapisze plik *.sol w następującym położeniu:

c:/Documents and Settings/fred/Application Data/Macromedia/Flash Player/#SharedObjects/KROKWXRK/#localhost/sos/MyApp.swf/data.sol

Domyślnie program Flash może zapisywać lokalnie trwałe obiekty SharedObject o wielkości maksymalnie 100 KB na jedną domenę. Użytkownik może skonfigurować tę wartość. Gdy aplikacja próbuje zapisać w obiekcie współużytkowanym dane, które spowodowałyby przekroczenie limitu 100 KB, w programie Flash Player wyświetlane jest okno dialogowe, w którym użytkownik może zezwolić na powiększenie magazynu lokalnego dla domeny, która tego zażądała, lub odmówić powiększenia magazynu lokalnego.

Po utworzeniu lokalnego lub zdalnego obiektu SharedObject za pomocą metody getLocal() lub getRemote() dostępny jest opcjonalny parametr o nazwie secure , który określa, czy dostęp do obiektu współużytkowanego jest ograniczony do plików SWF, które są wprowadzane przez połączenie HTTPS. Jeśli ten parametr ma wartość true , a plik SWF został wprowadzony przez HTTPS, wówczas program Flash Player tworzy nowy obiekt współużytkowany lub pobiera odwołanie do istniejącego bezpiecznego obiektu współużytkowanego. Odczytywać z lub zapisywać do tego bezpiecznego obiektu udostępnionego mogą tylko pliki SWF dostarczone za pomocą protokołu HTTPS, które wywołują metodę SharedObject.getLocal() z parametrem secure ustawionym na true . Jeśli dla tego parametru ustawiona jest wartość false , a plik SWF został dostarczony za pomocą HTTPS, program Flash Player tworzy nowy obiekt współużytkowany lub pobiera odwołanie do istniejącego obiektu współużytkowanego.

Ten obiekt współużytkowany może być odczytywany/zapisywany przez pliki SWF dostarczone przez połączenia inne niż HTTPS. Jeśli plik SWF został dostarczony przez połączenie inne niż HTTPS, a użytkownik podejmie próbę ustawienia dla tego parametru wartości true , wówczas utworzenie nowego obiektu współużytkowanego (lub dostęp do poprzednio utworzonego bezpiecznego obiektu współużytkowanego) nie powiedzie się, wystąpi błąd, a dla obiektu współużytkowanego zostanie ustawiona wartość null . Jeśli użytkownik podejmie próbę uruchomienia poniższego urywka z połączenia innego niż HTTPS, metoda SharedObject.getLocal() zwróci błąd:

try 
{ 
    var so:SharedObject = SharedObject.getLocal("contactManager", null, true); 
} 
catch (error:Error) 
{ 
    trace("Unable to create SharedObject."); 
}

Niezależnie od wartości tego parametru tworzone obiekty udostępnione są wliczane do całkowitej ilości miejsca na dysku dostępnej dla domeny.

Wartości są zapisywane w obiektach współużytkowanych we właściwości data . Dla każdej wartości można wykonać pętlę w instancji obiektu współużytkowanego, korzystając z pętli for..in , jak w poniższym przykładzie:

var so:SharedObject = SharedObject.getLocal("test"); 
so.data.hello = "world"; 
so.data.foo = "bar"; 
so.data.timezone = new Date().timezoneOffset; 
for (var i:String in so.data) 
{ 
    trace(i + ":\t" + so.data[i]); 
}

Aby zlikwidować obiekt SharedObject na kliencie, należy użyć metody SharedObject.clear() . Nie powoduje to usunięcia katalogów w domyślnej ścieżce obiektów współużytkowanych aplikacji.

Poniższy przykład ilustruje usuwanie pliku obiektu SharedObject z klienta:

public function destroySharedObject():void { 
    mySO.clear(); 
}

Poniższy przykład ilustruje sposób zapisywania prostych obiektów, takich jak obiekt Date, w obiekcie SharedObject bez konieczności ręcznej serializacji i deserializacji tych obiektów.

Działanie poniższego przykładu rozpoczyna się od powitania użytkownika jako osoby po raz pierwszy korzystającej z aplikacji. Po kliknięciu przycisku Log Out aplikacja zapisuje bieżącą datę w obiekcie współużytkowanym. Po następnym uruchomieniu aplikacji lub odświeżeniu strony aplikacja wita użytkownika informacją o tym, kiedy ostatnio się wylogował.

Aby zobaczyć aplikację w działaniu, należy ją uruchomić, kliknąć przycisk Log Out, a następnie odświeżyć stronę. Aplikacja wyświetli datę i godzinę kliknięcia przycisku Log Out podczas ostatniej wizyty. Zapisane informacje można w dowolnej chwili usunąć, klikając przycisk Delete LSO.

<?xml version="1.0"?> 
<!-- lsos/WelcomeMessage.mxml --> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()"> 
  <mx:Script><![CDATA[ 
  public var mySO:SharedObject; 
  [Bindable] 
  public var welcomeMessage:String; 
 
  public function initApp():void { 
     mySO = SharedObject.getLocal("mydata"); 
     if (mySO.data.visitDate==null) { 
        welcomeMessage = "Hello first-timer!" 
     } else { 
        welcomeMessage = "Welcome back. You last visited on " + 
           getVisitDate(); 
     } 
  } 
 
  private function getVisitDate():Date { 
     return mySO.data.visitDate; 
  } 
 
  private function storeDate():void { 
     mySO.data.visitDate = new Date(); 
     mySO.flush(); 
  } 
  
  private function deleteLSO():void { 
     // Deletes the SharedObject from the client machine. 
     // Next time they log in, they will be a 'first-timer'. 
     mySO.clear(); 
  } 
  
  ]]></mx:Script> 
  <mx:Label id="label1" text="{welcomeMessage}"/> 
  <mx:Button label="Log Out" click="storeDate()"/> 
  <mx:Button label="Delete LSO" click="deleteLSO()"/> 
</mx:Application>