인덱스 배열

Array 인스턴스나 Vector 인스턴스를 만드는 방법에는 몇 가지가 있습니다. 그러나 각 배열 종류를 만드는 방법은 약간 다릅니다.

인덱스 배열에 요소를 추가하는 가장 기본적인 방법은 배열 액세스([]) 연산자를 사용하는 것입니다. 인덱스 배열 요소의 값을 설정하려면 대입문의 왼쪽에 Array 또는 Vector 객체 이름과 인덱스 번호를 사용합니다.

songTitles[5] = "Happy Birthday";

Array 또는 Vector의 해당 인덱스에 요소가 아직 없으면 해당 인덱스가 만들어지고 여기에 값이 저장됩니다. 해당 인덱스에 값이 있으면 새 값이 기존 값을 대체합니다.

Array 객체의 경우 어느 인덱스에나 요소를 만들 수 있습니다. 그러나 Vector 객체의 경우에는 기존 인덱스나 사용 가능한 다음 인덱스에만 값을 할당할 수 있습니다. 사용 가능한 다음 인덱스는 Vector 객체의 length 속성 값과 같습니다. Vector 객체에 새 요소를 추가하는 가장 안전한 방법은 다음 샘플과 같은 코드를 사용하는 것입니다.

myVector[myVector.length] = valueToAdd;

Array 및 Vector 클래스의 push(), unshift() 및 splice() 메서드 세 가지를 사용하여 인덱스 배열에 요소를 삽입할 수 있습니다. push() 메서드는 배열 끝에 하나 이상의 요소를 추가합니다. 즉, push() 메서드를 사용하여 배열에 삽입된 마지막 요소는 최상위 인덱스 번호를 가지게 됩니다. unshift() 메서드는 배열 시작 부분에 하나 이상의 요소를 삽입하며 이 위치의 인덱스 번호는 항상 0입니다. splice() 메서드는 지정된 인덱스 위치의 모든 항목을 배열에 삽입합니다.

다음 예제는 이 세 가지 메서드를 모두 보여 줍니다. planets 배열은 태양에 가까운 순서로 행성의 이름을 저장하기 위해 만들어진 배열입니다. 먼저, push() 메서드가 첫 항목 Mars를 추가하기 위해 호출됩니다. 그 다음, unshift() 메서드가 배열 맨 앞에 있어야 할 항목인 Mercury를 삽입하기 위해 호출됩니다. 마지막으로, splice() 메서드가 Mercury 뒤 및 Mars 앞에 Venus와 Earth 항목을 삽입하기 위해 호출됩니다. splice()에 전달된 첫 번째 인수인 정수 1은 인덱스 1에서 삽입을 시작하도록 지시합니다. splice()로 전달된 두 번째 인수인 정수 0은 삭제해야 할 항목이 없음을 의미합니다. 마지막으로 splice()에 전달된 세 번째 및 네 번째 인수인 Venus 및 Earth는 삽입할 항목입니다.

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

push() 및 unshift() 메서드는 모두 수정된 배열의 길이를 나타내는 부호 없는 정수를 반환합니다. splice() 메서드는 요소를 삽입하기 위해 사용될 때 빈 배열을 반환합니다. 이상해 보이지만 splice() 메서드의 다양한 용도를 생각해 보면 이해할 수 있습니다. splice() 메서드를 사용하여 배열에 요소를 삽입할 수 있을 뿐만 아니라 배열에서 요소를 제거할 수도 있습니다. 요소를 제거하기 위해 사용할 경우 splice() 메서드는 제거된 요소를 포함하는 배열을 반환합니다.

인덱스 배열에서 요소 값을 가져오는 가장 간단한 방법은 배열 액세스([]) 연산자를 사용하는 것입니다. 인덱스 배열 요소의 값을 가져오려면 대입문의 오른쪽에 Array 또는 Vector 객체 이름과 인덱스 번호를 사용합니다.

var myFavoriteSong:String = songTitles[3];

요소가 없는 Array 또는 Vector에서는 값을 가져올 수 없습니다. 이 경우 Array 객체에서는 undefined 값이 반환되고 Vector 객체에서는 RangeError 예외가 발생합니다.

Array 및 Vector 클래스의 pop(), shift() 및 splice() 메서드 세 가지를 사용하여 요소를 제거할 수 있습니다. pop() 메서드는 배열 끝에서 요소를 제거합니다. 즉, 인덱스 번호가 가장 높은 요소를 제거합니다. shift() 메서드는 배열 시작 부분에서 요소를 제거합니다. 즉, 항상 인덱스 번호 0의 위치에 있는 요소를 제거합니다. 요소를 삽입하는 데에도 사용할 수 있는 splice() 메서드는 이 메서드에 전달된 첫 번째 인수에 의해 지정된 인덱스 번호부터 시작하여 임의의 개수의 요소를 제거합니다.

다음 예제에서는 이 세 가지 메서드를 모두 사용하여 Array 인스턴스에서 요소를 제거합니다. oceans라는 Array는 거대한 수역의 이름을 저장하기 위해 만들어진 배열입니다. Array의 일부 이름은 바다가 아닌 호수라서 제거해야 합니다.

