シェーダーのロードまたは埋め込み

実行時にロード：シェーダーファイルは URLLoader オブジェクトを使用して外部アセットとしてロードできます。この方法はテキストファイルなどの外部アセットをロードすることと似ています。次の例は、シェーダーバイトコードファイルを実行時にロードし、それを Shader インスタンスにリンクする方法を示しています。

var loader:URLLoader = new URLLoader(); 
loader.dataFormat = URLLoaderDataFormat.BINARY; 
loader.addEventListener(Event.COMPLETE, onLoadComplete); 
loader.load(new URLRequest("myShader.pbj")); 
 
var shader:Shader; 
 
function onLoadComplete(event:Event):void { 
    // Create a new shader and set the loaded data as its bytecode 
    shader = new Shader(); 
    shader.byteCode = loader.data; 
     
    // You can also pass the bytecode to the Shader() constructor like this: 
    // shader = new Shader(loader.data); 
     
     // do something with the shader 
}

SWF ファイルに埋め込む：シェーダーファイルは [Embed] メタタグを使用してコンパイル時に SWF ファイルに埋め込むことができます。 [Embed] メタデータタグは、Flex SDK を使用して SWF ファイルをコンパイルした場合にのみ使用できます。この例では、 [Embed] タグの source パラメーターがシェーダーファイルを指定し、 mimeType パラメーターは、「 application/octet-stream 」となります。

[Embed(source="myShader.pbj", mimeType="application/octet-stream")] 
var MyShaderClass:Class; 
 
// ... 
 
// create a shader and set the embedded shader as its bytecode 
var shader:Shader = new Shader(); 
shader.byteCode = new MyShaderClass(); 
 
// You can also pass the bytecode to the Shader() constructor like this: 
// var shader:Shader = new Shader(new MyShaderClass()); 
 
// do something with the shader