SQL データベースでの暗号化の使用

Flex の例

アプリケーションの MXML ファイルには、暗号化されたデータベースに対する接続を作成する（開く）単純なアプリケーションのソースコードが含まれています。

<?xml version="1.0" encoding="utf-8"?> 
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical" creationComplete="init();"> 
    <mx:Script> 
        <![CDATA[ 
            import com.adobe.air.crypto.EncryptionKeyGenerator; 
             
            private const dbFileName:String = "encryptedDatabase.db"; 
             
            private var dbFile:File; 
            private var createNewDB:Boolean = true; 
            private var conn:SQLConnection; 
             
            // ------- Event handling ------- 
             
            private function init():void 
            { 
                conn = new SQLConnection(); 
                dbFile = File.applicationStorageDirectory.resolvePath(dbFileName); 
                if (dbFile.exists) 
                { 
                    createNewDB = false; 
                    instructions.text = "Enter your database password to open the encrypted database."; 
                    openButton.label = "Open Database"; 
                } 
            } 
             
            private function openConnection():void 
            { 
                var password:String = passwordInput.text; 
                 
                var keyGenerator:EncryptionKeyGenerator = new EncryptionKeyGenerator(); 
                 
                if (password == null || password.length <= 0) 
                { 
                    statusMsg.text = "Please specify a password."; 
                    return; 
                } 
                 
                if (!keyGenerator.validateStrongPassword(password)) 
                { 
                    statusMsg.text = "The password must be 8-32 characters long. It must contain at least one lowercase letter, at least one uppercase letter, and at least one number or symbol."; 
                    return; 
                } 
                 
                passwordInput.text = ""; 
                passwordInput.enabled = false; 
                openButton.enabled = false; 
                 
                var encryptionKey:ByteArray = keyGenerator.getEncryptionKey(password); 
                 
                conn.addEventListener(SQLEvent.OPEN, openHandler); 
                conn.addEventListener(SQLErrorEvent.ERROR, openError); 
                  
                conn.openAsync(dbFile, SQLMode.CREATE, null, false, 1024, encryptionKey); 
            } 
             
            private function openHandler(event:SQLEvent):void 
            { 
                conn.removeEventListener(SQLEvent.OPEN, openHandler); 
                conn.removeEventListener(SQLErrorEvent.ERROR, openError); 
                  
                statusMsg.setStyle("color", 0x009900); 
                if (createNewDB) 
                { 
                    statusMsg.text = "The encrypted database was created successfully."; 
                } 
                else 
                { 
                    statusMsg.text = "The encrypted database was opened successfully."; 
                } 
            } 
              
            private function openError(event:SQLErrorEvent):void 
            { 
                conn.removeEventListener(SQLEvent.OPEN, openHandler); 
                conn.removeEventListener(SQLErrorEvent.ERROR, openError); 
     
                if (!createNewDB && event.error.errorID == EncryptionKeyGenerator.ENCRYPTED_DB_PASSWORD_ERROR_ID) 
                { 
                    statusMsg.text = "Incorrect password!"; 
                } 
                else 
                { 
                    statusMsg.text = "Error creating or opening database."; 
                } 
            } 
        ]]> 
    </mx:Script> 
    <mx:Text id="instructions" text="Enter a password to create an encrypted database. The next time you open the application, you will need to re-enter the password to open the database again." width="75%" height="65"/> 
    <mx:HBox> 
        <mx:TextInput id="passwordInput" displayAsPassword="true"/> 
        <mx:Button id="openButton" label="Create Database" click="openConnection();"/> 
    </mx:HBox> 
    <mx:Text id="statusMsg" color="#990000" width="75%"/> 
</mx:WindowedApplication>

Flash Professional の例

アプリケーションの FLA ファイルには、暗号化されたデータベースに対する接続を作成する（開く）単純なアプリケーションのソースコードが含まれています。FLA ファイルのステージ上には、次に示す 4 個のコンポーネントが配置されています。

