동영상 클립 예제: RuntimeAssetsExplorer

탐색기가 SWF 라이브러리와 적절히 상호 작용하려면 런타임 에셋 라이브러리의 구조를 정형화해야 합니다. 이러한 구조는 예상 구조를 보여 주는 메서드의 청사진이라는 점에서 클래스와 유사하지만 클래스와는 다르게 메서드 본문이 포함되지 않은 인터페이스를 만들어 정형화할 수 있습니다. 이 인터페이스는 런타임 라이브러리와 탐색기 모두에 서로 통신할 수 있는 방법을 제공합니다. 브라우저에 로드되는 런타임 에셋의 각 SWF는 이 인터페이스를 구현합니다. 인터페이스 및 그 활용에 대한 자세한 정보는 ActionScript 3.0 학습 에서 인터페이스를 참조하십시오.

RuntimeLibrary 인터페이스는 매우 간단합니다. 심볼을 내보내고 런타임 라이브러리에서 사용할 수 있는 클래스 경로 배열을 탐색기에 제공할 수 있는 함수만 있으면 됩니다. 이 작업을 수행할 수 있도록 인터페이스에 getAssets() 라는 메서드 하나가 있습니다.

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

RuntimeLibrary 인터페이스를 정의하여 다른 SWF 파일로 로드할 수 있는 여러 에셋 라이브러리 SWF 파일을 만들 수 있습니다. 에셋의 개별 SWF 라이브러리를 만들려면 다음 네 가지 작업을 수행해야 합니다.

• 에셋 라이브러리 SWF 파일의 클래스 만들기

• 라이브러리에 포함된 개별 에셋의 클래스 만들기

• 실제 그래픽 에셋 만들기

• 그래픽 요소를 클래스와 연결하고 라이브러리 SWF 제작

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

마지막으로 설명할 기능은 에셋 탐색기의 사용자 인터페이스입니다. 이 예제에서 런타임 라이브러리 경로는 ASSETS_PATH 라는 변수로 하드 코딩되어 있습니다. FileReference 클래스를 사용할 수도 있습니다. 예를 들어, 하드 드라이브에서 특정 SWF 파일을 탐색하는 인터페이스를 만들려는 경우에 FileReference 클래스를 사용합니다.

런타임 라이브러리가 성공적으로 로드되면 Flash Player는 runtimeAssetsLoadComplete() 메서드를 호출합니다.

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

이 메서드에서 변수 rl은 로드된 SWF 파일을 나타냅니다. 코드는 로드된 SWF 파일의 getAssets() 메서드를 호출하고 사용 가능한 에셋 목록을 가져온 다음, 이 에셋을 사용하여 populateDropDown() 메서드 호출로 사용 가능한 에셋 목록을 ComboBox 구성 요소에 채웁니다. 그리고 해당 메서드는 각 에셋의 전체 클래스 경로를 저장합니다. 사용자 인터페이스에서 [추가] 버튼을 클릭하면 addAsset() 메서드가 트리거됩니다.

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

이 메서드는 ComboBox에 현재 선택되어 있는 에셋의 클래스 경로를 가져오고( assetNameCbo.selectedItem.data ), flash.utils 패키지의 getDefinitionByName() 함수를 사용하여 에셋의 클래스에 대한 실제 참조를 가져와 에셋의 새 인스턴스를 만듭니다.