Het bereik van een variabele is het gebied van de code waar toegang tot de variabele mogelijk is door een lexicale verwijzing. Een algemene variabele wordt gedefinieerd in alle gebieden van de code, een lokale variabele wordt gedefinieerd in een deel van de code. In ActionScript 3.0 krijgen variabelen altijd het bereik toegewezen van de functie of klasse waarin ze worden gedeclareerd. Een algemene variabele wordt gedefinieerd buiten een functie- of klassendefinitie. Met de volgende code wordt bijvoorbeeld een algemene variabele strGlobal gemaakt door deze buiten een functie te declareren. Het voorbeeld toont dat een algemene variabele beschikbaar is zowel binnen als buiten de functiedefinitie.

var strGlobal:String = "Global"; 
function scopeTest() 
{ 
    trace(strGlobal); // Global 
} 
scopeTest(); 
trace(strGlobal); // Global

U declareert een lokale variabele binnen een functiedefinitie. Het kleinste codegebied waarvoor u een lokale variabele kunt definiëren is een functiedefinitie. Een lokale variabele die binnen een functie wordt gedeclareerd, bestaat alleen in die functie. Wanneer u bijvoorbeeld een variabele declareert met de naam str2 binnen een functie met de naam localScope(), is deze variabele niet beschikbaar buiten de functie.

function localScope() 
{ 
    var strLocal:String = "local"; 
} 
localScope(); 
trace(strLocal); // error because strLocal is not defined globally

Wanneer de variabelenaam die u gebruikt voor de lokale variabele al is gedeclareerd als een algemene variabele, verbergt (of arceert) de lokale definitie de algemene definitie wanneer de lokale variabele in het bereik valt. De algemene variabele blijft bestaan buiten de functie. Met de volgende code wordt bijvoorbeeld een algemene tekenreeksvariabele gemaakt met de naam str1 en wordt vervolgens een lokale variabele met dezelfde naam gemaakt binnen de functie scopeTest(). De instructie trace geeft binnen de functie de lokale waarde van de variabele als uitvoer. Buiten de functie geeft de instructie trace de algemene waarde van de variabele als uitvoer.

var str1:String = "Global"; 
function scopeTest () 
{ 
    var str1:String = "Local"; 
    trace(str1); // Local 
} 
scopeTest(); 
trace(str1); // Global

Variabelen in ActionScript hebben geen bereik op blokniveau, wat in C++ en Java wel het geval is. Een codeblok is een groep instructies tussen een accolade openen ( { ) en een accolade sluiten (}). In sommige programmeertalen, zoals C++ en Java, zijn variabelen die binnen een codeblok worden gedeclareerd, niet beschikbaar buiten dat codeblok. Deze beperking in het bereik wordt bereik op blokniveau genoemd en komt in ActionScript niet voor. Als u een variabele binnen een codeblok declareert, is die variabele niet alleen beschikbaar in dat codeblok maar ook in alle andere delen van de functie waartoe het codeblok behoort. De volgende functie bevat bijvoorbeeld variabelen die worden gedefinieerd in diverse blokbereiken. Alle variabelen zijn beschikbaar in de gehele functie.

function blockTest (testArray:Array) 
{ 
    var numElements:int = testArray.length; 
    if (numElements > 0) 
    { 
        var elemStr:String = "Element #"; 
        for (var i:int = 0; i < numElements; i++) 
        { 
            var valueStr:String = i + ": " + testArray[i]; 
            trace(elemStr + valueStr); 
        } 
        trace(elemStr, valueStr, i); // all still defined 
    } 
    trace(elemStr, valueStr, i); // all defined if numElements > 0 
} 
 
blockTest(["Earth", "Moon", "Sun"]);

Een interessant gevolg van het ontbreken van bereik op blokniveau is dat u een variabele kunt lezen of ernaar schrijven voordat deze wordt gedeclareerd (mits declaratie plaatsvindt voordat de functie eindigt). Dit komt door een techniek die hoisting wordt genoemd, wat betekent dat de compiler alle declaraties van variabelen naar het hoofdniveau van de functie verplaatst. De volgende code wordt bijvoorbeeld gecompileerd ook al treedt de eerste functie trace() voor de variabele num op voordat de variabele num wordt gedeclareerd:

trace(num); // NaN 
var num:Number = 10; 
trace(num); // 10

In de compiler vindt echter geen hoisting plaats voor toewijzingsinstructies. Dit verklaart waarom de eerste trace() van num resulteert in NaN (Not a Number), wat de standaardwaarde is voor variabelen van het gegevenstype Number. Dit betekent dat u waarden kunt toewijzen aan variabelen nog voordat deze worden gedeclareerd, zoals in het volgende voorbeeld wordt getoond:

num = 5; 
trace(num); // 5 
var num:Number = 10; 
trace(num); // 10

Een standaardwaarde is de waarde die een variabele bevat voordat u de waarde ervan instelt. U initialiseert een variabele wanneer u voor de eerste keer de waarde ervan instelt. Wanneer u een variabele declareert maar niet de waarde ervan instelt, is de variabele niet-geïnitialiseerd. De waarde van een niet-geïnitialiseerde variabele is afhankelijk van het gegevenstype ervan. In de volgende tabel worden de standaardwaarden van variabelen beschreven, geordend op gegevenstype:

Voor variabelen van het type Number is de standaardwaarde NaN (Not a Number). Dit is een speciale waarde gedefinieerd door de IEEE-754-standaard die een waarde anders dan een getal vertegenwoordigt.

Als u wel een variabele maar geen gegevenstype declareert, is het gegevenstype * (variabele zonder type) van toepassing. Als u een variabele zonder type ook niet initialiseert met een waarde, is de standaardwaarde undefined.

Voor gegevenstypen anders dan Boolean, Number, int en uint is de standaardwaarde voor een niet-geïnitialiseerde variabele null. Dit geldt voor alle klassen die door ActionScript 3.0 worden gedefinieerd plus de aangepaste klassen die u zelf maakt.

De waarde null is geen geldige waarde voor variabelen van het type Boolean, Number, int of uint. Wanneer u probeert de waarde null toe te wijzen aan een van deze variabelen, wordt de waarde omgezet in de standaardwaarde voor dat gegevenstype. U kunt de waarde null toewijzen aan variabelen van het type Object. Wanneer u probeert de waarde undefined toe te wijzen aan een variabele van het type Object, wordt de waarde omgezet in null.

Voor variabelen van het type Number bestaat een speciale functie op hoofdniveau met de naam isNaN() die de Booleaanse waarde true retourneert als de variabele geen getal is en false als dat wel het geval is.