クラス

ActionScript 3.0 には、クラス内で定義されたプロパティへのアクセスを制御する 4 つの特別な属性、 public 、 private 、 protected 、および internal があります。

public 属性は、スクリプト内の任意の場所でプロパティを表示します。例えば、パッケージ外部のコードでメソッドを使用するには、 public 属性でメソッドを宣言する必要があります。これは、宣言されたキーワードが var 、 const 、 function のいずれであるかにかかわらず、あらゆるプロパティに当てはまります。

private 属性は、プロパティが定義されたクラス内の呼び出し元に対してのみプロパティを表示します。このビヘイビアーは、サブクラスがスーパークラスのプライベートプロパティにアクセスできる ActionScript 2.0 の private 属性とは異なります。ランタイムアクセスに関しても、ビヘイビアーが大きく変更されています。 ActionScript 2.0 では、 private キーワードによりアクセスが禁止されるのはコンパイル時のみで、実行時にはアクセスが禁止されません。ActionScript 3.0 では、これは当てはまりません。 private とマークされたプロパティは、コンパイル時も実行時も使用することができません。

例えば、次のコードは、プライベート変数を 1 つ持つ PrivateExample という単純なクラスを作成し、クラス外部からこのプライベート変数にアクセスしようとします。

class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // ActionScript 2.0 allows access, but in ActionScript 3.0, this is a run-time error. 

ActionScript 3.0 では、ドット演算子（ myExample.privVar ）を使用してプライベートプロパティにアクセスしようとすると、strict モードを使用している場合にコンパイル時エラーになります。それ以外の場合は、プロパティアクセス演算子（ myExample["privVar"] ）を使用するときと同様に、エラーは実行時に報告されます。

次の表に、sealed（dynamic ではない）クラスに属するプライベートプロパティにアクセスしようとした結果の概要を示します。

dynamic 属性で宣言されたクラスでは、プライベート変数にアクセスしようとしても、ランタイムエラーにはなりません。ただし、変数が参照不可になるため、 undefined という値が返されます。しかし、strict モードでドット演算子を使用すると、コンパイル時エラーが発生します。 次の例は、PrivateExample クラスがダイナミッククラスとして宣言されている点を除き、前の例と同じです。

dynamic class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // output: undefined

通常、ダイナミッククラスは、クラス外部のコードがプライベートプロパティにアクセスしようとすると、エラーを生成するのではなく、戻り値として undefined を返します。次の表は、ドット演算子を使用して strict モードでプライベートプロパティにアクセスしようとしたときにのみエラーが生成されることを示します。

ActionScript 3.0 で新しく導入された protected 属性は、クラス内またはサブクラス内の呼び出し元に対してプロパティを表示します。つまり、protected プロパティは、そのクラス内または継承階層内でそのクラスの下の任意の場所にあるクラスで使用することができます。 これは、サブクラスが同じパッケージ内にあるか別のパッケージ内にあるかに関係なく、同じです。

ActionScript 2.0 に詳しいユーザーにとっては、この機能は ActionScript 2.0 の private 属性とほぼ同じです。また、ActionScript 3.0 の protected 属性は Java の protected 属性とほぼ同じですが、Java のこの属性は同じパッケージ内の呼び出し元へのアクセスも許可するという点で異なります。ただし、Java では、この属性は同じパッケージ内の呼び出し元へのアクセスも許可するという点で異なります。 protected 属性は、サブクラスで必要なメソッドまたは変数を継承チェーン外部のコードに対して非表示にするときに便利です。

ActionScript 3.0 で新しく導入された internal 属性は、パッケージ内にある呼び出し元に対してプロパティを表示します。これはパッケージ内のコードのデフォルト属性であり、次のいずれの属性も持たないあらゆるプロパティに適用されます。

• public

• private

• protected

• ユーザー定義の名前空間

