텍스트 입력 캡처

Flash Player 9 이상, Adobe AIR 1.0 이상

기본적으로 텍스트 필드의 type 속성은 dynamic 으로 설정됩니다. TextFieldType 클래스를 사용하여 type 속성을 input 으로 설정하면 사용자 입력을 수집하여 해당 값을 응용 프로그램의 다른 부분에서 사용할 수 있도록 저장할 수 있습니다. 입력 텍스트 필드는 프로그램의 다른 위치에서 사용하기 위해 사용자가 텍스트 값을 정의하도록 할 모든 응용 프로그램 및 양식에 유용합니다.

예를 들어 다음 코드는 myTextBox 라는 입력 텍스트 필드를 만듭니다. 사용자가 필드에 텍스트를 입력하면 textInput 이벤트가 트리거됩니다. textInputCapture 라는 이벤트 핸들러는 입력된 텍스트 문자열을 캡처하고 해당 문자열에 변수를 할당합니다. Flash Player 또는 AIR는 myOutputBox 라는 또 다른 텍스트 필드에 새 텍스트를 표시합니다.

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}