AIR ミュージックストアアプリケーションでは、リモート SWF ファイルでアルバムの価格をブロードキャストできるようにする必要がありますが、リモート SWF ファイルでその価格が販売価格かどうかを公開しないようにする必要があるとします。この場合、StoreAPI クラスのメソッドを使用して、価格を取得しても販売価格は公開されないようにします。次に、この StoreAPI クラスのインスタンスが、リモート SWF を読み込む Loader オブジェクトの LoaderInfo オブジェクトの
parentSandboxBridge
プロパティに割り当てられます。
AIR ミュージックストアのコードを次に示します。
<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" title="Music Store" creationComplete="initApp()">
<mx:Script>
import flash.display.Loader;
import flash.net.URLRequest;
private var child:Loader;
private var isSale:Boolean = false;
private function initApp():void {
var request:URLRequest =
new URLRequest("http://[www.yourdomain.com]/PriceQuoter.swf")
child = new Loader();
child.contentLoaderInfo.parentSandboxBridge = new StoreAPI(this);
child.load(request);
container.addChild(child);
}
public function getRegularAlbumPrice():String {
return "$11.99";
}
public function getSaleAlbumPrice():String {
return "$9.99";
}
public function getAlbumPrice():String {
if(isSale) {
return getSaleAlbumPrice();
}
else {
return getRegularAlbumPrice();
}
}
</mx:Script>
<mx:UIComponent id="container" />
</mx:WindowedApplication>
StoreAPI オブジェクトはメインアプリケーションを呼び出して通常のアルバム価格を取得しますが、
getSaleAlbumPrice()
メソッドが呼び出されると、「Not available」を返します。次のコードでは、StoreAPI クラスを定義します。
public class StoreAPI
{
private static var musicStore:Object;
public function StoreAPI(musicStore:Object)
{
this.musicStore = musicStore;
}
public function getRegularAlbumPrice():String {
return musicStore.getRegularAlbumPrice();
}
public function getSaleAlbumPrice():String {
return "Not available";
}
public function getAlbumPrice():String {
return musicStore.getRegularAlbumPrice();
}
}
次のコードは、ストアの価格を報告しても、販売価格は報告できない PriceQuoter SWF ファイルの例を表しています。
package
{
import flash.display.Sprite;
import flash.system.Security;
import flash.text.*;
public class PriceQuoter extends Sprite
{
private var storeRequester:Object;
public function PriceQuoter() {
trace("Initializing child SWF");
trace("Child sandbox: " + Security.sandboxType);
storeRequester = loaderInfo.parentSandboxBridge;
var tf:TextField = new TextField();
tf.autoSize = TextFieldAutoSize.LEFT;
addChild(tf);
tf.appendText("Store price of album is: " + storeRequester.getAlbumPrice());
tf.appendText("\n");
tf.appendText("Sale price of album is: " + storeRequester.getSaleAlbumPrice());
}
}
}
