Korzystanie ze składnika Button

Składnik Button jest prostokątnym przyciskiem, którego rozmiar można zmienić i który można nacisnąć myszą lub spacją w celu zainicjowania operacji aplikacji. Do składnika Button można dodać niestandardową ikonę. Można również zmienić zachowanie składnika Button z naciskania na przełączanie. Składnik Button typu przełącznik pozostaje wciśnięty po kliknięciu i powraca do stanu up po ponownym kliknięciu.

Składnik Button jest podstawową częścią wielu formularzy i aplikacji sieci Web. Przycisków można używać zawsze, gdy użytkownik ma inicjować zdarzenie. Na przykład, większość formularzy zawiera przycisk Prześlij. Do prezentacji można dodać przyciski Poprzedni i Następny.

Posługiwanie się składnikiem Button

W aplikacji przycisk można włączyć lub wyłączyć. W stanie disabled przycisk nie odbiera danych wprowadzanych za pomocą klawiatury lub myszy. Włączony przycisk jest aktywowany po jego kliknięciu lub przejściu do niego za pomocą klawisza Tab. Po aktywowaniu instancji Button można nią sterować za pomocą następujących klawiszy:

Klucz

Opis

Shift+Tab

Przesuwa aktywność do poprzedniego obiektu.

Spacja

Powoduje naciśnięcie lub zwolnienie przycisku i wywołanie zdarzenia click .

Karta

Przesuwa aktywność do kolejnego obiektu.

Enter/Return

Przesuwa aktywność do kolejnego obiektu, jeśli przycisk został ustawiony jako domyślny składnik Button klasy FocusManager.

Więcej informacji na temat sterowania aktywnością zawiera opis interfejsu IFocusManager oraz opis klasy FocusManager w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional oraz w sekcji Praca z klasą FocusManager .

Podgląd aktywny każdej z instancji Button odzwierciedla zmiany dokonane w parametrach w Inspektorze właściwości oraz Inspektorze składników podczas tworzenia.

Uwaga: Jeśli ikona jest większa niż przycisk, zostanie ona rozszerzona poza krawędzie przycisku.

Aby wskazać przycisk jako domyślny przycisk aplikacji (przycisk, który otrzymuje zdarzenie click po naciśnięciu klawisza Enter), należy ustawić właściwość FocusManager.defaultButton . Na przykład poniższy kod ustawia jako przycisk domyślny instancję składnika Button o nazwie submitButton . 

FocusManager.defaultButton = submitButton;

Po dodaniu składnika Button do aplikacji można go udostępnić dla czytnika ekranu, dodając do kodu ActionScript następujące wiersze: 

import fl.accessibility.ButtonAccImpl; 
 
ButtonAccImpl.enableAccessibility();

Ułatwienia dostępu włącza się dla danej klasy składników tylko raz, niezależnie od liczby utworzonych instancji.

Parametry składnika Button

Dla każdej instancji klasy Button można w Inspektorze właściwości (Okno > Właściwości > Właściwości) lub w Inspektorze składników (Okno > Inspektor składników) ustawić następujące parametry tworzenia treści: emphasized , label , labelPlacement , selected i toggle . Dla każdego z tych parametrów istnieje odpowiednia właściwość ActionScript o takiej samej nazwie. Przypisanie wartości dla tych parametrów jest równoważne z ustawieniem wstępnego stanu właściwości w aplikacji. Ustawienie właściwości w ActionScript powoduje zastąpienie wartości ustawionej w parametrze. Więcej informacji na temat możliwych wartości tych parametrów zawiera opis klasy Button w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .

Tworzenie aplikacji ze składnikiem Button

Poniższa procedura wyjaśnia jak podczas tworzenia dodać składnik Button do aplikacji. W tym przykładzie kliknięcie przycisku powoduje zmianę stanu składnika ColorPicker.

  1. Utwórz nowy dokument Flash (ActionScript 3.0).

  2. Przeciągnij składnik Button z panelu Składniki na stół montażowy i wprowadź dla niego w Inspektorze właściwości następujące wartości:

    • Wprowadź dla instancji nazwę aButton .

    • Dla parametru label wprowadź wartość Show .

  3. Dodaj składnik ColorPicker na stół montażowy i nadaj instancji nazwę aCp .

  4. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod ActionScript: 

    aCp.visible = false; 
 
aButton.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
     
    switch(event.currentTarget.label) { 
        case "Show": 
            aCp.visible = true; 
            aButton.label = "Disable"; 
            break; 
        case "Disable": 
            aCp.enabled = false; 
            aButton.label = "Enable"; 
            break; 
        case "Enable": 
            aCp.enabled = true; 
            aButton.label = "Hide"; 
            break; 
        case "Hide": 
            aCp.visible = false; 
            aButton.label = "Show"; 
            break; 
    } 
}

    Drugi wiersz kodu rejestruje funkcję clickHandler() jako funkcję obsługi zdarzenia MouseEvent.CLICK . Zdarzenie następuje po kliknięciu składnika Button, powodując, w zależności od wartości składnika Button, wykonanie przez funkcję clickHandler() jednej z następujących operacji:

    • Show - powoduje wyświetlenie składnika ColorPicker i zmienia etykietę składnika Button na Disable.

    • Disable - wyłącza składnik ColorPicker i zmienia etykietę składnika Button na Enable.

    • Enable - włącza składnik ColorPicker i zmienia etykietę składnika Button na Hide.

    • Hide - powoduje ukrycie składnika ColorPicker i zmienia etykietę składnika Button na Show.

  5. Wybierz polecenia Sterowanie > Testuj film, aby uruchomić aplikację.

Tworzenie aplikacji ze składnikiem Button

Poniższa procedura tworzy składnik Button typu przełącznik z użyciem kodu ActionScript i wyświetla typ zdarzenia w panelu Wyjście i po naciśnięciu składnika Button. W przykładzie instancja Button tworzona jest przez wywołanie konstruktora klasy i dodanie go na stół montażowy przez wywołanie metody addChild() .

  1. Utwórz nowy dokument Flash (ActionScript 3.0).

  2. Przeciągnij składnik Button z panelu Składniki do panelu Biblioteka bieżącego dokumentu.

    Powoduje to dodanie składnika do biblioteki, ale nie jest on wyświetlany w aplikacji.

  3. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod w celu utworzenia instancji Button: 

    import fl.controls.Button; 
 
var aButton:Button = new Button(); 
addChild(aButton); 
aButton.label = "Click me"; 
aButton.toggle =true;  
aButton.move(50, 50);

    Metoda move() powoduje ustawienie przycisku w lokalizacji 50 (współrzędna x), 50 (współrzędna y) na stole montażowym.

  4. Dodaj następujący kod ActionScript, aby utworzyć detektor zdarzeń i funkcję obsługi zdarzenia: 

    aButton.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    trace("Event type: " + event.type); 
}

  5. Wybierz polecenie Sterowanie > Testuj film.

    Po kliknięciu przycisku program Flash wyświetli w panelu Wyjście komunikat “Typ zdarzenia: kliknięcie”.