アプリケーションのコードは、メインタイムラインのフレーム 1 にあるキーフレーム上に定義されています。アプリケーションのコードを次に示します。

import com.adobe.air.crypto.EncryptionKeyGenerator; 
     
const dbFileName:String = "encryptedDatabase.db"; 
     
var dbFile:File; 
var createNewDB:Boolean = true; 
var conn:SQLConnection; 
     
init(); 
     
// ------- Event handling ------- 
     
function init():void 
{ 
    passwordInput.displayAsPassword = true; 
    openButton.addEventListener(MouseEvent.CLICK, openConnection); 
    statusMsg.setStyle("textFormat", new TextFormat(null, null, 0x990000)); 
     
    conn = new SQLConnection(); 
    dbFile = File.applicationStorageDirectory.resolvePath(dbFileName); 
     
    if (dbFile.exists) 
    { 
        createNewDB = false; 
        instructions.text = "Enter your database password to open the encrypted database."; 
        openButton.label = "Open Database"; 
    } 
    else 
    { 
        instructions.text = "Enter a password to create an encrypted database. The next time you open the application, you will need to re-enter the password to open the database again."; 
        openButton.label = "Create Database"; 
    } 
} 
     
function openConnection(event:MouseEvent):void 
{ 
    var keyGenerator:EncryptionKeyGenerator = new EncryptionKeyGenerator(); 
     
    var password:String = passwordInput.text; 
     
    if (password == null || password.length <= 0) 
    { 
        statusMsg.text = "Please specify a password."; 
        return; 
    } 
     
    if (!keyGenerator.validateStrongPassword(password)) 
    { 
        statusMsg.text = "The password must be 8-32 characters long. It must contain at least one lowercase letter, at least one uppercase letter, and at least one number or symbol."; 
        return; 
    } 
     
    passwordInput.text = ""; 
    passwordInput.enabled = false; 
    openButton.enabled = false; 
     
    var encryptionKey:ByteArray = keyGenerator.getEncryptionKey(password); 
     
    conn.addEventListener(SQLEvent.OPEN, openHandler); 
    conn.addEventListener(SQLErrorEvent.ERROR, openError); 
     
    conn.openAsync(dbFile, SQLMode.CREATE, null, false, 1024, encryptionKey); 
} 
     
function openHandler(event:SQLEvent):void 
{ 
    conn.removeEventListener(SQLEvent.OPEN, openHandler); 
    conn.removeEventListener(SQLErrorEvent.ERROR, openError); 
     
    statusMsg.setStyle("textFormat", new TextFormat(null, null, 0x009900)); 
    if (createNewDB) 
    { 
        statusMsg.text = "The encrypted database was created successfully."; 
    } 
    else 
    { 
        statusMsg.text = "The encrypted database was opened successfully."; 
    } 
} 
 
function openError(event:SQLErrorEvent):void 
{ 
    conn.removeEventListener(SQLEvent.OPEN, openHandler); 
    conn.removeEventListener(SQLErrorEvent.ERROR, openError); 
     
    if (!createNewDB && event.error.errorID == EncryptionKeyGenerator.ENCRYPTED_DB_PASSWORD_ERROR_ID) 
    { 
        statusMsg.text = "Incorrect password!"; 
    } 
    else 
    { 
        statusMsg.text = "Error creating or opening database."; 
    } 
}

アプリケーションの HTML ファイルには、暗号化されたデータベースに対する接続を作成する（開く）単純なアプリケーションのソースコードが含まれています。

