Formaty danych Clipboard

W przypadku obiektu zapisanego w schowku w niestandardowym formacie danych dane obiektu można odczytać ze schowka jako odwołanie lub jako serializowaną kopię obiektu oryginalnego. Są cztery tryby przenoszenia określające, czy obiekty są przenoszone jako odniesienia czy kopie serializowane.

Zapisując obiekt w schowku, jako parametru format można używać dowolnego ciągu znaków, który nie rozpoczyna się od zarezerwowanych przedrostków air: lub flash: : Ten sam ciąg co dla formatu można wykorzystać do odczytywania obiektu. Następujące przykłady ilustrują sposób odczytywania i zapisywania obiektów do schowka:

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Aby wyciągnąć obiekt serializowana z obiektu schowka (po upuszczeniu lub wklejeniu), należy użyć tej samej nazwy formatu i trybów przenoszenia CLONE_ONLY lub CLONE_PREFFERED .

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

Odniesienie jest zawsze dodane do obiektu Clipboard. Aby wyciągnąć odniesienie z obiektu schowka (po upuszczeniu lub wklejeniu), zamiast kopii serializowanej należy użyć i trybów przenoszenia ORIGINAL_ONLY lub ORIGINAL_PREFFERED .

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Odniesienia są poprawne wyłącznie, jeśli obiekt Clipboard pochodzi z bieżącej aplikacji Za pomocą trybu przenoszenia ORIGINAL_PREFFERED można uzyskać dostęp do odniesienia, gdy jest dostępne, i do kopii serializowanej, gdy odniesienie nie jest dostępne.

W następnym przykładzie przedstawiony jest sposób wdrażania funkcji opóźnionego renderowania.

Gdy użytkownik naciśnie przycisk Kopiuj, aplikacja czyści schowek systemowy w celu zapewnienia, że nie zawiera on żadnych danych pozostawionych po poprzednich operacjach schowka. Następnie metoda setDataHandler() ustawia funkcję renderData() jako mechanizm renderujący dla schowka.

Gdy użytkownik wybierze polecenie Wklej z menu kontekstowego docelowego pola tekstowego, wówczas aplikacja uzyskuje dostęp do schowka i ustawia tekst docelowy. Format danych tekstowych w schowku został ustawiony za pomocą funkcji, a nie ciągu znaków, dlatego schowek wywołuje funkcję renderData() . Funkcja renderData() zwraca tekst w tekście źródłowym, który następnie zostanie przypisany do tekstu docelowego.

Należy zwrócić uwagę, że podczas edycji tekstu źródłowego przed naciśnięciem przycisku wklejania, zmiany zostaną odzwierciedlone we wklejonym tekście, nawet jeśli miały miejsce po naciśnięciu przycisku kopiowania. Dzieje się tak, ponieważ funkcja renderowania nie kopiuje tekstu źródłowego do czasu naciśnięcia przycisku wklejania. (Podczas korzystania z opóźnionego renderowania w rzeczywistej aplikacji dane źródłowe można przechowywać lub chronić w taki sam sposób, aby uniknąć tego problemu).

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>