internal 属性は、Java のデフォルトのアクセス制御に似ています。ただし、Java ではこのレベルのアクセスに明示的な名前はなく、他のアクセス修飾子が省略された場合にのみ、このデフォルトのアクセス制御が使用されます。 internal 属性は ActionScript 3.0 で使用可能で、パッケージ内の呼び出し元に対してのみプロパティを表示する意図を明示的に表すオプションがあります。

static 属性は、 var 、 const 、または function キーワードで宣言されたプロパティと共に使用でき、クラスのインスタンスではなくクラスにプロパティを関連付けることができます。クラス外にあるコードは、インスタンス名ではなくクラス名を使用して静的プロパティを呼び出す必要があります。

静的プロパティはサブクラスに継承されませんが、サブクラスのスコープチェーンの一部です。つまり、サブクラスの本体内では、静的変数またはメソッドは、定義されたクラスを参照しなくても使用できます。

事前に定義されているアクセス制御属性の代わりに、属性として使用するカスタム名前空間を作成できます。 1 つの定義に使用できる名前空間属性は 1 つだけです。また、名前空間属性をアクセス制御属性（ public 、 private 、 protected 、 internal ）と組み合わせて使用することはできません。

単にコンストラクターと呼ばれることもあるコンストラクターメソッドは、定義されたクラスと同じ名前を共有する関数です。コンストラクターメソッドに含まれるコードは、クラスのインスタンスが new キーワードで作成されるときに実行されます。例えば、次のコードは、 status という名前のプロパティを 1 つ含む単純なクラス Example を定義します。 status 変数の初期値は、コンストラクター関数内で設定します。

class Example 
{ 
    public var status:String; 
    public function Example() 
    { 
        status = "initialized"; 
    } 
} 
 
var myExample:Example = new Example(); 
trace(myExample.status); // output: initialized

コンストラクターメソッドにはパブリックだけを指定できますが、 public 属性を使用するかどうかは任意です。コンストラクターに、 private 、 protected 、 internal やその他のアクセス制御指定子を使用することはできません。また、ユーザー定義の名前空間をコンストラクターメソッドで使用することもできません。

コンストラクターは、 super() ステートメントを使用して直接のスーパークラスのコンストラクターを明示的に呼び出すことができます。スーパークラスのコンストラクターを明示的に呼び出さない場合は、コンパイラーによってコンストラクター本体の最初のステートメントの前に呼び出しが自動的に挿入されます。 スーパークラスへの参照として super 接頭辞を使用し、スーパークラスのメソッドを呼び出すこともできます。同じコンストラクター本体で super() と super を使用する場合は、必ず最初に super() を呼び出します。そうしないと、 super 参照が意図したとおりに動作しません。 super() コンストラクターも、 throw または return ステートメントの前に呼び出す必要があります。

次に、 super() コンストラクターを呼び出す前に super 参照を使用しようとした場合の例を示します。新しいクラス ExampleEx は Example クラスを拡張します。 ExampleEx コンストラクターは、 super() を呼び出す前に、スーパークラスで定義された status 変数にアクセスしようとします。ExampleEx コンストラクター内の trace() ステートメントは、値 null を生成します。これは、 super() コンストラクターが実行されるまで status 変数を使用できないからです。

class ExampleEx extends Example 
{ 
    public function ExampleEx() 
    { 
        trace(super.status); 
        super(); 
    } 
} 
 
var mySample:ExampleEx = new ExampleEx(); // output: null

コンストラクター内で return ステートメントを使用することはできますが、値を返すことはできません。つまり、 return ステートメントに式または値を関連付けることはできません。したがって、コンストラクターメソッドは値を返すことができず、戻り値の型を指定できません。

クラスでコンストラクターメソッドを定義しなかった場合、コンパイラーが自動的に空のコンストラクターを作成します。クラスが別のクラスを拡張する場合、コンパイラーには、そのコンパイラーが生成するコンストラクター内の super() 呼び出しが含まれます。

