Pisanie metod wywołania zwrotnego do obsługi metadanych i punktów sygnalizacji

Przypisując właściwości client klasę Object lub podklasę klasy NetStream, można przekierować wywołania zwrotne metod onMetaData i onCuePoint lub całkowicie zignorować te wywołania. Poniższy przykład ilustruje użycie pustego obiektu Object w celu zignorowania wywołań zwrotnych bez konieczności wykrywania zdarzenia asyncError :

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var customClient:Object = new Object(); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = customClient; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Jeśli chcemy wykrywać wywołania zwrotne metody onMetaData lub onCuePoint , musimy zdefiniować te metody, co ilustruje poniższy urywek kodu:

var customClient:Object = new Object(); 
customClient.onMetaData = metaDataHandler; 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
}

Powyższy kod wykrywa wywołanie zwrotne metody onMetaData i wywołuje metodę metaDataHandler() , która wyświetla ciąg znaków. Gdyby środowisko wykonawcze Flash napotkało punkt synchronizacji, nie zostałyby zgłoszone żadne błędy, mimo że nie zdefiniowano metody wywołania zwrotnego onCuePoint .

Poniższy kod przypisuje właściwości client obiektu NetStream klasę niestandardową, CustomClient, w której są zdefiniowane metody obsługi wywołań zwrotnych

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = new CustomClient(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Klasa CustomClient jest zdefiniowana w następujący sposób:

package 
{ 
    public class CustomClient 
    { 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
    } 
}

W klasie CustomClient zdefiniowana jest metoda obsługi wywołania zwrotnego onMetaData . W razie napotkania punktu sygnalizacji i wywołania metody obsługi wywołania zwrotnego onCuePoint zostałoby wygenerowane zdarzenie asyncError ( AsyncErrorEvent.ASYNC_ERROR ) z informacją „flash.net.NetStream was unable to invoke callback onCuePoint” (flash.net.NetStream nie mógł wywołać funkcji wywołania zwrotnego onCuePoint). Aby zapobiec wystąpieniu tego błędu, należy zdefiniować metodę wywołania zwrotnego onCuePoint we własnej klasie CustomClient lub zdefiniować funkcję obsługi zdarzenia asyncError .

Poniższy kod tworzy instancję klasy CustomNetStream zdefiniowanej we fragmencie kodu zamieszczonym poniżej.

var ns:CustomNetStream = new CustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

W poniższym fragmencie kodu zdefiniowano klasę CustomNetStream, która rozszerza klasę NetStream, tworzy niezbędny obiekt NetConnection i obsługuje wywołania zwrotne metod onMetaData i onCuePoint :

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function CustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        public function onCuePoint(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

W celu zmiany nazw metod onMetaData() i onCuePoint() w klasie CustomNetStream można byłoby użyć poniższego kodu:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public var onMetaData:Function; 
        public var onCuePoint:Function; 
        public function CustomNetStream() 
        { 
            onMetaData = metaDataHandler; 
            onCuePoint = cuePointHandler; 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        private function metaDataHandler(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        private function cuePointHandler(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

Możliwe jest rozszerzenie klasy NetStream i utworzenie podklasy dynamicznej, tak aby możliwe było dynamiczne dodawanie metod wywołania zwrotnego onCuePoint i onMetaData . Ilustruje to poniższy fragment kodu:

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Klasa DynamicCustomNetStream jest zdefiniowana w następujący sposób:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public dynamic class DynamicCustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function DynamicCustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
    } 
}

Nawet jeśli metody wywołania zwrotnego onMetaData i onCuePoint nie zostaną zdefiniowane, błędy nie będą zgłaszane, ponieważ klasa DynamicCustomNetStream jest dynamiczna. W celu zdefiniowania metod do obsługi wywołań zwrotnych onMetaData i onCuePoint można skorzystać z poniższego kodu:

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.onMetaData = metaDataHandler; 
ns.onCuePoint = cuePointHandler; 
ns.play("http://www.helpexamples.com/flash/video/cuepoints.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid); 
 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function cuePointHandler(infoObject:Object):void 
{ 
    trace("cue point"); 
}

Przypisanie właściwości client wartości this powoduje, że aplikacja poszukuje metod onMetaData() i onCuePoint() w bieżącym zasięgu. Ilustruje to poniższy przykład:

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = this; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Wywołania zwrotne onMetaData lub onCuePoint w sytuacji, gdy nie istnieją metody obsługi tych wywołań, nie powodują generowania błędów. Aby obsługiwać te wywołania zwrotne, należy utworzyć w kodzie metody onMetaData() i onCuePoint() , co ilustruje poniższy urywek kodu:

function onMetaData(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function onCuePoint(infoObject:Object):void 
{ 
    trace("cue point"); 
}