JavaScript 開発者のための ActionScript の基礎

ActionScript は、JavaScript と同じ ECMAScript 言語仕様に基づいています。したがって、両言語の基本的シンタックスは共通しています。例えば、次のコードは JavaScript でも ActionScript でも同様に機能します。

var str1 = "hello"; 
var str2 = " world."; 
var str = reverseString(str1 + str2); 
     
function reverseString(s) { 
    var newString = ""; 
    var i; 
    for (i = s.length - 1; i >= 0; i--) { 
        newString += s.charAt(i); 
    } 
    return newString; 
}

しかし、これら 2 つの言語のシンタックスと機能には相違点もあります。例えば、前述のコード例は ActionScript 3.0（SWF ファイル）で次のように記述することもできます。

function reverseString(s:String):String { 
    var newString:String = ""; 
    for (var i:int = s.length - 1; i >= 0; i--) { 
        newString += s.charAt(i); 
    } 
    return newString; 
}

Adobe AIR の HTML コンテンツでサポートされる JavaScript のバージョンは JavaScript 1.7 です。このトピックでは、JavaScript 1.7 と ActionScript 3.0 の違いについて説明します。

ランタイムには、高度な機能を提供するビルトインクラスがあります。HTML ページの JavaScript から、実行時にこれらのクラスにアクセスできます。これらのランタイムクラスは、ActionScript（SWF ファイル）と JavaScript（ブラウザーで実行される HTML ファイル）の両方で使用できます。ただし、現在、これらのクラスの API ドキュメント（『 HTML 開発者用 Adobe AIR API リファレンスガイド 』には含まれていません）では、ActionScript のシンタックスを使用して説明されています。このため、ランタイムの高度な機能の一部については、『 Adobe Flash Platform 用 ActionScript 3.0 リファレンスガイド 』を参照してください。ActionScript に関する基礎知識は、JavaScript におけるこれらのランタイムクラスの使用方法を理解するのに役立ちます。

例として、MP3 ファイルのサウンドを再生する JavaScript コードを次に示します。

var file = air.File.userDirectory.resolve("My Music/test.mp3"); 
var sound = air.Sound(file); 
sound.play();

これらの各コード行では、JavaScript のランタイム機能が呼び出されます。

SWF ファイルでは、次に示す ActionScript コードでこれらのランタイム機能にアクセスできます。

var file:File = File.userDirectory.resolve("My Music/test.mp3"); 
var sound = new Sound(file); 
sound.play();

ActionScript 3.0 は、 厳密な型指定 を行う言語です。つまり、1 つの変数に 1 つのデータ型を割り当てることができます。例えば、前述の例の第 1 行は次のように記述することもできます。

var str1:String = "hello";

ここでは、 str1 変数が String 型として宣言されています。後続のすべての str1 変数には、ストリング値が割り当てられます。

変数、関数のパラメーター、関数の戻り値の型に対して、型を割り当てることができます。したがって、前述の例における関数の宣言を ActionScript で記述すると次のようになります。

function reverseString(s:String):String { 
       var newString:String = ""; 
       for (var i:int = s.length - 1; i >= 0; i--) { 
           newString += s.charAt(i); 
       } 
       return newString; 
}

ActionScript では型指定を省略できますが、次のようにオブジェクトの型を宣言することによる利点もあります。

• オブジェクトが型指定されていると、実行時だけでなく、厳密モードによるコンパイル時にもデータの型チェックが行われます。コンパイル時の型チェックはエラーの特定に役立ちます（厳密モードはコンパイラーのオプションです）。

• 型指定されたオブジェクトを使用すると、効率性の高いアプリケーションを作成できます。

  このため、ActionScript マニュアルの例ではデータ型が使用されています。多くの場合、型宣言（" :String "）を削除するだけで、ActionScript のコード例を JavaScript に変換できます。

function exampleFunction(n:*):* { 
       trace("hi, " + n); 
}

ActionScript 3.0 には、JavaScript 1.7 に存在しないクラスに関する機能が含まれています。

