워커 만들기 및 관리

[Embed] 메타태그를 사용하여 워커 swf를 기본 swf 안에 ByteArray로 포함시킵니다.

[Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")] 
private static var BgWorker_ByteClass:Class; 
private function createWorker():void 
{ 
    var workerBytes:ByteArray = new BgWorker_ByteClass(); 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

워커 swf는 기본 swf 내에 BgWorker_ByteClass라는 이름의 ByteArray 하위 클래스로 컴파일됩니다. 이 클래스의 인스턴스를 만들면 워커 swf의 바이트로 미리 채워진 ByteArray가 제공됩니다.

URLLoader 객체를 사용하여 외부 swf 파일을 로드합니다. 이 swf 파일은 동일한 보안 도메인에서 가져와야 합니다. 예를 들면 기본 swf와 같은 인터넷 도메인에서 로드되거나 AIR 응용 프로그램 패키지에 포함되어 있는 swf 파일을 사용해야 합니다.

var workerLoader:URLLoader = new URLLoader(); 
workerLoader.dataFormat = URLLoaderDataFormat.BINARY; 
workerLoader.addEventListener(Event.COMPLETE, loadComplete); 
workerLoader.load(new URLRequest("BgWorker.swf")); 
 
private function loadComplete(event:Event):void 
{ 
    // create the background worker 
    var workerBytes:ByteArray = event.target.data as ByteArray; 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

URLLoader에서 swf 파일의 로드를 마치면 URLLoader 객체의 data 속성(위의 예에서 event.target.data 참조)에서 해당 swf의 바이트를 사용할 수 있습니다.

하나의 swf를 기본 swf 및 워커 swf로 모두 사용할 수 있습니다. 기본 표시 클래스의 loaderInfo.bytes 속성을 사용하여 swf의 바이트에 액세스합니다.

// The primordial worker's main class constructor 
public function PrimordialWorkerClass() 
{ 
    init(); 
} 
 
private function init():void 
{ 
    var swfBytes:ByteArray = this.loaderInfo.bytes; 
     
    // Check to see if this is the primordial worker or the background worker 
    if (Worker.current.isPrimordial) 
    { 
        // create a background worker 
        var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes); 
         
        // ... set up worker communication and start the worker 
    } 
    else // entry point for the background worker 
    { 
        // set up communication between workers using getSharedProperty() 
        // ... (not shown) 
         
        // start the background work 
    } 
}

이 기술을 사용할 경우 if 문을 활용하여 기본 클래스의 생성자 또는 이 생성자가 호출하는 메서드 안에서 swf 파일 코드를 분기하십시오. 해당 코드가 기본 워커 또는 백그라운드 워커 중 어디에서 실행되고 있는지 알려면 위의 예처럼 현재 Worker 객체의 isPrimordial 속성을 확인합니다.