静的メソッドは、クラスメソッドとも呼ばれ、 static キーワードで宣言されたメソッドです。静的メソッドは、クラスのインスタンスではなくクラスに関連付けられ、個々のインスタンスの状態以外のものに影響を与える機能のカプセル化に役立ちます。 静的メソッドはクラス全体に関連付けられるため、クラスのインスタンスではなくクラスからのみアクセスできます。

静的メソッドは、クラスインスタンスの状態に影響を与えるだけではない機能のカプセル化に役立ちます。 つまり、メソッドにクラスインスタンスの値に直接影響しない機能がある場合、そのメソッドは静的です。 例えば、Date クラスには、ストリングを取得して数値に変換する parse() という静的メソッドがあります。このメソッドは、クラスの個々のインスタンスに影響を与えないため静的です。 parse() メソッドは、日付値を表すストリングを取得し、そのストリングを解析して、Date オブジェクトの内部表現と互換性がある形式で数値を返します。このメソッドは、Date クラスのインスタンスに適用しても意味がないため、インスタンスメソッドではありません。

静的な parse() メソッドと、 getMonth() などの Date クラスのインスタンスメソッドを比較してみます。 getMonth() メソッドは、Date インスタンスの特定のコンポーネント月を取得することで、インスタンスの値に対して直接実行されるため、インスタンスメソッドです。

静的メソッドは個々のインスタンスにバインドされていないので、静的メソッドの本体内で this または super キーワードを使用できません。 this 参照と super 参照は、インスタンスメソッドのコンテキスト内でのみ有効です。

他のクラスベースのプログラミング言語とは異なり、ActionScript 3.0 では静的メソッドは継承されません。

インスタンスメソッドは、 static キーワードを使用せずに宣言されたメソッドです。インスタンスメソッドは、クラス全体ではなくクラスのインスタンスに関連付けられ、クラスの個々のインスタンスに影響を与える機能の実装に役立ちます。 例えば、Array クラスには、Array インスタンスに直接実行される sort() という名前のインスタンスメソッドが含まれています。

インスタンスメソッドの本体内では、静的変数およびインスタンス変数はスコープ内にあります。つまり、同じクラス内で定義された変数は、単純な識別子を使用して参照できます。 例えば、次の CustomArray クラスは Array クラスを拡張します。 CustomArray クラスは、クラスインスタンスの総数を追跡する静的変数 arrayCountTotal 、インスタンスが作成された順序を追跡するインスタンス変数 arrayNumber 、およびこれらの変数の値を返すインスタンスメソッド getPosition() を定義します。

public class CustomArray extends Array 
{ 
    public static var arrayCountTotal:int = 0; 
    public var arrayNumber:int; 
 
    public function CustomArray() 
    { 
        arrayNumber = ++arrayCountTotal; 
    } 
     
    public function getArrayPosition():String 
    { 
         return ("Array " + arrayNumber + " of " + arrayCountTotal); 
    } 
}

クラス外部にあるコードは、 CustomArray.arrayCountTotal を使用して、クラスオブジェクトから arrayCountTotal 静的変数にアクセスする必要がありますが、 getPosition() メソッドの本体内にあるコードは、 arrayCountTotal 静的変数を直接参照できます。これは、スーパークラスの静的変数でも同じです。 ActionScript 3.0 では静的プロパティは継承されませんが、スーパークラスの静的プロパティはスコープ内です。 例えば、Array クラスにはいくつかの静的変数があり、そのうちの 1 つは DESCENDING という定数です。Array サブクラス内にあるコードは、単純な識別子を使用して静的定数 DESCENDING にアクセスできます。

public class CustomArray extends Array 
{ 
    public function testStatic():void 
    { 
        trace(DESCENDING); // output: 2 
    } 
}

インスタンスメソッドの本体内の this 参照の値は、メソッドが関連付けられているインスタンスへの参照です。次のコードは、 this 参照がメソッドを含むインスタンスを参照していることを示します。

