Podstawowe informacje o pracy w sieci i komunikacji

Obiektu NetworkInfo można używać do wykrywania sprzętowych i programowych interfejsów sieciowych dostępnych dla aplikacji. NetworkInfo jest obiektem typu singleton; nie trzeba go jawnie tworzyć. Dostęp do jedynego istniejącego obiektu NetworkInfo uzyskuje się za pośrednictwem statycznej właściwości klasy, networkInfo. Obiekt NetworkInfo wywołuje również zdarzenie networkChange, gdy zajdzie zmiana w jednym z dostępnych interfejsów.

Aby uzyskać listę obiektów NetworkInterface, należy wywołać metodę findInterfaces(). Każdy obiekt NetworkInterface na liście opisuje jeden z dostępnych interfejsów. Obiekt NetworkInterface zawiera takie informacje, jak adres IP, adres sprzętowy, rozmiar maksymalnej jednostki transmisji (MTU) i status aktywności interfejsu.

Poniższy przykładowy kod wyświetla właściwości NetworkInterface każdego z interfejsów komputera klienckiego:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Aby znaleźć więcej informacji na ten temat, zobacz:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

Aplikacja AIR może działać w środowiskach, w których stan połączeń sieciowych będzie zmienny lub niestabilny. Aby ułatwić zarządzanie połączeniami z zasobami sieciowymi w ramach aplikacji, środowisko AIR wysyła zdarzenie zmiany stanu sieci za każdym razem, gdy połączenie sieciowe stanie się dostępne lub niedostępne. Zarówno obiekt NetworkInfo, jak i obiekt NativeApplication aplikacji wywołują zdarzenie networkChange. Aby zareagować na to zdarzenie, należy dodać detektor:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Oraz zdefiniować funkcję obsługi zdarzenia:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

Zdarzenie networkChange nie oznacza każdej zmiany w aktywności sieci, a jedynie zmianę stanu jednego z połączeń sieciowych. Środowisko AIR nie próbuje interpretować znaczenia zmiany stanu połączenia sieciowego. Komputer pracujący w sieci może mieć wiele połączeń rzeczywistych i wirtualnych, a zatem utrata połączenia nie musi być równoznaczna z utratą dostępu do zasobu. Z drugiej strony, nowe połączenia nie gwarantują lepszej dostępności zasobu. Niekiedy nowe połączenie może nawet zablokować dostęp do zasobów, które były wcześniej dostępne (na przykład w wypadku połączenia z siecią VPN).

Co do zasady, jedynym sposobem sprawdzenia, czy aplikacja może połączyć się z zasobem zdalnym, jest podjęcie próby takiego połączenia. Architektura monitorowania usług udostępnia oparty na zdarzeniach mechanizm reagowania na zmiany stanu połączeń sieciowych z konkretnym hostem.

Klasa DNSResolver umożliwia wyszukiwanie rekordów zasobów DNS. Rekordy DNS zawierają takie informacje, jak adres IP przypisany do nazwy domeny oraz nazwa domeny przypisana do adresu IP. Istnieje możliwość wyszukiwania następujących typów rekordów zasobów DNS:

• ARecord — adres IPv4 hosta.

• AAAARecord — adres IPv6 hosta.

• MXRecord — rekord usługi wymiany poczty dla hosta.

• PTRRecord — nazwa hosta przypisana do danego adresu IP.

• SRVRecord — rekord usługi..

Aby wyszukać rekord, należy przekazać ciąg znaków zapytania i obiekt klasy reprezentujący typ rekordu do metody lookup() obiektu DNSResolver. Ciąg znaków zapytania powinien odpowiadać typowy rekord:

Poniższy przykładowy kod wyszukuje adres IP hosta "example.com".

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Aby znaleźć więcej informacji na ten temat, zobacz:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord