Usare il componente Slider

Quando un'istanza Slider è attiva, potete utilizzare i seguenti tasti per controllarla:

Per ulteriori informazioni sul controllo dell'attivazione, vedete l'interfaccia IFocusManager e la classe FocusManager nella Guida di riferimento di ActionScript 3.0 per Flash Professional e Operazioni con FocusManager .

Nell'anteprima dal vivo di ogni istanza del componente Slider vengono visualizzate le modifiche apportate durante la creazione ai parametri nella finestra di ispezione Proprietà o nella finestra di ispezione dei componenti.

I seguenti parametri di creazione possono essere impostati per ogni istanza del componente Slider nella finestra di ispezione Proprietà o nella finestra di ispezione dei componenti: direction , liveDragging , maximum , minimum , snapInterval , tickInterval e value . Ciascuno di questi parametri ha una proprietà ActionScript corrispondente con lo stesso nome. Per informazioni sui valori che potete impostare per questi parametri, vedete la classe Slider nella Guida di riferimento di ActionScript 3.0 per Flash Professional .

Nell'esempio seguente viene creata un'istanza Slider per consentire all'utente di esprimere il proprio livello di soddisfazione per un evento ipotetico. L'utente sposta il componente Slider verso destra o verso sinistra per indicare un livello di soddisfazione maggiore o minore.

1. Create un nuovo documento Flash (ActionScript 3.0).

2. Trascinate un componente Label dal pannello Componenti al centro dello stage.

   • Assegnate all'istanza il nome valueLabel .

   • Assegnate il valore 0 percent al parametro text .

3. Trascinate un componente Slider dal pannello Componenti e posizionatelo al centro sotto value_lbl .

   • Assegnate all'istanza il nome aSlider .

   • Assegnate il valore 200 per la larghezza (W:).

   • Assegnate il valore 10 per l'altezza (H:).

   • Assegnate il valore 100 al parametro maximum .

   • Assegnate il valore 10 ai parametri snapInterval e tickInterval .

4. Trascinate un'altra istanza del componente Label dal pannello Libreria e posizionatela al centro sotto aSlider .

   • Assegnate all'istanza il nome promptLabel .

   • Assegnate il valore 250 per la larghezza (W:).

   • Assegnate il valore 22 per l'altezza (H:).

   • Inserite Indicare il proprio livello di soddisfazione per il parametro text .

5. Aprite il pannello Azioni, selezionate il fotogramma 1 nella linea temporale principale, quindi immettete il codice ActionScript seguente:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Selezionare Controllo > Prova filmato.

   In questo esempio, quando spostate la casella di scorrimento da un intervallo all'altro, un listener dell'evento SliderEvent.CHANGE aggiorna la proprietà text di valueLabel per visualizzare la percentuale corrispondente alla posizione della casella di scorrimento.

Nell'esempio seguente viene creato un componente mediante ActionScript. Viene scaricata l'immagine di un fiore e il componente Slider viene usato per consentire all'utente di applicare un effetto di dissolvenza o di rendere più brillante l'immagine mediante la modifica della proprietà alpha che corrisponde al valore del componente.

1. Create un nuovo documento Flash (ActionScript 3.0).

2. Trascinate i componenti Label e Slider dal pannello Componenti al pannello Libreria del documento corrente.

   In questo modo, i componenti vengono aggiunti alla libreria ma non sono visibili nell'applicazione.

3. Aprite il pannello Azioni, selezionate il fotogramma 1 nella linea temporale principale, quindi inserite il codice seguente per creare e posizionare le istanze dei componenti:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Selezionate Controllo > Prova filmato per eseguire l'applicazione.

5. Spostate la casella di scorrimento del componente a sinistra per sbiadire l'immagine e a destra per renderla più luminosa.