Korzystanie ze składnika ComboBox

W poniższym przykładzie z użyciem kodu ActionScript tworzony jest składnik ComboBox i wypełniany jest listą uniwersytetów z obszaru stanu San Francisco i Kalifornia. Właściwość width składnika ComboBox dopasowywana jest do szerokości tekstu monitu, a właściwość dropdownWidth jest nieznacznie poszerzana w celu dopasowania do najdłuższej nazwy uniwersytetu.

Lista uniwersytetów w przykładzie tworzona jest w instancji Array z użyciem właściwości label w celu zapisania nazw szkół i właściwości data do zapisania adresów URL stron sieci Web dla każdej z uczelni. Instancja Array przypisywana jest do składnika ComboBox przez ustawienie właściwości dataProvider .

Po wybraniu z listy uniwersytetu wywoływane jest zdarzenie Event.Zdarzenie CHANGE oraz funkcja changeHandler() , która ładuje do żądania URL właściwość data w celu uzyskania dostępu do strony sieci Web.

Należy zauważyć, że ostatni wiersz instancji ComboBox ustawia właściwość selectedIndex na wartość -1 w celu ponownego wyświetlenia monitu po zamknięciu listy. W innym wypadku monit zostanie zastąpiony nazwą wybranej uczelni.

1. Utwórz nowy dokument Flash (ActionScript 3.0).

2. Przeciągnij składnik ComboBox z panelu Składniki do panelu Biblioteka.

3. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod ActionScript:

   import fl.controls.ComboBox; 
   import fl.data.DataProvider; 
   import flash.net.navigateToURL; 
    
   var sfUniversities:Array = new Array( 
       {label:"University of California, Berkeley",  
                   data:"http://www.berkeley.edu/"}, 
       {label:"University of San Francisco",  
                   data:"http://www.usfca.edu/"}, 
       {label:"San Francisco State University",  
                   data:"http://www.sfsu.edu/"}, 
       {label:"California State University, East Bay",  
                   data:"http://www.csuhayward.edu/"}, 
       {label:"Stanford University", data:"http://www.stanford.edu/"}, 
       {label:"University of Santa Clara", data:"http://www.scu.edu/"}, 
       {label:"San Jose State University", data:"http://www.sjsu.edu/"} 
   ); 
    
   var aCb:ComboBox = new ComboBox(); 
   aCb.dropdownWidth = 210; 
   aCb.width = 200;  
   aCb.move(150, 50); 
   aCb.prompt = "San Francisco Area Universities"; 
   aCb.dataProvider = new DataProvider(sfUniversities); 
   aCb.addEventListener(Event.CHANGE, changeHandler); 
    
   addChild(aCb); 
    
   function changeHandler(event:Event):void { 
       var request:URLRequest = new URLRequest(); 
       request.url = ComboBox(event.target).selectedItem.data; 
       navigateToURL(request); 
       aCb.selectedIndex = -1; 
   }

4. Wybierz polecenie Sterowanie > Testuj film.

Przykład można zaimplementować i uruchomić w środowisku tworzenia programu Flash, jednak przy próbie dostępu do stron sieci Web uczelni, przez kliknięcie pozycji w składniku ComboBox, wyświetlone zostaną ostrzeżenia. Aby uzyskać dostęp do składnika ComboBox w pełni funkcjonalnego w Internecie, należy odwiedzić następującą stronę:

http://www.helpexamples.com/peter/bayAreaColleges/bayAreaColleges.html