ComboBox コンポーネントの使用

次の例では、ActionScript を使用して ComboBox を作成し、サンフランシスコおよびカリフォルニアの地域にある大学のリストを設定します。 ComboBox の width プロパティはプロンプトに表示するテキストの幅に合わせて設定され、 dropdownWidth プロパティは最も長い大学の名前よりも若干広く設定されます。

この例では、Array インスタンス内に大学のリストを作成します。 label プロパティを使用して学校の名前を格納し、 data プロパティを使用して各学校の Web サイトの URL を格納します。この Array は、 dataProvider プロパティを設定することで ComboBox に割り当てられます。

ユーザーがリストから大学を選択すると、Event. CHANGE イベントおよび changeHandler() 関数の呼び出しがトリガーされ、学校の Web サイトにアクセスするために data プロパティが URL 要求にロードされます。

最後の行では、リストを閉じたときにプロンプトを再表示するために、ComboBox インスタンスの selectedIndex プロパティを -1 に設定しています。この設定がないと、プロンプトは選択された学校の名前に置き換えられます。

1. 新しい Flash (ActionScript 3.0) ドキュメントを作成します。

2. ComboBox コンポーネントをコンポーネントパネルからライブラリパネルにドラッグします。

3. アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.controls.ComboBox; 
   import fl.data.DataProvider; 
   import flash.net.navigateToURL; 
    
   var sfUniversities:Array = new Array( 
       {label:"University of California, Berkeley",  
                   data:"http://www.berkeley.edu/"}, 
       {label:"University of San Francisco",  
                   data:"http://www.usfca.edu/"}, 
       {label:"San Francisco State University",  
                   data:"http://www.sfsu.edu/"}, 
       {label:"California State University, East Bay",  
                   data:"http://www.csuhayward.edu/"}, 
       {label:"Stanford University", data:"http://www.stanford.edu/"}, 
       {label:"University of Santa Clara", data:"http://www.scu.edu/"}, 
       {label:"San Jose State University", data:"http://www.sjsu.edu/"} 
   ); 
    
   var aCb:ComboBox = new ComboBox(); 
   aCb.dropdownWidth = 210; 
   aCb.width = 200;  
   aCb.move(150, 50); 
   aCb.prompt = "San Francisco Area Universities"; 
   aCb.dataProvider = new DataProvider(sfUniversities); 
   aCb.addEventListener(Event.CHANGE, changeHandler); 
    
   addChild(aCb); 
    
   function changeHandler(event:Event):void { 
       var request:URLRequest = new URLRequest(); 
       request.url = ComboBox(event.target).selectedItem.data; 
       navigateToURL(request); 
       aCb.selectedIndex = -1; 
   }

4. 制御／ムービープレビューを選択します。

この例は Flash オーサリング環境に実装して実行できますが、ComboBox でアイテムをクリックして大学の Web サイトにアクセスしようとすると、警告メッセージが表示されます。 インターネットから ComboBox の機能に完全にアクセスするには、次の URL を参照してください。

http://www.helpexamples.com/peter/bayAreaColleges/bayAreaColleges.html