実装の概要

Flash Builder で、CreateCorrespondence プロジェクトをパッケージエクスプローラービューで開きます。

CreateCorrespondence/src/com.adobe.solutions.cmg.Create Correspondence/presentation に移動します。

SaveAsDraftActionHandler などの ActionScript クラスを作成します。このクラスは、com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler クラスを拡張します。新しく追加されたアクションをサポートするには、次の 2 つが必要です。

1. 新しく追加されたアクションを有効／無効にするロジック。actionEnabled(extraParams:Object=null):Boolean 関数をオーバーライドします。

2. ユーザーがボタンをクリックするときのアクションの処理（handleAction(extraParams:Object=null):void 関数の実装をオーバーライドする場合）。

   次の例は、CCRDefaultActionHandler を拡張するcom.adobe.solutions.cmg.ccr.presentation.SaveAsDraftActionHandler のサンプル実装です。

   package com.adobe.solutions.cmg.ccr.presentation 
   { 
       import com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler; 
       import com.adobe.icc.external.dc.ExternalApi; 
       import com.adobe.icc.external.dc.InvokeParams; 
       import com.adobe.icc.services.ServiceProvider; 
       import com.adobe.icc.services.submit.ISubmitService; 
       import com.adobe.icc.util.Debug; 
       import com.adobe.icc.util.UrlHelper; 
        
       import flash.net.URLRequest; 
       import flash.net.navigateToURL; 
        
           import mx.controls.Alert; 
       import mx.rpc.events.FaultEvent; 
       import mx.rpc.events.ResultEvent; 
       import mx.utils.ObjectUtil; 
        
       public class SaveAsDraftActionHandler extends CCRDefaultActionHandler 
       { 
           public static const SAVE_AS_DRAFT_ACTION:String = "SaveAsDraft"; 
            
           public function SaveAsDraftActionHandler() 
           { 
               super(); 
               var htmlUrl:String = ExternalApi.getInstance().htmlGetUrl(); 
               Debug.info("invoke url: " + htmlUrl); 
               invokeParams = new InvokeParams(htmlUrl); 
                
           } 
            
           /** 
            * Called when the user clicks an action 
            * @param extraParams additional arguments that may be passed to handler (For future use) 
            * 
            */ 
           override public function handleAction(extraParams:Object=null):void 
           { 
               if(action && action.name == SAVE_AS_DRAFT_ACTION) 
               { 
                   //Additional logic to show popup to ask file save name goes here. 
                   var saveName:String = letterVO.name; 
                   submitLetter(saveName); 
               } 
           } 
            
           [Bindable(event="actionEnabledChange")] 
           /** 
            * Should the action be enabled in toolbar 
            * @param extraParams 
            * @return flag indicating whether the action should be enabled 
            * 
            */ 
           override public function actionEnabled(extraParams:Object=null):Boolean 
           { 
               //Always enable the Action. 
               return true; 
           } 
            
           private function submitLetter(saveName: String):void 
           { 
               var service:ISubmitService = ServiceProvider.getSubmitService(); 
                
               var params:Object = new Object(); 
               if(action.actionConfig) 
                   params = ObjectUtil.copy(action.actionConfig); 
               params["cm_actionName"] = action.name; 
               //Add additional custom params here which is available under <icc:meta> tag. 
               params["cm_saveName"] = saveName; 
                
               var reload:Boolean = false; 
               if(!(invokeParams.letterId) && !(invokeParams.letterName)) 
               { 
                   //If Letter is loaded without letterName or letterId then it must be reload 
                   reload = true; 
               } 
               //Invoke the default letter post process 
               service.submitLetterWithParams(letterVO, letterData, 
                   false, invokeParams.useLatest, reload, null, params).addHandlers 
                   ( 
                       // result handler 
                       function(event:ResultEvent):void 
                       { 
                           var response:Object = event.result as Object; 
                           //Redirect to success page if mentioned 
                           if (response.redirect) 
                           { 
                               // redirect via new window or else the user is prompted to close the DC window before proceeding 
                               if (UrlHelper.isValid(response.redirect)) 
                                   navigateToURL((new URLRequest(response.redirect)), "_blank"); 
                               else 
                                   Debug.error("server returned invalid redirect URL: " + response.redirect); 
                           } 
                                                   Alert.show("Save Successful"); 
                       }, 
                       // fault handler 
                       function(event:FaultEvent):void 
                       { 
                           Debug.error("failed to submit " + letterVO + ":\n\t", event); 
                                                   Alert.show("Save Failed"); 
    
                       } 
                   ); 
                
           } 
       } 
   }

CreateCorrespondence/src/com.adobe.solutions.cmg.Create Correspondence/presentation/CCRApplication.as ファイルで、タイプ SaveAsDraftActionHandle のプライベート変数を宣言します。この変数は、新しいクラスが FlashBuilder で確実にコンパイルされるようにします。

private var saveActionHandler:SaveAsDraftActionHandler;

ソリューションテンプレートを再構築および再デプロイして変更を確認します。再構築および再デプロイについては、Solution Template の構築とデプロイを参照してください。