고급 텍스트 렌더링

응용 프로그램에서 TextField의 특정 글꼴을 지정하면 Flash Player 또는 AIR가 이름이 같은 장치 글꼴(사용자의 컴퓨터에 있는 글꼴)을 찾습니다. 시스템에서 해당 글꼴을 찾지 못하거나, 이름은 같지만 글꼴의 버전이 약간 다른 경우에는 텍스트의 모양이 의도와 매우 다르게 표시될 수 있습니다. 기본적으로 텍스트는 Times Roman 글꼴로 표시됩니다.

정확히 원하는 글꼴이 표시되도록 하려면 응용 프로그램 SWF 파일에 해당 글꼴을 포함할 수 있습니다. 포함된 글꼴에는 다음과 같은 여러 가지 이점이 있습니다.

• 포함된 글꼴 문자에는 앤티앨리어싱이 적용되어 가장자리가 보다 부드럽게 표시됩니다(특히 큰 텍스트의 경우).

• 포함된 글꼴을 사용하는 텍스트를 회전할 수 있습니다.

• 포함된 글꼴 텍스트는 투명하거나 반투명하게 만들 수 있습니다.

• 포함된 글꼴과 함께 커닝 CSS 스타일을 사용할 수 있습니다.

포함된 글꼴 사용에 있어 가장 큰 제한 사항은 포함된 글꼴로 인해 파일 크기 또는 응용 프로그램의 다운로드 크기가 커진다는 것입니다.

글꼴 파일을 응용 프로그램 SWF 파일에 포함하는 정확한 방법은 개발 환경에 따라 다릅니다.

글꼴을 포함한 후에는 다음과 같이 TextField에서 올바른 포함된 글꼴을 사용하도록 할 수 있습니다.

• TextField의 embedFonts 속성을 true 로 설정합니다.

• TextFormat 객체를 만들고 fontFamily 속성을 포함된 글꼴의 이름으로 설정한 다음 해당 TextFormat 객체를 TextField에 적용합니다. 포함된 글꼴을 지정할 때 fontFamily 속성에는 하나의 이름만 포함해야 하며 여러 글꼴 이름의 쉼표로 분리된 목록을 사용할 수 없습니다.

• CSS 스타일을 사용하여 TextField 또는 구성 요소의 글꼴을 설정하는 경우 font-family CSS 속성을 포함된 글꼴의 이름으로 설정합니다. 포함된 글꼴을 지정하려는 경우 font-family 속성에 하나의 이름을 포함해야 하며 여러 이름의 목록을 사용할 수 없습니다.

기본적으로 텍스트의 크기 또는 색상을 변경하거나 텍스트를 다양한 배경에 표시할 때 Flash Player 또는 AIR에서 선명도, 두께, 앤티앨리어싱 등 텍스트 표시 컨트롤의 설정을 결정합니다. 텍스트의 크기가 매우 작거나 클 때 또는 여러 가지 고유한 배경에 텍스트를 표시할 때 등 일부 경우에는 이러한 설정을 직접 제어할 수도 있습니다. flash.text.TextRenderer 클래스 및 CSMSettings 클래스와 같은 관련 클래스를 사용하여 Flash Player 또는 AIR 설정을 무시할 수 있습니다. 이러한 클래스를 사용하면 포함된 텍스트의 렌더링 품질을 정밀하게 제어할 수 있습니다. 포함된 글꼴에 대한 자세한 내용은 포함된 글꼴 사용 을 참조하십시오.

다음 예제에서는 myFont 라는 포함된 글꼴을 사용하여 사용자 정의 CSM(Continuous Stroke Modulation) 속성 및 서식을 표시된 텍스트에 적용합니다. 사용자가 표시된 텍스트를 클릭하면 Flash Player 또는 Adobe AIR에서 사용자 정의 설정을 적용합니다.

var format:TextFormat = new TextFormat(); 
format.color = 0x336699; 
format.size = 48; 
format.font = "myFont"; 
 
var myText:TextField = new TextField(); 
myText.embedFonts = true; 
myText.autoSize = TextFieldAutoSize.LEFT; 
myText.antiAliasType = AntiAliasType.ADVANCED; 
myText.defaultTextFormat = format; 
myText.selectable = false; 
myText.mouseEnabled = true; 
myText.text = "Hello World"; 
addChild(myText); 
myText.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:Event):void 
{ 
    var myAntiAliasSettings = new CSMSettings(48, 0.8, -0.8); 
    var myAliasTable:Array = new Array(myAntiAliasSettings); 
    TextRenderer.setAdvancedAntiAliasingTable("myFont", FontStyle.ITALIC, TextColorType.DARK_COLOR, myAliasTable); 
}