먼저, splice() 메서드를 사용하여 Aral 및 Superior 항목을 제거하고 Atlantic 및 Indian 항목을 삽입합니다. splice()에 전달된 첫 번째 인수인 정수 2는 인덱스 2 위치에 있는 목록의 세 번째 항목으로 작업을 시작해야 함을 나타냅니다. 두 번째 인수 2는 두 개의 항목이 제거되어야 함을 나타냅니다. 남은 인수인 Atlantic 및 Indian은 인덱스 2 위치에 삽입할 값입니다.

그 다음, pop() 메서드를 사용하여 배열에서 마지막 요소인 Huron을 제거합니다. 세 번째로 shift() 메서드를 사용하여 배열의 첫 번째 항목인 Victoria를 제거합니다.

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

pop() 및 shift() 메서드는 모두 제거된 항목을 반환합니다. Array 인스턴스의 경우 배열에 모든 데이터 유형의 값을 저장할 수 있으므로 반환 값의 데이터 유형은 Object입니다. Vector 인스턴스의 경우 반환 값의 데이터 유형은 Vector의 기본 유형입니다. splice() 메서드는 제거된 값을 포함하는 Array 또는 Vector를 반환합니다. oceans Array 예제를 변경하여, 다음 예제와 같이 splice()에 대한 호출에서 반환된 Array가 새 Array 변수에 할당되도록 할 수 있습니다.

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

Array 객체 요소에 대해 delete 연산자를 사용하는 코드가 있을 수 있습니다. delete 연산자는 Array 요소 값을 undefined로 설정하지만 Array에서 요소를 제거하지는 않습니다. 예를 들어 다음 코드에서는 oceans Array의 세 번째 요소에 대해 delete 연산자를 사용하지만 Array의 길이는 여전히 5입니다.

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

배열의 length 속성을 사용하여 Array 또는 Vector를 자를 수 있습니다. 인덱스 배열의 length 속성을 배열의 현재 길이보다 작게 설정할 경우, 배열이 잘리고 새 length 값에서 1을 뺀 값보다 큰 인덱스 번호 위치에 저장된 모든 요소가 제거됩니다. 예를 들어 다음 코드와 같이 oceans 배열을 배열 시작 부분에 모든 유효 항목이 오도록 정렬한 경우 length 속성을 사용하여 배열 끝에 있는 항목을 제거할 수 있습니다.

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

reverse(), sort() 및 sortOn() 메서드 세 가지를 사용하면 인덱스 배열을 정렬 또는 역정렬하여 순서를 변경할 수 있습니다. 이 세 가지 메서드는 모두 기존 배열을 수정합니다. 다음 표에는 이러한 메서드와 Array 및 Vector 객체에 대한 메서드 비헤이비어가 요약되어 있습니다.

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

Array 및 Vector 클래스의 concat(), join(), slice() 및 toString() 메서드 네 가지는 배열에서 정보를 쿼리하지만 배열을 수정하지는 않습니다. join() 및 toString() 메서드가 모두 문자열을 반환하는 반면. concat() 및 slice() 메서드는 모두 새 배열을 반환합니다. concat() 메서드는 인수로 요소 목록이나 새 배열을 취하며 이를 기존 배열과 결합하여 새 배열을 만듭니다. slice() 메서드에는 startIndex와 endIndex라는 두 개의 매개 변수가 있으며 기존 배열에서 "분할"된 요소의 복사본이 포함된 새로운 배열을 반환합니다. 분할은 startIndex 위치의 요소에서 시작되어 endIndex 직전 위치에 있는 요소에서 종료됩니다. 즉, endIndex 위치의 요소는 반환 값에 포함되지 않습니다.

다음 예제에서는 다른 배열의 요소를 사용하여 새 배열을 만들기 위해 concat() 및 slice()를 사용합니다.

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

join() 및 toString() 메서드를 사용하여 배열에 쿼리를 실행하고 그 내용을 문자열로 반환할 수 있습니다. join() 메서드에 매개 변수를 사용하지 않는 경우 두 메서드는 동일하게 동작합니다. 즉, 배열에 있는 모든 요소의 목록이 쉼표로 구분되어 포함된 문자열을 반환합니다. toString() 메서드와는 달리 join() 메서드는 delimiter라는 매개 변수를 취하여, 반환된 문자열에서 각 요소 간을 분리하는 데 사용되는 구분 기호를 선택할 수 있습니다.

다음 예제에서는 rivers라는 Array를 만들고 join() 및 toString()을 모두 호출하여 Array의 값을 문자열로 반환합니다. toString() 메서드는 쉼표로 구분된 값(riverCSV)을 반환하는 데 사용되는 반면, join() 메서드는 + 문자로 구분된 값을 반환하는 데 사용됩니다.

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

단, 다음 예제와 같이 중첩된 Array 또는 Vector 인스턴스는 join() 메서드에서 항상 쉼표로 구분된 값으로 반환됩니다. 이때 기본 배열 요소에 지정한 분리 기호는 무시됩니다.

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e