Korzystanie ze składnika RadioButton

Składnik RadioButton pozwala wymusić na użytkowniku wybranie jednej opcji z określonego zbioru możliwości. Składnik ten musi być używany w grupie (co najmniej jako jedna z dwu instancji RadioButton). W danej chwili może być wybrany nie więcej niż jeden członek grupy. Wybór jednego przycisku opcji w grupie powoduje usunięcie zaznaczenia innego, obecnie zaznaczonego przycisku opcji w obrębie danej grupy. Parametr groupName służy do wskazywania grupy, do której należy dany przycisk opcji.

Przycisk opcji (składnik RadioButton) stanowi podstawową część wielu aplikacji formularzy w sieci WWW. Przyciski opcji mogą być używane zawsze, gdy użytkownik ma wybrać jedną opcję z grupy opcji. Przykład: przyciski opcji mogą być używane w formularzu w celu zapytania o kartę kredytową, której chce użyć użytkownik.

Posługiwanie się składnikiem RadioButton

Przycisk opcji może być włączony lub wyłączony. W stanie disabled przycisk opcji nie odbiera danych wprowadzanych za pomocą klawiatury lub myszy. Po kliknięciu przez użytkownika lub przejściu klawiszem Tab do dowolnego przycisku z grupy składników RadioButton uaktywniany jest tylko wybrany przycisk opcji. Następnie użytkownik może użyć następujących klawiszy do sterowania:

Klucz

Opis

Strzałka w górę/Strzałka w lewo

Zaznaczenie przesuwa się do poprzedniego przycisku opcji w danej grupie przycisków opcji.

Strzałka w dół/Strzałka w prawo

Zaznaczenie przesuwa się do kolejnego przycisku opcji w danej grupie przycisków opcji.

Karta

Przesuwa obszar aktywny z grupy przycisków opcji do następnego składnika.

Więcej informacji na temat sterowania aktywnością zawiera opis interfejsu IFocusManager oraz opis klasy FocusManager w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional oraz w sekcji Praca z klasą FocusManager .

Podgląd aktywny każdej instancji RadioButton na stole montażowym odzwierciedla zmiany dokonane w parametrach w Inspektorze właściwości oraz Inspektorze składników podczas tworzenia. Jednak wzajemne wykluczenie zaznaczenia nie jest widoczne w podglądzie aktywnym. Jeśli dla wybranego parametru zostanie ustawiona wartość true dla dwóch przycisków opcji w tej samej grupie, obydwa przyciski zostaną zaznaczone, nawet jeśli tylko instancja utworzona jako ostatnia jest zaznaczona w czasie wykonywania. Więcej informacji zawiera sekcja Parametry składnika RadioButton .

Po dodaniu składnika RadioButton do aplikacji można go udostępnić dla czytnika ekranu, dodając do kodu ActionScript następujące wiersze: 

import fl.accessibility.RadioButtonAccImpl; 
RadioButtonAccImpl.enableAccessibility();

Ułatwienia dostępu włącza się dla danej klasy składników tylko raz, niezależnie od liczby posiadanych instancji. Więcej informacji zawiera rozdział 18, “Tworzenie treści dostępnych dla użytkowników niepełnosprawnych”, w podręczniku Korzystanie z programu Flash .

Parametry składnika RadioButton

Dla każdej instancji składnika RadioButton można w Inspektorze właściwości lub w Inspektorze składników ustawić następujące parametry tworzenia treści: groupName, label, LabelPlacement, selected i value . Dla każdego z tych parametrów istnieje odpowiednia właściwość ActionScript o takiej samej nazwie. Więcej informacji na temat możliwych wartości tych parametrów zawiera opis klasy RadioButton w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .

W kodzie ActionScript możliwe jest ustawienie dodatkowych opcji dla instancji RadioButton za pomocą metod, właściwości i zdarzeń klasy RadioButton.

Tworzenie aplikacji ze składnikiem RadioButton

Poniższa procedura wyjaśnia jak podczas tworzenia dodać składniki RadioButton do aplikacji. W tym przykładzie składniki RadioButton reprezentują pytanie, na które udzielana jest odpowiedź tak lub nie. Dane ze składnika RadioButton są wyświetlane w obszarze TextArea.

  1. Utwórz nowy dokument Flash (ActionScript 3.0).

  2. Przeciągnij dwa składniki RadioButton z panelu Składniki na stół montażowy.

  3. Zaznacz pierwszy przycisk opcji. W Inspektorze właściwości nadaj instancji przycisku nazwę yesRb , a grupie nazwę rbGroup .

  4. Zaznacz drugi przycisk opcji. W Inspektorze właściwości nadaj instancji przycisku nazwę noRb , a grupie nazwę rbGroup .

  5. Przeciągnij składnik TextArea z panelu Składniki na stół montażowy i nadaj nazwę instancji aTa .

  6. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod ActionScript: 

    yesRb.label = "Yes"; 
yesRb.value = "For"; 
noRb.label = "No"; 
noRb.value = "Against"; 
 
yesRb.move(50, 100); 
noRb.move(100, 100); 
aTa.move(50, 30); 
noRb.addEventListener(MouseEvent.CLICK, clickHandler); 
yesRb.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    aTa.text = event.target.value; 
}

  7. Wybierz polecenia Sterowanie > Testuj film, aby uruchomić aplikację.

Tworzenie składnika RadioButton przy użyciu kodu ActionScript

W tym przykładzie wykorzystano język ActionScript w celu utworzenia trzech składników RadioButton dla kolorów: czerwonego, niebieskiego i zielonego oraz w celu narysowania szarego pola. Właściwość value każdego składnika RadioButton określa szesnastkową wartość dla koloru powiązanego z przyciskiem. Gdy użytkownik kliknie jeden z przycisków RadioButton, funkcja clickHandler() wywoła funkcję drawBox() , przekazując kolor z właściwości value składnika RadioButton w celu nałożenia koloru pola.

  1. Utwórz nowy dokument Flash (ActionScript 3.0).

  2. Przeciągnij składnik RadioButton do panelu Biblioteka.

  3. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod ActionScript: 

    import fl.controls.RadioButton; 
import fl.controls.RadioButtonGroup; 
 
var redRb:RadioButton = new RadioButton(); 
var blueRb:RadioButton = new RadioButton(); 
var greenRb:RadioButton = new RadioButton(); 
var rbGrp:RadioButtonGroup = new RadioButtonGroup("colorGrp"); 
 
var aBox:MovieClip = new MovieClip(); 
drawBox(aBox, 0xCCCCCC); 
 
addChild(redRb); 
addChild(blueRb); 
addChild(greenRb); 
addChild(aBox); 
 
redRb.label = "Red"; 
redRb.value = 0xFF0000; 
blueRb.label = "Blue"; 
blueRb.value = 0x0000FF; 
greenRb.label = "Green"; 
greenRb.value = 0x00FF00; 
redRb.group = blueRb.group = greenRb.group = rbGrp; 
redRb.move(100, 260); 
blueRb.move(150, 260); 
greenRb.move(200, 260); 
 
rbGrp.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    drawBox(aBox, event.target.selection.value); 
} 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(125, 150, 100, 100); 
            box.graphics.endFill();         
}

  4. Wybierz polecenia Sterowanie > Testuj film, aby uruchomić aplikację.

    Więcej informacji zawiera opis klasy RadioButton w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .