Formati di dati degli Appunti

Quando un oggetto viene scritto negli Appunti utilizzando un formato di dati personalizzato, i dati dell'oggetto possono essere letti dagli Appunti come riferimento oppure come copia serializzata dell'oggetto originale. AIR definisce quattro modalità di trasferimento che determinano se gli oggetti vengono trasferiti come riferimenti o come copie serializzate:

Per la scrittura di un oggetto negli Appunti, potete utilizzare qualsiasi stringa che non inizia con i prefissi riservati air: o flash: per il parametro format . Utilizzate la stessa stringa come formato per leggere l'oggetto. Nell'esempio seguente viene illustrato come leggere e scrivere oggetti negli Appunti:

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Per estrarre un oggetto serializzato dagli Appunti dopo un'operazione di rilascio o di incolla, utilizzate lo stesso nome formato e le modalità di trasferimento CLONE_ONLY o CLONE_PREFFERED .

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

Viene sempre aggiunto un riferimento all'oggetto Clipboard. Per estrarre il riferimento dall'oggetto Clipboard dopo un'operazione di trascinamento o di incolla, invece della copia serializzata, utilizzate le modalità di trasferimento ORIGINAL_ONLY o ORIGINAL_PREFFERED :

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

I riferimenti sono validi solo se l'oggetto Clipboard ha origine nell'applicazione corrente. Se il riferimento è disponibile, per accedervi utilizzate la modalità di trasferimento ORIGINAL_PREFFERED ; in caso contrario, utilizzate il clone serializzato.

Nell'esempio illustrato di seguito viene mostrato come implementare una funzione di rendering differito.

Quando l'utente fa clic sul pulsante Copia, l'applicazione svuota gli appunti di sistema per assicurarsi che non rimanga alcun dato di una precedente operazione sugli appunti. Il metodo setDataHandler() , quindi, imposta la funzione renderData() come renderer degli Appunti.

Quando l'utente seleziona il comando Incolla dal menu di scelta rapida del campo di testo di destinazione, l'applicazione accede agli appunti e imposta il testo di destinazione. Poiché il formato di dati del testo sugli appunti è stato impostato con una funzione anziché con una stringa, gli appunti chiamano la funzione renderData() . La funzione renderData() restituirà quindi il testo nel testo di origine, che viene quindi assegnato al testo di destinazione.

Si noti che se si modifica il testo di origine prima di premere il pulsante Paste, la modifica verrà applicata nel testo incollato, anche se si verifica dopo che è stato premuto il pulsante di copia. La ragione è che la funzione di rendering non consente di copiare il testo di origine fino a quando non viene premuto il pulsante per incollare. Per impedire tale problema, quando si utilizza il rendering differito in un'applicazione reale è possibile archiviare o proteggere i dati di origine in qualche modo.

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>