ネットワーキングとコミュニケーションの基礎

NetworkInfo オブジェクトを使用すると、アプリケーションで使用できるハードウェアおよびソフトウェアのネットワークインターフェイスを検出できます。NetworkInfo オブジェクトは「シングルトン」オブジェクトで、作成する必要はありません。代わりに、静的クラスプロパティ networkInfo を使用して、NetworkInfo シングルトンオブジェクトにアクセスします。また、NetworkInfo オブジェクトは、使用可能なインターフェイスのいずれかが変更されると、 networkChange イベントを送出します。

NetworkInterface オブジェクトのリストを取得するには、 findInterfaces() メソッドを呼び出します。リストには NetworkInterface オブジェクトごとに、使用可能なインターフェイスの 1 つが記載されています。NetworkInterface オブジェクトでは、IP アドレス、ハードウェアアドレス、最大転送ユニット、インターフェイスの稼働状況などに関する情報を提供します。

次のコード例では、クライアントコンピューター上で各インターフェイスの NetworkInterface プロパティをトレースします。

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

詳しくは、以下を参照してください。

• NetworkInfo

• NetworkInterface

• InterfaceAddress

• Flexpert：Detecting the network connection type with Flex 4.5

AIR アプリケーションは、ネットワーク接続が一定ではなく変化する環境で実行できます。アプリケーションでオンラインリソースに対する接続を管理できるように、Adobe AIR では、ネットワーク接続が使用できるようになったり使用できなくなったりするたびにネットワーク変更イベントが送信されます。NetworkInfo オブジェクトおよびアプリケーションの NativeApplication オブジェクトは両方とも networkChange イベントを送出します。このイベントに対処するには、リスナーを追加します。

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

さらに、イベントハンドラー関数を定義します。

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

networkChange イベントは、ネットワーク活動全体の変更ではなく、個々のネットワーク接続の変更のみを示します。AIR では、ネットワークが変更された意味については解釈されません。ネットワークに接続されたコンピューターには実際の接続や仮想接続が多数存在できるので、1 つの接続が切断されても必ずしもリソースが失われるわけではありません。一方、新しい接続でも、リソースの可用性の向上が保証されるわけではありません。新しい接続によって、それまで使用できていたリソースへのアクセスがブロックされることもあります（例えば、VPN に接続する場合など）。

一般に、アプリケーションでリモートリソースに接続できるかどうかを確認するには、試してみるしかありません。サービス監視フレームワークには、特定のホストに対するネットワーク接続が変更された場合に、イベントに基づいて応答する方法が用意されています。

DNS リソースレコードのルックアップには、DNSResolver クラスを使用できます。DNS リソースレコードでは、ドメイン名の IP アドレスまたは IP アドレスのドメイン名のような情報を提供します。ルックアップ可能な DNS リソースレコードのタイプを以下に示します。

• ARecord - ホストの IPv4 アドレス

• AAAARecord - ホストの IPv6 アドレス

• MXRecord - ホストのメール交換レコード

• PTRRecord - IP アドレスのホスト名

• SRVRecord - サービスのサービスレコード

レコードをルックアップするには、クエリ文字列とレコードタイプを表すクラスオブジェクトを DNSResolver オブジェクトの lookup() メソッドに渡します。使用するクエリ文字列はレコードタイプによって異なります。

次のコード例では、ホスト "example.com" の IP アドレスをルックアップします。

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

詳しくは、以下を参照してください。

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord