문자열에 일반 표현식을 사용하는 데 필요한 메서드

RegExp 클래스의 test() 메서드는 다음 예제와 같이 제공된 문자열에 일반 표현식에 대해 일치하는 항목이 포함되어 있는지 여부만 확인합니다.

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

RegExp 클래스의 exec() 메서드는 제공된 문자열에 일반 표현식에 대해 일치하는 항목이 포함되어 있는지 확인한 후 다음 항목이 포함된 배열을 반환합니다.

• 일치하는 하위 문자열

• 일반 표현식의 괄호 그룹에 대해 일치하는 하위 문자열

이 배열에는 하위 문자열 일치 항목의 시작 인덱스 위치를 나타내는 index 속성도 포함되어 있습니다.

예를 들어 다음과 같은 코드를 살펴봅니다.

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

일반 표현식에 g ( global ) 플래그가 설정된 경우 하위 문자열을 여러 개 찾으려면 exec() 메서드를 여러 번 사용하십시오.

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

String 클래스의 match() , replace() , search() 및 split() 메서드는 일반 표현식을 매개 변수로 사용합니다. 이러한 메서드에 대한 자세한 내용은 문자열의 패턴 찾기 및 하위 문자열 바꾸기 를 참조하십시오.