<html> 
    <head> 
        <title>Encrypted Database Example (HTML)</title> 
        <style type="text/css"> 
            body 
            { 
                padding-top: 25px; 
                font-family: Verdana, Arial; 
                font-size: 14px; 
            } 
            div 
            { 
                width: 85%; 
                margin-left: auto; 
                margin-right: auto; 
            } 
            .error {color: #990000} 
            .success {color: #009900} 
        </style> 
         
        <script type="text/javascript" src="AIRAliases.js"></script> 
        <script type="application/x-shockwave-flash" src="EncryptionKeyGenerator.swf"/> 
        <script type="text/javascript"> 
            // set up the class shortcut 
            var ekg; 
            if (window.runtime) 
            { 
                if (!ekg) ekg = {}; 
                ekg.EncryptionKeyGenerator = window.runtime.com.adobe.air.crypto.EncryptionKeyGenerator; 
            } 
             
            // app globals 
            var dbFileName = "encryptedDatabase.db"; 
            var dbFile; 
            var createNewDB = true; 
            var conn; 
             
            // UI elements 
            var instructions; 
            var passwordInput; 
            var openButton; 
            var statusMsg; 
             
            function init() 
            { 
                // UI elements 
                instructions = document.getElementById("instructions"); 
                passwordInput = document.getElementById("passwordInput"); 
                openButton = document.getElementById("openButton"); 
                statusMsg = document.getElementById("statusMsg"); 
             
                conn = new air.SQLConnection(); 
                dbFile = air.File.applicationStorageDirectory.resolvePath(dbFileName); 
                if (dbFile.exists) 
                { 
                    createNewDB = false; 
                    instructions.innerHTML = "<p>Enter your database password to open the encrypted database.</p>"; 
                    openButton.value = "Open Database"; 
                } 
            } 
             
            function openConnection() 
            { 
                var keyGenerator = new ekg.EncryptionKeyGenerator(); 
                 
                var password = passwordInput.value; 
                 
                if (password == null || password.length <= 0) 
                { 
                    statusMsg.innerHTML = "<p class='error'>Please specify a password.</p>"; 
                    return; 
                } 
                 
                if (!keyGenerator.validateStrongPassword(password)) 
                { 
                    statusMsg.innerHTML = "<p class='error'>The password must be 8-32 characters long. It must contain at least one lowercase letter, at least one uppercase letter, and at least one number or symbol.</p>"; 
                    return; 
                } 
                 
                passwordInput.value = ""; 
                passwordInput.disabled = true; 
                openButton.disabled = true; 
                statusMsg.innerHTML = ""; 
                 
                var encryptionKey = keyGenerator.getEncryptionKey(password); 
                 
                conn.addEventListener(air.SQLEvent.OPEN, openHandler); 
                conn.addEventListener(air.SQLErrorEvent.ERROR, openError); 
                 
                conn.openAsync(dbFile, air.SQLMode.CREATE, null, false, 1024, encryptionKey); 
            } 
             
            function openHandler(event) 
            { 
                conn.removeEventListener(air.SQLEvent.OPEN, openHandler); 
                conn.removeEventListener(air.SQLErrorEvent.ERROR, openError); 
                 
                if (createNewDB) 
                { 
                    statusMsg.innerHTML = "<p class='success'>The encrypted database was created successfully.</p>"; 
                } 
                else 
                { 
                    statusMsg.innerHTML = "<p class='success'>The encrypted database was opened successfully.</p>"; 
                } 
            } 
             
            function openError(event) 
            { 
                conn.removeEventListener(air.SQLEvent.OPEN, openHandler); 
                conn.removeEventListener(air.SQLErrorEvent.ERROR, openError); 
                 
                if (!createNewDB && event.error.errorID == ekg.EncryptionKeyGenerator.ENCRYPTED_DB_PASSWORD_ERROR_ID) 
                { 
                    statusMsg.innerHTML = "<p class='error'>Incorrect password!</p>"; 
                } 
                else 
                { 
                    statusMsg.innerHTML = "<p class='error'>Error creating or opening database.</p>"; 
                } 
            } 
        </script> 
    </head> 
     
    <body onload="init();"> 
        <div id="instructions"><p>Enter a password to create an encrypted database. The next time you open the application, you will need to re-enter the password to open the database again.</p></div> 
        <div><input id="passwordInput" type="password"/><input id="openButton" type="button" value="Create Database" onclick="openConnection();"/></div> 
        <div id="statusMsg"></div> 
    </body> 
</html>