Odtwarzanie wielu plików wideo

W jednej instancji składnika FLVPlayback można otworzyć wiele odtwarzaczy wideo, aby odtwarzać wiele plików wideo i przełączać je podczas odtwarzania.

Do utworzenia pierwszego odtwarzacza wideo dochodzi po przeciągnięciu składnika FLVPlayback na stół montażowy. Składnik automatycznie przypisuje pierwszemu odtwarzaczowi wideo numer 0 i ustawia go jako odtwarzacz domyślny. W celu utworzenia dodatkowego odtwarzacza wideo ustaw nową liczbę dla właściwości activeVideoPlayerIndex . Ustawienie właściwości activeVideoPlayerIndex powoduje również ustawienie wybranego odtwarzacza wideo jako aktywnego odtwarzacza wideo — na ten odtwarzacz będą wpływać właściwości i metody klasy FLVPlayback. Ustawienie właściwości activeVideoPlayerIndex nie powoduje jednak wyświetlenia odtwarzacza wideo. W celu wyświetlenia odtwarzacza wideo należy ustawić właściwość visibleVideoPlayerIndex na numer odtwarza wideo. Więcej informacji o interakcjach między tymi właściwościami a metodami i właściwościami klasy FLVPlayback zawierają opisy właściwości FLVPlayback.activeVideoPlayerIndex i FLVPlayback.visibleVideoPlayerIndex w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .

Poniższy kod ActionScript ładuje właściwość source w celu odtworzenia pliku wideo w domyślnym odtwarzaczu wideo, a następnie dodaje do niego punkt sygnalizacji. Gdy wystąpi zdarzenie ready , moduł obsługi zdarzeń otwiera drugi odtwarzacz wideo, ustawiając dla właściwości activeVideoPlayerIndex numer 1. Ten kod określa plik FLV i punkt sygnalizacji dla drugiego odtwarzacza wideo, a następnie ponownie ustawia domyślny odtwarzacz (0) jako aktywny odtwarzacz wideo.

/** 
    Requires: 
- FLVPlayback component on the Stage with an instance name of my_FLVPlybk 
*/ 
// add a cue point to the default player 
import fl.video.*; 
my_FLVPlybk.source = "http://www.helpexamples.com/flash/video/clouds.flv"; 
my_FLVPlybk.addASCuePoint(3, "1st_switch"); 
my_FLVPlybk.addEventListener(VideoEvent.READY, ready_listener); 
function ready_listener(eventObject:VideoEvent):void { 
    // add a second video player and create a cue point for it 
    my_FLVPlybk.activeVideoPlayerIndex = 1; 
    my_FLVPlybk.source = "http://www.helpexamples.com/flash/video/water.flv"; 
    my_FLVPlybk.addASCuePoint(3, "2nd_switch"); 
    my_FLVPlybk.activeVideoPlayerIndex = 0; 
};

Aby wybrać inny plik FLV podczas odtwarzania jednego pliku, należy ustawić przełączenie w kodzie ActionScript. Punkty sygnalizacji umożliwiają interweniowanie w określonych miejscach pliku FLV za pomocą zdarzenia cuePoint . Poniższy kod tworzy detektor dla zdarzenia cuePoint i wywołuje funkcję modułu obsługi zdarzeń, która wstrzymuje aktywny odtwarzacz wideo (0), przełącza na drugi odtwarzacz (1), a następnie odtwarza jego plik FLV:

import fl.video.*; 
// add listener for a cuePoint event 
my_FLVPlybk.addEventListener(MetadataEvent.CUE_POINT, cp_listener); 
// add the handler function for the cuePoint event 
function cp_listener(eventObject:MetadataEvent):void { 
        // display the no. of the video player causing the event 
        trace("Hit cuePoint event for player: " + eventObject.vp); 
        // test for the video player and switch FLV files accordingly 
        if (eventObject.vp == 0) { 
            my_FLVPlybk.pause();     //pause the first FLV file 
            my_FLVPlybk.activeVideoPlayerIndex = 1; // make the 2nd player active 
            my_FLVPlybk.visibleVideoPlayerIndex = 1; // make the 2nd player visible 
            my_FLVPlybk.play(); // begin playing the new player/FLV 
        } else if (eventObject.vp == 1) { 
            my_FLVPlybk.pause(); // pause the 2nd FLV 
            my_FLVPlybk.activeVideoPlayerIndex = 0; // make the 1st player active 
            my_FLVPlybk.visibleVideoPlayerIndex = 0; // make the 1st player visible 
            my_FLVPlybk.play(); // begin playing the 1st player 
        } 
} 
my_FLVPlybk.addEventListener(VideoEvent.COMPLETE, complete_listener); 
function complete_listener(eventObject:VideoEvent):void { 
        trace("Hit complete event for player: " + eventObject.vp); 
        if (eventObject.vp == 0) { 
            my_FLVPlybk.activeVideoPlayerIndex = 1; 
            my_FLVPlybk.visibleVideoPlayerIndex = 1; 
            my_FLVPlybk.play(); 
        } else { 
            my_FLVPlybk.closeVideoPlayer(1); 
        } 
};

W przypadku utworzenia nowego odtwarzacza wideo instancja FLVPlayback ustawia jego właściwości na wartości zgodne z wartościami domyślnego odtwarzacza wideo — z wyjątkiem właściwości source , totalTime i isLive , dla których instancja FLVPlayback zawsze ustawia wartości domyślne — odpowiednio: pusty ciąg znaków, 0 i false . Instancja ustawia właściwość autoPlay , która domyślnie przyjmuje wartość true , a dla domyślnego odtwarzacza wideo przyjmuje wartość false . Właściwość cuePoints nie ma wpływu na kolejne operacje ładowania do domyślnego odtwarzacza wideo.

Metody i właściwości, które kontrolują wielkość, położenie, wymiary, widoczność i elementy sterowania na interfejsie użytkownika są zawsze globalne, a na ich działanie nie wpływa ustawienie właściwości activeVideoPlayerIndex . Więcej informacji o tych metodach i właściwościach oraz skutkach ustawienia właściwości activeVideoPlayerIndex zawiera opis właściwości FLVPlayback.activeVideoPlayerIndex w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional . Pozostałe właściwości i metody są określone dla odtwarzacza wideo określonego przez wartość właściwości activeVideoPlayerIndex .

Właściwości i metody, które kontrolują wymiary, wchodzą w interakcje z właściwością visibleVideoPlayerIndex . Więcej informacji zawiera opis właściwości FLVPlayback.visibleVideoPlayerIndex w Skorowidzu języka ActionScript 3.0 dla programu Flash Professional .