ビデオ再生の制御

NetStream クラスは、ビデオ再生を制御する 4 つの主な方法を提供します。

pause()：ビデオストリームの再生を停止します。ビデオが既に停止している場合は、このメソッドを呼び出しても何も実行されません。

resume()：停止中のビデオストリームの再生を再開します。ビデオが既に再生中である場合は、このメソッドを呼び出しても何も実行されません。

seek()：指定された場所（ストリームの先頭からの秒単位のオフセット）に最も近いキーフレームをシークします。

togglePause()：ストリームの再生を停止または再開します。

次の例は、様々なボタンを使用してビデオを制御する方法を示します。 次の例を実行するには、新しいドキュメントを作成し、ワークスペース内に pauseBtn、playBtn、stopBtn および togglePauseBtn の 4 つのボタンインスタンスを追加します。

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 
ns.play("video.flv"); 
function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
    // ignore error 
} 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid); 
 
pauseBtn.addEventListener(MouseEvent.CLICK, pauseHandler); 
playBtn.addEventListener(MouseEvent.CLICK, playHandler); 
stopBtn.addEventListener(MouseEvent.CLICK, stopHandler); 
togglePauseBtn.addEventListener(MouseEvent.CLICK, togglePauseHandler); 
 
function pauseHandler(event:MouseEvent):void 
{ 
    ns.pause(); 
} 
function playHandler(event:MouseEvent):void 
{ 
    ns.resume(); 
} 
function stopHandler(event:MouseEvent):void 
{ 
    // Pause the stream and move the playhead back to 
    // the beginning of the stream. 
    ns.pause(); 
    ns.seek(0); 
} 
function togglePauseHandler(event:MouseEvent):void 
{ 
    ns.togglePause(); 
}

ビデオの再生中に pauseBtn ボタンインスタンスをクリックすると、ビデオファイルが一時停止します。ビデオが既に一時停止状態にある場合、このボタンインスタンスをクリックしても何も効果がありません。 再生が一時停止状態にある場合に playBtn ボタンインスタンスをクリックすると、ビデオ再生が再開されます。ビデオが既に再生中であれば、何も効果がありません。