ActionScript 内の XML の例：インターネットからの RSS データのロード

RSSParser クラスには、rssXML 変数に保存されている入力 RSS データを HTML 形式の出力を含むストリングである rssOutput に変換する xmlLoaded() メソッドがあります。

ソース RSS データにデフォルトの名前空間が含まれている場合にデフォルトの XML 名前空間を設定するコードが、メソッドの先頭近くにあります。

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

次の行は、ソース XML データの内容でループし、item という子孫のプロパティを確認します。

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

最初の 3 行は、XML データの item プロパティの title、description、および link プロパティを表すストリング変数を単純に設定しています。次の行は、3 つの新しいストリング変数をパラメーターとして使用して buildItemHTML() メソッドを呼び出し、XMLList オブジェクトの形式で HTML データを取得しています。

HTML データ（XMLList オブジェクト）の形式は、次のとおりです。

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

メソッドの最初の行で、デフォルトの xml 名前空間を消去します。

default xml namespace = new Namespace();

default xml namespace ディレクティブのスコープは、関数ブロックレベルです。すなわち、この宣言のスコープは buildItemHTML() メソッドです。

次の行で、関数に渡されたストリング引数に基づいて、XMLList を構成します。

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

この XMLList オブジェクトは、ActionScript HTML テキストフィールドに適したストリングデータを表します。

xmlLoaded() メソッドは、buildItemHTML() メソッドの戻り値を使用して、ストリングに変換します。

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

xmlLoaded() メソッドは、ソース RSS XML データの情報に基づいて、 rssTitle ストリング変数を設定します。

rssTitle = rssXML.channel.title.toString();

最後に、xmlLoaded() メソッドが、データが解析され使用可能になったことをアプリケーションに通知するイベントを生成します。

            dataWritten = new Event("dataWritten", true);