Metodi di impiego di espressioni regolari con stringhe

Flash Player 9 e versioni successive, Adobe AIR 1.0 e versioni successive

La classe RegExp comprende due metodi: exec() e test() .

Oltre ai metodi exec() e test() della classe RegExp, la classe String comprende i metodi seguenti per cercare espressioni regolari nelle stringhe: match() , replace() , search() e splice() .

Metodo test()

Il metodo test() della classe RegExp verifica se la stringa contiene una corrispondenza dell'espressione regolare, come illustra l'esempio seguente:

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

Metodo exec()

Il metodo exec() della classe RegExp verifica se la stringa contiene una corrispondenza dell'espressione regolare e restituisce un array con:

  • La sottostringa di cui si è trovata la corrispondenza

  • Sottostringhe che contengono corrispondenze ai gruppi parentetici dell'espressione regolare

L'array comprende anche la proprietà index , che indica la posizione di indice dell'inizio della corrispondenza nella sottostringa.

Consideriamo l'esempio del codice seguente:

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

Usate il metodo exec() più volte per cercare più sottostringhe quando il flag g ( global ) è impostato nell'espressione regolare:

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

Metodi della classe String che usano parametri RegExp

I seguenti metodi della classe String accettano le espressioni regolari come parametri: match() , replace() , search() e split() . Per ulteriori informazioni su questi modelli, vedete Ricerca di modelli nelle stringhe e sostituzione di sottostringhe .