AIR のタスクバーアイコン

コマンドを格納する NativeMenu オブジェクトを作成し、そのオブジェクトを NativeApplication.nativeApplication.icon.menu プロパティに割り当てることで、標準のドックメニューにコマンドを追加することができます。メニューのアイテムは、標準のドックアイコンメニューアイテムの上に表示されます。

NativeApplication.nativeApplication.icon.bounce() メソッドを呼び出すことにより、ドックアイコンをバウンスさせることができます。 bounce() priority パラメーターを informational に設定すると、アイコンが 1 回バウンスします。critical に設定すると、ユーザーがアプリケーションをアクティブにするまでアイコンがバウンスします。 priority パラメーターの定数は、NotificationType クラスで定義されています。

ドックアイコンがクリックされると、NativeApplication オブジェクトから invoke イベントが送出されます。アプリケーションが実行されていない場合は、システムによってアプリケーションが起動されます。それ以外の場合は、 invoke イベントは実行中のアプリケーションインスタンスに送られます。

NativeMenu オブジェクトを作成し、そのオブジェクトを NativeApplication.nativeApplication.icon.menu プロパティに割り当てることで、システムトレイアイコンにメニューを追加することができます（オペレーティングシステムのデフォルトのメニューはありません）。システムトレイアイコンのメニューにアクセスするには、アイコンを右クリックします。

アイコンにツールチップを追加するには、tooltip プロパティを設定します。

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

NativeApplication.nativeApplication.icon プロパティによって参照される SystemTrayIcon オブジェクトから、 click 、 mouseDown 、 mouseUp 、 rightClick 、 rightMouseDown 、 rightMouseUp の各イベントに対して ScreenMouseEvent が送出されます。これらのイベントをアイコンメニューと一緒に使用すると、アプリケーションに可視のウィンドウがない場合にユーザーがそのアプリケーションを操作できるようになります。

次の例では、システムトレイアイコンがあり、可視のウィンドウはない AIR アプリケーションを作成します（アプリケーションの visible プロパティは、アプリケーション記述で true に設定しないようにする必要があります。さもなければ、アプリケーションの起動時にウィンドウが表示されます）。

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

ウィンドウがバックグラウンドで実行されているときに、ウィンドウに関連するイベントが発生したことをユーザーに通知することができます。Mac OS X では、アプリケーションドックアイコンをバウンスさせてユーザーに通知できます（ ドックのバウンス の説明を参照）。Windows および Linux では、NativeWindow インスタンスの notifyUser() メソッドを呼び出すと、そのウィンドウに対応するタスクバーボタンが強調表示されます。メソッドに渡される type パラメーターによって、通知の緊急度が決まります。

• NotificationType.CRITICAL ：ユーザーがウィンドウを前面に表示するまでウィンドウアイコンが点滅します。

• NotificationType.INFORMATIONAL ：別の色でウィンドウアイコンが強調表示されます。

  注意： Linux では、サポートされている通知の種類は INFORMATIONAL のみです。 notifyUser() 関数にどの type 値を渡しても同じ効果になります。

  次のステートメントでは、ウィンドウのタスクバーボタンを強調表示します。

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  ウィンドウレベルの通知がサポートされていないオペレーティングシステムでは、 NativeWindow.notifyUser() メソッドを呼び出しても効果はありません。ウィンドウの通知がサポートされているかどうかを確認するには、 NativeWindow.supportsNotification プロパティを使用します。

Windows オペレーティングシステムでは、 utility または lightweight のタイプで作成されたウィンドウはタスクバーに表示されません。また、不可視のウィンドウもタスクバーに表示されません。

初期ウィンドウのタイプは必ず normal であるため、ウィンドウがタスクバーに表示されないアプリケーションを作成するには、初期ウィンドウを閉じるか、不可視のままにしておく必要があります。アプリケーションを終了しないでアプリケーションのすべてのウィンドウを閉じるには、最後のウィンドウを閉じる前に、NativeApplication オブジェクトの autoExit プロパティを false に設定します。単に初期ウィンドウが可視にならないようにするには、 <visible>false</visible> をアプリケーション記述ファイルの <initalWindow> エレメントに追加します（さらに、 visible プロパティを true に設定したり、ウィンドウの activate() メソッドを呼び出したりしないようにします）。

アプリケーションで開かれる新しいウィンドウでは、ウィンドウコンストラクターに渡される NativeWindowInitOption オブジェクトの type プロパティを NativeWindowType.UTILITY または NativeWindowType.LIGHTWEIGHT に設定します。

Mac OS X では、最小化されたウィンドウはドックタスクバーに表示されます。最小化されたアイコンが表示されないようにするには、ウィンドウを最小化するのではなく非表示にします。次の例では、 nativeWindowDisplayState 変更イベントをリッスンし、ウィンドウが最小化される場合にキャンセルします。その代わりに、ハンドラーでウィンドウの visible プロパティを false に設定します。

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

visible プロパティを false に設定している場合に Mac OS X ドックでウィンドウが最小化されても、ドックアイコンが削除されるわけではありません。ユーザーは、引き続きアイコンをクリックしてウィンドウを再表示することができます。