Basisinformatie over netwerken en communicatie

U kunt het object NetworkInfo gebruiken om te zien welke hardware- en softwarenetwerkinterfaces beschikbaar zijn voor uw toepassing. Het object NetworkInfo is een singleton-object. U hoeft dit object niet te maken. Gebruik in plaats hiervan de statische klasseneigenschap networkInfo om toegang te krijgen tot het enkele object NetworkInfo. Het object NetworkInfo verzendt eveneens een networkChange-gebeurtenis als er zich een wijziging voordoet in een van de beschikbare interfaces.

Roep de methode findInterfaces() aan om een lijst met NetworkInterface-objecten te zien. Elk NetworkInterface-object in de lijst geeft een beschrijving van een van de beschikbare interfaces. Het NetworkInterface-object geeft informatie over onder meer het IP-adres, het hardwareadres en de maximale verzendeenheid. Ook wordt er aangegeven of de interface actief is of niet.

In het volgende codevoorbeeld worden de NetworkInterface-eigenschappen van elke interface op de clientcomputer getraceerd:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Raadpleeg de volgende bronnen voor meer informatie:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

Uw AIR-toepassing kan worden uitgevoerd in omgevingen met een onzekere of veranderende netwerkconnectiviteit. Om de verbindingen met online bronnen beter te kunnen beheren, verstuurt Adobe AIR de gebeurtenis network change wanneer een netwerkverbinding beschikbaar of onbeschikbaar wordt. De gebeurtenis networkChange wordt verzonden door zowel het NetworkInfo-object als het NativeApplication-object van de toepassing. Om op deze gebeurtenis te kunnen reageren, voegt u een listener toe:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Vervolgens definieert u een gebeurtenishandlerfunctie:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

De networkChange-gebeurtenis geeft geen wijziging in alle netwerkactiviteit aan, maar alleen dat er een netwerkverbinding is gewijzigd. AIR probeert niet om de betekenis van de netwerkwijziging te interpreteren. Een computer in een netwerk kan vele reële en virtuele verbindingen hebben. Het verlies van een verbinding betekent dus niet noodzakelijk dat een resource verloren is gegaan. Anderzijds waarborgen nieuwe verbindingen ook geen betere beschikbaarheid van de resources. Soms kan een nieuwe verbinding zelfs de toegang blokkeren tot resources die voordien beschikbaar waren (bijvoorbeeld wanneer verbinding wordt gemaakt met een VPN).

Een toepassing kan alleen bepalen of deze verbinding kan maken met een externe resource door dit daadwerkelijk te proberen. Het framework voor servicebewaking biedt aan een opgegeven host een op gebeurtenissen gebaseerd middel om te reageren op wijzigingen in netwerkconnectiviteit.

U kunt DNS-bronrecords opzoeken aan de hand van de klasse DNSResolver. DNS-bronrecords bieden informatie zoals het IP-adres van een domeinnaam en de domeinnaam van een IP-adres. U kunt de volgende DNS-bronrecordtypen opzoeken:

• ARecord - IPv4-adres voor een host.

• AAAARecord - IPv6-adres voor een host.

• MXRecord - mailuitwisselingsrecord voor een host.

• PTRRecord - hostnaam voor een IP-adres.

• SRVRecord - servicerecord voor een service..

Als u een record wilt opzoeken, geeft u een querytekenreeks en het klassenobject dat het recordtype representeert, door aan de methode lookup() van het DNSResolver-object. De te gebruiken querytekenreeks is afhankelijk van het recordtype:

In het volgende codevoorbeeld wordt het IP-adres van de host "example.com" opgezocht.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Raadpleeg de volgende bronnen voor meer informatie:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord