클립보드 데이터 형식

사용자 정의 데이터 형식을 사용하여 클립보드에 객체를 쓸 경우 클립보드에서 해당 객체 데이터를 읽을 때는 참조나 원본 객체의 직렬화된 복사본으로 읽을 수 있습니다. AIR는 객체를 참조 또는 직렬화된 복사본으로 전송할 지 여부를 결정하는 4개의 전송 모드를 정의합니다.

클립보드에 객체를 쓸 때 format 매개 변수에는 예약된 접두어인 air: 또는 flash: 로 시작하지 않는 모든 문자열을 이용할 수 있습니다. 객체를 읽을 형식과 같은 문자열을 사용합니다. 다음 예제에서는 객체를 클립보드에 읽고 쓰는 방법에 대해 설명합니다.

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

드롭 또는 붙여넣기 작업 후 Clipboard 객체에서 직렬화된 객체를 추출하려면 동일한 형식 이름과 CLONE_ONLY 또는 CLONE_PREFFERED 전송 모드를 사용합니다.

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

참조는 항상 Clipboard 객체에 추가됩니다. 드롭 또는 붙여넣기 작업 후에 Clipboard 객체에서 참조를 추출하려면 직렬화된 복사본 대신 ORIGINAL_ONLY 또는 ORIGINAL_PREFFERED 전송 모드를 사용합니다.

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Clipboard 객체가 현재 응용 프로그램에서 발생한 경우에만 참조가 유효합니다. ORIGINAL_PREFFERED 전송 모드를 사용하여 참조가 사용 가능할 때 참조에 액세스하고 참조가 사용 가능하지 않을 때 직렬화된 클론에 액세스합니다.

다음 예제에서는 지연된 렌더링 함수를 구현하는 방법에 대해 설명합니다.

사용자가 복사 버튼을 누르면 응용 프로그램에서는 이전 클립보드 작업에서 복사된 데이터가 남아 있지 않도록 시스템 클립보드를 지웁니다. 그런 다음 setDataHandler() 메서드가 renderData() 함수를 클립보드 렌더러로 설정합니다.

사용자가 대상 텍스트 필드의 컨텍스트 메뉴에서 붙여넣기 명령을 선택하면 응용 프로그램에서는 클립보드에 액세스하여 대상 텍스트를 설정합니다. 문자열 대신 함수를 사용하여 클립보드의 텍스트 데이터 형식을 설정한 후에는 클립보드에서 renderData() 함수가 호출됩니다. renderData() 함수는 소스 텍스트의 텍스트를 반환하고 이 텍스트가 대상 텍스트에 할당됩니다.

[붙여넣기] 버튼을 누르기 전에 소스 텍스트를 편집하는 경우 [복사] 버튼을 누른 후에 편집이 발생하더라도 붙여넣은 텍스트에서 편집이 반영됩니다. 이는 붙여넣기 버튼을 누를 때까지 렌더링 함수가 소스 텍스트를 복사하지 않기 때문입니다. 실제 응용 프로그램에서 지연된 렌더링을 사용할 때 이 문제를 방지하기 위해 어떤 식으로든 소스 데이터를 저장하거나 보호할 수 있습니다.

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>