ワーカーの作成と管理

[Embed] メタタグを使用して、ワーカー SWF を ByteArray としてメイン SWF に埋め込みます。

[Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")] 
private static var BgWorker_ByteClass:Class; 
private function createWorker():void 
{ 
    var workerBytes:ByteArray = new BgWorker_ByteClass(); 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

ワーカー SWF は、BgWorker_ByteClass という名前の ByteArray サブクラスとして、メイン SWF 内部にコンパイルされます。このクラスのインスタンスを作成することで、ワーカー SWF のバイトデータが事前に設定された状態の ByteArray を取得できます。

URLLoader オブジェクトを使用して、外部 SWF ファイルをロードします。この SWF ファイルは、メイン SWF と同じインターネットドメインからロードした SWF ファイル、AIR アプリケーションパッケージに含まれる SWF ファイルなど、同じセキュリティドメインにある必要があります。

var workerLoader:URLLoader = new URLLoader(); 
workerLoader.dataFormat = URLLoaderDataFormat.BINARY; 
workerLoader.addEventListener(Event.COMPLETE, loadComplete); 
workerLoader.load(new URLRequest("BgWorker.swf")); 
 
private function loadComplete(event:Event):void 
{ 
    // create the background worker 
    var workerBytes:ByteArray = event.target.data as ByteArray; 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

URLLoader で SWF ファイルのロードが完了すれば、SWF のバイトデータを URLLoader オブジェクトの data プロパティ（例では event.target.data ）で取得できます。

1 つの SWF を、メイン SWF とワーカー SWF の両方として使用できます。メイン表示クラスの loaderInfo.bytes プロパティを使用して、SWF のバイトデータにアクセスします。

// The primordial worker's main class constructor 
public function PrimordialWorkerClass() 
{ 
    init(); 
} 
 
private function init():void 
{ 
    var swfBytes:ByteArray = this.loaderInfo.bytes; 
     
    // Check to see if this is the primordial worker or the background worker 
    if (Worker.current.isPrimordial) 
    { 
        // create a background worker 
        var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes); 
         
        // ... set up worker communication and start the worker 
    } 
    else // entry point for the background worker 
    { 
        // set up communication between workers using getSharedProperty() 
        // ... (not shown) 
         
        // start the background work 
    } 
}

このテクニックを使用する場合、メインクラスのコンストラクター内部か、呼び出すメソッド内部で、 if 文を使用して SWF ファイルのコードを分岐します。実行中のコードがメインワーカー内にあるかバックグラウンドワーカー内にあるかを判定するには、例に示すとおり、現在の Worker オブジェクトの isPrimordial プロパティを確認します。