class ThisTest 
{ 
    function thisValue():ThisTest 
    { 
        return this; 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
trace(myTest.thisValue() == myTest); // output: true

インスタンスメソッドの継承は、 override キーワードと final キーワードを使用して制御できます。 override 属性を使用して、継承されたメソッドを再定義できます。また、 final 属性を使用して、サブクラスによってメソッドがオーバーライドされないようにできます。

getter および setter とも呼ばれる get および set アクセッサー関数を使用すると、作成したクラスの使いやすいプログラミングインターフェイスを提供すると同時に、情報の非表示およびカプセル化というプログラミング原則に従うことができます。get および set 関数を使用して、クラスプロパティをクラスに対してプライベートに保持できますが、クラスのユーザーは、クラスメソッドを呼び出すのではなくクラス変数にアクセスしている場合と同じように、これらのプロパティにアクセスできます。

この方法の利点は、 getPropertyName() 、 setPropertyName() など、従来の冗長な名前のアクセッサー関数を使用する必要がないことです。また、getter および setter には、読み取りおよび書き込みアクセスを可能にする各プロパティに対して 2 つの公開関数を持つ必要がないという利点もあります。

次の例の GetSet クラスには、 privateProperty という名前のプライベート変数へのアクセスを提供する publicAccess() という名前の get および set アクセッサー関数が含まれています。

class GetSet 
{ 
    private var privateProperty:String; 
     
    public function get publicAccess():String 
    { 
        return privateProperty; 
    } 
     
    public function set publicAccess(setValue:String):void 
    { 
        privateProperty = setValue; 
    } 
}

privateProperty プロパティに直接アクセスしようとすると、次のエラーが発生します。

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.privateProperty); // error occurs

代わりに、GetSet クラスを使用する場合は、 publicAccess というプロパティのように見えて、実際には privateProperty という名前のプライベートプロパティに対して動作する get および set アクセッサー関数のペアを使用します。次の例では、GetSet クラスをインスタンス化し、 publicAccess という名前のパブリックアクセッサーを使用して privateProperty の値を設定します。

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.publicAccess); // output: null 
myGetSet.publicAccess = "hello"; 
trace(myGetSet.publicAccess); // output: hello

getter および setter 関数でも、スーパークラスから継承されるプロパティをオーバーライドできますが、通常のクラスメンバー変数を使用したときにはオーバーライドできません。 var キーワードで宣言されたクラスメンバー変数は、サブクラスではオーバーライドできません。一方、getter および setter 関数を使用して作成されたプロパティにはこの制限はありません。 スーパークラスから継承した getter 関数と setter 関数に override 属性を使用できます。

バインドメソッドは、メソッドクロージャとも呼ばれ、単にインスタンスから抽出されるメソッドです。バインドメソッドの例には、関数にパラメーターとして渡され、関数から値として返されるメソッドがあります。 ActionScript 3.0 で新しく導入されたバインドメソッドは、インスタンスから抽出されたときでもレキシカル環境が保持されるメソッドクロージャに似ています。 バインドメソッドとメソッドクロージャの主な違いは、バインドメソッドの this 参照は、バインドメソッドを実装するインスタンスにリンクされたまま、つまりバインドされたままであるという点です。つまり、バインドメソッドの this 参照が、常にこのメソッドを実装する元のオブジェクトを指していることを意味します。関数クロージャの場合、 this 参照は汎用です。つまり、この関数が呼び出された時点で関連付けられているオブジェクトが何であっても、そのオブジェクトを参照します。

this キーワードを使用する場合は、バインドメソッドを理解していることが重要です。 this キーワードを使用すれば、メソッドの親オブジェクトを参照できます。ほとんどの ActionScript プログラマーは、 this キーワードが常にメソッドの定義を含むオブジェクトまたはクラスを表すと考えますが、メソッドのバインディングがないと必ずしもそうなりません。 旧バージョンの ActionScript では、例えば、 this 参照はメソッドを実装するインスタンスを常に参照するわけではありませんでした。ActionScript 2.0 でインスタンスからメソッドを抽出すると、 this 参照が元のインスタンスにバインドされないだけでなく、インスタンスのクラスのメンバー変数もメソッドも使用できません。ActionScript 3.0 では、メソッドをパラメーターとして渡すとバインドメソッドが自動的に作成されるため、これは問題にはなりません。 バインドメソッドにより、 this キーワードは常に、メソッドが定義されたオブジェクトまたはクラスを参照します。

