Korzystanie ze składnika Slider

Po aktywowaniu instancji Slider można nią sterować za pomocą następujących klawiszy:

Więcej informacji na temat sterowania aktywnością zawiera opis interfejsu IFocusManager oraz opis klasy FocusManager w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional oraz w sekcji Praca z klasą FocusManager .

Podgląd aktywny każdej instancji Slider odzwierciedla zmiany dokonane w parametrach w Inspektorze właściwości oraz Inspektorze składników podczas tworzenia.

Dla każdej instancji składnika Slider można w Inspektorze właściwości lub w Inspektorze składników ustawić następujące parametry tworzenia treści: direction , liveDragging , maximum , minimum , snapInterval , tickInterval i value . Dla każdego z tych parametrów istnieje odpowiednia właściwość ActionScript o takiej samej nazwie. Więcej informacji na temat możliwych wartości tych parametrów zawiera opis klasy Slider w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .

W poniższym przykładzie przedstawiono tworzenie instancji Slider, która umożliwia użytkownikowi wyrażenie poziomu zadowolenia z hipotetycznego zdarzenia. Użytkownik przesuwa suwak (składnik Slider) w prawo lub w lewo, aby określić wysoki lub niski poziom zadowolenia.

1. Utwórz nowy dokument Flash (ActionScript 3.0).

2. Przeciągnij składnik Label z panelu Składniki na środek stołu montażowego.

   • Nadaj instancji nazwę valueLabel .

   • Do parametru text przypisz wartość 0 percent .

3. Przeciągnij składnik Slider z panelu Składniki i wyśrodkuj go poniżej value_lbl .

   • Nadaj instancji nazwę aSlider .

   • Przypisz składnikowi szerokość (Sz) równą 200 .

   • Przypisz składnikowi wysokość (W) równą 10 .

   • Do parametru maximum przypisz wartość 100 .

   • Do parametrów snapInterval i tickInterval przypisz wartość 10 .

4. Przeciągnij kolejną instancję Label z panelu Biblioteka i wyśrodkuj ją poniżej aSlider .

   • Nadaj instancji nazwę promptLabel .

   • Przypisz instancji szerokość (Sz) równą 250.

   • Przypisz instancji wysokość (W) równą 22.

   • Dla parametru text wprowadź tekst Określ swój poziom zadowolenia .

5. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod ActionScript:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Wybierz polecenie Sterowanie > Testuj film.

   W tym przykładzie podczas przesuwania uchwytu suwaka między odstępami detektor zdarzenia SliderEvent.CHANGE aktualizuje właściwość text instancji valueLabel w celu wyświetlenia wartości procentowej, która odpowiada położeniu wskaźnika.

W poniższym przykładzie przedstawiono tworzenie składnika Slider za pomocą kodu ActionScript. W przykładzie pobierany jest obraz kwiatka, a składnik Slider umożliwia użytkownikowi ukrywanie i rozjaśnianie obrazu poprzez zmianę jego właściwości alpha w taki sposób, aby odpowiadała wartości składnika Slider.

1. Utwórz nowy dokument Flash (ActionScript 3.0).

2. Przeciągnij składniki Label i Slider z panelu Składniki do panelu Biblioteka bieżącego dokumentu.

   Dzięki temu składniki zostaną dodane do biblioteki, ale nie będą widoczne w aplikacji.

3. Otwórz panel Operacje, zaznacz klatkę nr 1 na głównej osi czasu i wprowadź następujący kod w celu utworzenia i ustawienia instancji składnika:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Wybierz polecenia Sterowanie > Testuj film, aby uruchomić aplikację.

5. Przesuń wskaźnik składnika Slider w lewo, aby ukryć obraz, albo w prawo, aby go rozjaśnić.