public class ExampleClass { 
    public var x:Number; 
    public function ExampleClass(input:Number):void { 
        x = input; 
    } 
    public function greet():void { 
        trace("The value of x is: ", x); 
    } 
}

flash.filesystem.File

var myFile = new air.flash.filesystem.File();

ActionScript 3.0 でも JavaScript でも、関数にパラメーターを含めることができます。ActionScript 3.0 のパラメーターは、必須の場合とオプションの場合があります。これに対して、JavaScript のパラメーターは常にオプションです。

次の ActionScript 3.0 コードで定義される関数では、 n が必須パラメーターです。

function cube(n:Number):Number { 
    return n*n*n; 
}

次の ActionScript 3.0 コードで定義される関数では、 n が必須パラメーターです。また、 p はオプションのパラメータで、デフォルト値は 1 です。

function root(n:Number, p:Number = 1):Number { 
    return Math.pow(n, 1/p); 
}

ActionScript 3.0 関数では、任意の数の引数を受け取ることもできます。その場合、次に示すように、パラメーターのリストの末尾に ...rest シンタックスで記述します。

function average(... args) : Number{ 
    var sum:Number = 0; 
    for (var i:int = 0; i < args.length; i++) { 
        sum += args[i]; 
    } 
    return (sum / args.length); 
}

ActionScript 3.0 のプログラミングでは、すべてのイベントを イベントリスナー で処理します。イベントリスナーは関数です。オブジェクトからイベントが送出されると、イベントリスナーがイベントに応答します。ActionScript オブジェクトの一種であるイベントは、関数のパラメータとしてイベントリスナーに渡されます。このようなイベントオブジェクトの使用方法は、JavaScript で使用される DOM イベントモデルとは異なります。

例えば、Sound オブジェクトの load() メソッドを（MP3 ファイルを読み込むために）呼び出すと、Sound オブジェクトはサウンドの読み込みを試みます。Sound オブジェクトは、その後で、次に示すイベントのいずれかを送出します。

イベントを送出できるクラスは、EventDispatcher クラスを拡張するか、IEventDispatcher インターフェイスを実装します（ActionScript 3.0 インターフェイスは、クラスで実装可能な一連のメソッドの定義に使用するデータ型です）。『ActionScript リファレンスガイド』のこれらのクラスの項目には、各クラスで送出可能なイベントの一覧が記載されています。

これらのイベントを処理するイベントリスナー関数を登録するには、イベントを送出するオブジェクトの addEventListener() メソッドを使用します。例えば Sound オブジェクトの場合、次の ActionScript コードに示すように、 progress イベントと complete イベントを登録できます。

var sound:Sound = new Sound(); 
var urlReq:URLRequest = new URLRequest("test.mp3"); 
sound.load(urlReq); 
sound.addEventListener(ProgressEvent.PROGRESS, progressHandler); 
sound.addEventListener(Event.COMPLETE, completeHandler); 
 
function progressHandler(progressEvent):void { 
      trace("Progress " + progressEvent.bytesTotal + " bytes out of " + progressEvent.bytesTotal); 
} 
 
function completeHandler(completeEvent):void { 
      trace("Sound loaded."); 
}

AIR で実行する HTML コンテンツで、JavaScript 関数をイベントリスナーとして登録できます。次のコードはこの例を示しています（ここでは、HTML ドキュメントに progressTextArea という名前の TextArea オブジェクトが含まれていると仮定しています）。

var sound = new runtime.flash.media.Sound(); 
var urlReq = new runtime.flash.net.URLRequest("test.mp3"); 
sound.load(urlReq); 
sound.addEventListener(runtime.flash.events.ProgressEvent.PROGRESS, progressHandler); 
sound.addEventListener(runtime.flash.events.Event.COMPLETE, completeHandler); 
 
function progressHandler(progressEvent) { 
      document.progressTextArea.value += "Progress " + progressEvent.bytesTotal + " bytes out of " + progressEvent.bytesTotal; 
} 
 
function completeHandler(completeEvent) { 
      document.progressTextArea.value += "Sound loaded.";