次のコードは、ThisTest というクラスを定義します。このクラスには、バインドメソッドを定義するメソッド foo() 、およびバインドメソッドを返すメソッド bar() が含まれます。クラス外部にあるコードは、ThisTest クラスのインスタンスを作成し、 bar() メソッドを呼び出して、 myFunc という変数に戻り値を格納します。

class ThisTest 
{ 
    private var num:Number = 3; 
    function foo():void // bound method defined 
    { 
        trace("foo's this: " + this); 
        trace("num: " + num); 
    } 
    function bar():Function 
    { 
        return foo; // bound method returned 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
var myFunc:Function = myTest.bar(); 
trace(this); // output: [object global] 
myFunc(); 
/* output:  
foo's this: [object ThisTest] 
output: num: 3 */

コードの最後の 2 行は、バインドメソッド foo() の this 参照が、その直前の行の this 参照がグローバルオブジェクトを指していても、依然として ThisTest クラスのインスタンスを指すことを示しています。さらに、 myFunc 変数に格納されているバインドメソッドは、引き続き ThisTest クラスのメンバー変数にアクセスできます。この同じコードを ActionScript 2.0 で実行すると、 this 参照が一致し、 num 変数は undefined になります。

addEventListener() メソッドでは関数またはメソッドをパラメーターとして渡す必要があるため、バインドメソッドの追加が最もわかりやすいのはイベントハンドラーを使用する場合です。

アセットを埋め込むには、まずアセットを FLA ファイルのライブラリに保存します。次に、アセットのリンケージプロパティを使用して、アセットの埋め込みアセットクラスの名前を指定します。 その名前のクラスがクラスパスに見つからない場合、クラスは自動的に生成されます。 これにより、埋め込みアセットクラスのインスタンスを作成し、そのクラスによって定義または継承された任意のプロパティとメソッドを使用できるようになります。 例えば、次のコードを使用して、PianoMusic という名前の埋め込みアセットクラスにリンクされた埋め込みサウンドを再生できます。

var piano:PianoMusic = new PianoMusic(); 
var sndChannel:SoundChannel = piano.play();

または、次で説明するとおり、 [Embed] メタデータタグを使用して Flash Professional プロジェクトにアセットを埋め込むこともできます。コード内に [Embed] メタデータタグがあると、プロジェクトのコンパイル時に、Flash Professional コンパイラーではなく Flex コンパイラーが使用されます。

Flex コンパイラーを使用してコードをコンパイルする場合、アセットを ActionScript コードに埋め込むには、 [Embed] メタデータタグを使用します。メインソースフォルダーか、プロジェクトのビルドパスにある別のフォルダーにアセットを配置します。Flex コンパイラーによって Embed メタデータタグが検出されると、埋め込みアセットクラスが作成されます。このクラスには、 [Embed] メタデータタグの直後に宣言するデータ型クラスの変数からアクセスします。例えば、次のコードでは sound1.mp3and というサウンドを埋め込み、 soundCls という変数を使用して、そのサウンドに関連付けられている埋め込みアセットクラスに参照を保存します。 次に、埋め込みアセットクラスのインスタンスを作成して、そのインスタンスの play() メソッドを呼び出します。

package 
{ 
    import flash.display.Sprite; 
    import flash.media.SoundChannel; 
    import mx.core.SoundAsset; 
 
    public class SoundAssetExample extends Sprite 
    { 
        [Embed(source="sound1.mp3")] 
        public var soundCls:Class; 
         
        public function SoundAssetExample() 
        { 
            var mySound:SoundAsset = new soundCls() as SoundAsset; 
            var sndChannel:SoundChannel = mySound.play(); 
        } 
    } 
}