문자열의 패턴 및 하위 문자열 찾기

일치하는 하위 문자열 찾기

search() 메서드는 이 예제와 같이 지정된 패턴과 일치하는 첫 번째 하위 문자열의 인덱스 위치를 반환합니다.

var str:String = "The more the merrier."; 
// (This search is case-sensitive.) 
trace(str.search("the")); // output: 9 

일반 표현식을 사용하여 이 예제와 같이 일치하는 패턴을 정의할 수도 있습니다.

var pattern:RegExp = /the/i; 
var str:String = "The more the merrier."; 
trace(str.search(pattern)); // 0

문자열의 첫 번째 문자는 인덱스 위치 0이므로 trace() 메서드의 출력은 0이며, i 플래그가 일반 표현식에 설정되어 있으므로 검색 시 대/소문자를 구분하지 않습니다.

search() 메서드는 g(global) 플래그가 일반 표현식에 설정되어 있어도 일치하는 한 항목만 찾으며 그 시작 인덱스 위치를 반환합니다.

다음 예제에서는 큰따옴표로 묶인 문자열과 일치하는 보다 복잡한 일반 표현식을 보여 줍니다.

var pattern:RegExp = /"[^"]*"/; 
var str:String = "The \"more\" the merrier."; 
trace(str.search(pattern)); // output: 4 
 
str = "The \"more the merrier."; 
trace(str.search(pattern)); // output: -1  
// (Indicates no match, since there is no closing double quotation mark.)

match() 메서드는 이와 유사하게 작동하며, 일치하는 하위 문자열을 검색합니다. 하지만 다음 예제와 같이 일반 표현식 패턴에서 전역 플래그를 사용할 경우 match() 메서드는 일치하는 하위 문자열의 배열을 반환합니다.

var str:String = "bob@example.com, omar@example.org"; 
var pattern:RegExp = /\w*@\w*\.[org|com]+/g; 
var results:Array = str.match(pattern);

results 배열은 다음과 같이 설정됩니다.

["bob@example.com","omar@example.org"]

일반 표현식에 대한 자세한 내용은 일반 표현식 사용을 참조하십시오.

일치하는 하위 문자열 바꾸기

replace() 메서드를 사용하여 다음 예제와 같이 문자열에서 지정된 패턴을 검색하고 지정된 대체 문자열로 일치 항목을 바꿀 수 있습니다.

var str:String = "She sells seashells by the seashore."; 
var pattern:RegExp = /sh/gi; 
trace(str.replace(pattern, "sch")); //sche sells seaschells by the seaschore. 

이 예제에서는 i(ignoreCase) 플래그가 일반 표현식에 설정되어 있으므로 일치 문자열이 대/소문자를 구분하지 않으며, g(global) 플래그가 설정되어 있으므로 여러 일치 항목이 모두 바뀝니다. 자세한 내용은 일반 표현식 사용을 참조하십시오.

대체 문자열에서 다음 $ 대체 코드를 사용할 수 있습니다. 다음 표에 표시된 대체 텍스트는 $대체 코드 위치로 삽입됩니다.

예를 들어 다음 예제에서는 일치 그룹 중 첫 번째 및 두 번째 캡처 항목을 나타내는 $2 및 $1 대체 코드를 사용하는 방법을 보여 줍니다.

var str:String = "flip-flop"; 
var pattern:RegExp = /(\w+)-(\w+)/g; 
trace(str.replace(pattern, "$2-$1")); // flop-flip

함수를 replace() 메서드의 두 번째 매개 변수로 사용할 수도 있습니다. 이 경우 일치하는 텍스트는 반환된 함수 값으로 바뀝니다.

var str:String = "Now only $9.95!"; 
var price:RegExp = /\$([\d,]+.\d+)+/i; 
trace(str.replace(price, usdToEuro)); 
 
function usdToEuro(matchedSubstring:String,                                  capturedMatch1:String,                                  index:int,                                  str:String):String 
{ 
    var usd:String = capturedMatch1; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.853690; 
    var euro:Number = parseFloat(usd) * exchangeRate; 
    const euroSymbol:String = String.fromCharCode(8364); 
    return euro.toFixed(2) + " " + euroSymbol; 
}

함수를 replace() 메서드의 두 번째 매개 변수로 사용할 때 다음 인수가 함수로 전달됩니다.

• 문자열의 일치 부분

• 괄호로 둘러싼 일치 그룹 중 캡처할 항목. 이렇게 전달되는 인수의 수는 괄호로 둘러싼 일치 항목의 수에 따라 달라집니다. 괄호로 둘러싼 일치 항목의 수를 확인하려면 함수 코드 내에서 arguments.length - 3을 확인합니다.

• 문자열에서 검색을 시작할 인덱스 위치

• 전체 문자열