Présentation de l’implémentation

Dans Flash Builder, ouvrez le projet CreateCorrespondence dans la vue Explorateur de package.

Accédez à CreateCorrespondence > src > com.adobe.solutions.cmg.Create Correspondence > presentation

Créez la classe ActionScript (SaveAsDraftActionHandler), qui permet d’étendre la classe com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler. Pour que la nouvelle action soit prise en charge, les deux éléments suivants sont nécessaires :

1. La logique d’activation et de désactivation de la nouvelle action en remplaçant la fonction actionEnabled(extraParams:Object=null):Boolean.

2. Le traitement de l’action lorsque l’utilisateur clique sur le bouton au moment du remplacement de l’implémentation pour la fonction handleAction(extraParams:Object=null):void.

   L’exemple suivant est un modèle d’implémentation de com.adobe.solutions.cmg.ccr.presentation.SaveAsDraftActionHandler qui étend CCRDefaultActionHandler :

   package com.adobe.solutions.cmg.ccr.presentation 
   { 
       import com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler; 
       import com.adobe.icc.external.dc.ExternalApi; 
       import com.adobe.icc.external.dc.InvokeParams; 
       import com.adobe.icc.services.ServiceProvider; 
       import com.adobe.icc.services.submit.ISubmitService; 
       import com.adobe.icc.util.Debug; 
       import com.adobe.icc.util.UrlHelper; 
        
       import flash.net.URLRequest; 
       import flash.net.navigateToURL; 
        
           import mx.controls.Alert; 
       import mx.rpc.events.FaultEvent; 
       import mx.rpc.events.ResultEvent; 
       import mx.utils.ObjectUtil; 
        
       public class SaveAsDraftActionHandler extends CCRDefaultActionHandler 
       { 
           public static const SAVE_AS_DRAFT_ACTION:String = "SaveAsDraft"; 
            
           public function SaveAsDraftActionHandler() 
           { 
               super(); 
               var htmlUrl:String = ExternalApi.getInstance().htmlGetUrl(); 
               Debug.info("invoke url: " + htmlUrl); 
               invokeParams = new InvokeParams(htmlUrl); 
                
           } 
            
           /** 
            * Called when the user clicks an action 
            * @param extraParams additional arguments that may be passed to handler (For future use) 
            * 
            */ 
           override public function handleAction(extraParams:Object=null):void 
           { 
               if(action && action.name == SAVE_AS_DRAFT_ACTION) 
               { 
                   //Additional logic to show popup to ask file save name goes here. 
                   var saveName:String = letterVO.name; 
                   submitLetter(saveName); 
               } 
           } 
            
           [Bindable(event="actionEnabledChange")] 
           /** 
            * Should the action be enabled in toolbar 
            * @param extraParams 
            * @return flag indicating whether the action should be enabled 
            * 
            */ 
           override public function actionEnabled(extraParams:Object=null):Boolean 
           { 
               //Always enable the Action. 
               return true; 
           } 
            
           private function submitLetter(saveName: String):void 
           { 
               var service:ISubmitService = ServiceProvider.getSubmitService(); 
                
               var params:Object = new Object(); 
               if(action.actionConfig) 
                   params = ObjectUtil.copy(action.actionConfig); 
               params["cm_actionName"] = action.name; 
               //Add additional custom params here which is available under <icc:meta> tag. 
               params["cm_saveName"] = saveName; 
                
               var reload:Boolean = false; 
               if(!(invokeParams.letterId) && !(invokeParams.letterName)) 
               { 
                   //If Letter is loaded without letterName or letterId then it must be reload 
                   reload = true; 
               } 
               //Invoke the default letter post process 
               service.submitLetterWithParams(letterVO, letterData, 
                   false, invokeParams.useLatest, reload, null, params).addHandlers 
                   ( 
                       // result handler 
                       function(event:ResultEvent):void 
                       { 
                           var response:Object = event.result as Object; 
                           //Redirect to success page if mentioned 
                           if (response.redirect) 
                           { 
                               // redirect via new window or else the user is prompted to close the DC window before proceeding 
                               if (UrlHelper.isValid(response.redirect)) 
                                   navigateToURL((new URLRequest(response.redirect)), "_blank"); 
                               else 
                                   Debug.error("server returned invalid redirect URL: " + response.redirect); 
                           } 
                                                   Alert.show("Save Successful"); 
                       }, 
                       // fault handler 
                       function(event:FaultEvent):void 
                       { 
                           Debug.error("failed to submit " + letterVO + ":\n\t", event); 
                                                   Alert.show("Save Failed"); 
    
                       } 
                   ); 
                
           } 
       } 
   }

Déclarez une variable privée de type SaveAsDraftActionHandler dans le fichier CreateCorrespondence > src > com.adobe.solutions.cmg.Create Correspondence > presentation > CCRApplication.as. Cette variable permet de s’assurer que la nouvelle classe est compilée dans Flash Builder.

private var saveActionHandler:SaveAsDraftActionHandler;

Régénérez et redéployez le modèle de solution pour afficher les changements. Pour plus d’informations sur la régénération et le redéploiement, voir Génération et déploiement du modèle de solution.