Voorbeeld van arrays: PlayList

De klasse PlayList beheert een set objecten van het type Song. Deze klasse heeft methoden van het type public met functionaliteit voor het toevoegen van een nummer aan de afspeellijst (de methode addSong() ) en voor het sorteren van de nummers in de lijst (de methode sortList() ). Bovendien bevat deze klasse een eigenschap voor alleen-lezen-toegang ( songList ) voor toegang tot de eigenlijke set nummers in de afspeellijst. Intern houdt de klasse PlayList de nummers bij met behulp van een Array-variabele van het type private:

public class PlayList 
{ 
    private var _songs:Array; 
    private var _currentSort:SortProperty = null; 
    private var _needToSort:Boolean = false; 
    ... 
}

Naast de Array-variabele _songs , die door de klasse PlayList wordt gebruikt om de eigen lijst met nummers bij te houden, houden twee andere private variabelen bij of de lijst moet worden gesorteerd ( _needToSort ) en aan de hand van welke eigenschap de lijst met nummers moet worden gesorteerd op een bepaald moment ( _currentSort ).

Zoals bij alle objecten is het declareren van een instantie Array nog maar de helft van het maken van een array. Voordat de eigenschappen of methoden van een instantie Array kunnen worden benaderd, moet van de array een instantie worden gemaakt met behulp van de constructor van de klasse PlayList.

    public function PlayList() 
    { 
        this._songs = new Array(); 
        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE); 
    }

De eerste regel van de constructor maakt een instantie van de variabele _songs , zodat deze klaar is voor gebruik. Vervolgens wordt de methode sortList() aangeroepen om de eerste eigenschap waarop wordt gesorteerd te bepalen.

Wanneer een gebruiker een nieuw nummer aan de toepassing toevoegt, roept de code in het gegevensinvoerformulier de methode addSong() van de klasse PlayList aan.

    /** 
     * Adds a song to the playlist. 
     */ 
    public function addSong(song:Song):void 
    { 
        this._songs.push(song); 
        this._needToSort = true; 
    }

In addSong() wordt de methode push() van de array _songs aangeroepen, waardoor het object Song dat aan addSong() is doorgegeven, als nieuw element aan die array wordt toegevoegd. Met de methode push() wordt het nieuwe element aan het einde van de array toegevoegd, ongeacht de eventueel eerder toegepaste sorteervolgorde. Dit betekent dat na het aanroepen van de methode push() de sorteervolgorde van de lijst met nummers waarschijnlijk niet meer klopt. Daarom wordt de variabele _needToSort op true ingesteld. In theorie kan onmiddellijk de methode sortList() worden aangeroepen, zodat niet meer hoeft te worden bijgehouden of de lijst op een bepaald moment al dan niet gesorteerd is. In de praktijk hoeft de lijst met nummers echter pas net vóór het opvragen te worden gesorteerd. Door het sorteren uit te stellen hoeft de toepassing niet onnodig te sorteren als bijvoorbeeld meerdere nummers aan de lijst worden toegevoegd vóór het opvragen.

Omdat de instanties Song die door de afspeellijst worden beheerd complexe objecten zijn, willen de gebruikers van de toepassing de afspeellijst misschien liever sorteren op andere eigenschappen, zoals de naam van het nummer of het jaar waarin het is uitgebracht. In de toepassing PlayList bestaat het sorteren van de lijst met nummers uit drie onderdelen: de eigenschap identificeren waarop de lijst moet worden gesorteerd, aangeven welke sorteeropties gebruikt moeten worden wanneer er op die eigenschap wordt gesorteerd en het daadwerkelijk uitvoeren van de sorteerbewerking.

    public static const TITLE:SortProperty = new SortProperty("title"); 
    public static const ARTIST:SortProperty = new SortProperty("artist"); 
    public static const YEAR:SortProperty = new SortProperty("year");

        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE);

    /** 
     * Sorts the list of songs according to the specified property. 
     */ 
    public function sortList(sortProperty:SortProperty):void 
    { 
        ... 
        var sortOptions:uint; 
        switch (sortProperty) 
        { 
            case SortProperty.TITLE: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.ARTIST: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.YEAR: 
                sortOptions = Array.NUMERIC; 
                break; 
        } 
         
        // Perform the actual sorting of the data. 
        this._songs.sortOn(sortProperty.propertyName, sortOptions); 
             
        // Save the current sort property. 
        this._currentSort = sortProperty; 
 
        // Record that the list is sorted. 
        this._needToSort = false; 
    }

Naast het gebruik van een array om de lijst met nummers bij te houden in de klasse PlayList, worden in dit voorbeeld ook arrays gebruikt in de klasse Song als hulpmiddel bij het beheer van de lijst met genres waartoe een bepaald nummer behoort. Bekijk het volgende fragment uit de definitie van de klasse Song:

private var _genres:String; 
 
public function Song(title:String, artist:String, year:uint, filename:String, genres:Array) 
{ 
    ... 
    // Genres are passed in as an array 
    // but stored as a semicolon-separated string. 
    this._genres = genres.join(";"); 
}

Wanneer een nieuwe instantie Song wordt gemaakt, wordt de parameter genres voor het opgeven van het genre (of de genres) van het nummer gedefinieerd als een instantie van het type Array. Dit maakt het gemakkelijker om meerdere genres te groeperen in één variabele die aan de constructor kan worden doorgegeven. Intern houdt de klasse Song de genres echter bij in de variabele van het type private _genres als instantie van het type String met een puntkomma als scheidingsteken. De parameter Array wordt omgezet in een tekenreeks met een puntkomma als scheidingsteken door de bijbehorende methode join() aan te roepen met de letterlijke tekenreekswaarde ";" als opgegeven scheidingsteken.

Op dezelfde manier kunnen met de accessors van het type genres genres worden ingesteld of opgevraagd als Array:

    public function get genres():Array 
    { 
        // Genres are stored as a semicolon-separated String, 
        // so they need to be transformed into an Array to pass them back out. 
        return this._genres.split(";"); 
    } 
    public function set genres(value:Array):void 
    { 
        // Genres are passed in as an array, 
        // but stored as a semicolon-separated string. 
        this._genres = value.join(";"); 
    }

De accessor genres set gedraagt zich op precies dezelfde manier als de constructor: hij accepteert een Array en roept de methode join() aan voor de omzetting in een tekenreeks met een puntkomma als scheidingsteken. De accessor get voert een tegenovergestelde bewerking uit: de methode split() van de variabele _genres wordt aangeroepen, waardoor de String wordt opgedeeld in een array van waarden met het opgegeven scheidingsteken (dezelfde letterlijke tekenreekswaarde ";" als daarvoor).