Utilisation de la liste d’affichage

Vous pouvez ajouter un objet à un objet DisplayObjectContainer en appelant la méthode addChild() ou addChildAt() du conteneur. Dans le cas de la scène, vous pouvez également ajouter un objet à sa liste d’affichage lors de la programmation en le créant ou, dans le cas des composants, en le faisant glisser sur la scène depuis le panneau Composants. Pour ajouter un objet à un conteneur à l’aide d’ActionScript, commencez par créer une occurrence de celui-ci en appelant son constructeur à l’aide de l’opérateur new , puis la méthode add Child() ou addChildAt() pour le placer sur la scène et dans la liste d’affichage. La méthode addChild() place l’objet à la position suivante dans la liste d’affichage, tandis que la méthode addChildAt() spécifie la position à laquelle l’objet doit être ajouté. Si vous spécifiez une position déjà occupée, l’objet qui se trouve à cette position, et ceux des positions de niveau supérieur, sont décalés d’une position vers le haut. La propriété numChildren d’un objet DisplayObjectContainer contient le nombre d’objets d’affichage inclus dans celui-ci. Vous pouvez extraire un objet de la liste d’affichage en appelant la méthode getChildAt() et en spécifiant sa position, ou si vous connaissez le nom de l’objet, en appelant la méthode getChildByName() .

L’exemple suivant affiche les noms et positions de trois composants dans la liste d’affichage. Commencez par faire glisser les composants NumericStepper, Button et ComboBox sur la scène de manière à ce qu’ils se chevauchent et affectez-leur les noms d’occurrence aNs , aButton et aCb . Ajoutez ensuite le code suivant dans le panneau Actions, sur l’image 1 du scénario :

var i:int = 0; 
while(i < numChildren) { 
    trace(getChildAt(i).name + " is at position: " + i++); 
}

Les lignes suivantes doivent s’afficher dans le panneau Sortie :

aNs is at position: 0 
aButton is at position: 1 
aCb is at position: 2

Vous pouvez modifier la position d’un objet dans la liste d’affichage, ainsi que sa profondeur d’affichage, en appelant la méthode addChildAt() et en spécifiant le nom d’un objet et la position où vous voulez le placer en tant que paramètres de la méthode. Par exemple, ajoutez le code suivant à l’exemple précédent de manière à placer le composant NumericStepper sur le dessus et répétez la boucle pour afficher les nouvelles positions des composants dans la liste d’affichage :

this.addChildAt(aNs, numChildren - 1); 
i = 0; 
while(i < numChildren) { 
    trace(getChildAt(i).name + " is at position: " + i++); 
}

Les lignes suivantes doivent s’afficher dans le panneau Sortie :

aNs is at position: 0 
aButton is at position: 1 
aCb is at position: 2 
aButton is at position: 0 
aCb is at position: 1 
aNs is at position: 2

Le composant NumericStepper doit également s’afficher devant les autres composants à l’écran.

Notez que numChildren est le nombre d’objets (de 1à n ) dans la liste d’affichage tandis que la première position de la liste est 0. Par conséquent, si la liste contient trois objets, la position d’index du troisième objet est 2. Cela signifie que vous pouvez référencer la dernière position de la liste d’affichage, ou l’objet du dessus en termes de profondeur d’affichage, en tant que numChildren - 1 .

Vous pouvez supprimer un composant d’un conteneur d’objets d’affichage et de sa liste d’affichage à l’aide des méthodes removeChild() et removeChildAt() . L’exemple suivant place trois composants Button l’un devant l’autre sur la scène et ajoute un écouteur d’événements pour chacun d’entre eux. Lorsque vous cliquez sur chaque composant Button, le gestionnaire d’événements le supprime de la liste d’affichage et de la scène.

1. Créez un document de fichier Flash (ActionScript 3.0).

2. Faites glisser un composant Button du panneau Composants vers le panneau Bibliothèque.

3. Ouvrez le panneau Actions, sélectionnez l’image 1 dans le scénario principal et ajoutez le code suivant :

   import fl.controls.Button; 
    
   var i:int = 0; 
   while(i++ < 3) { 
       makeButton(i); 
   } 
   function removeButton(event:MouseEvent):void { 
       removeChildAt(numChildren -1); 
   } 
   function makeButton(num) { 
       var aButton:Button = new Button(); 
       aButton.name = "Button" + num; 
       aButton.label = aButton.name; 
       aButton.move(200, 200); 
       addChild(aButton); 
       aButton.addEventListener(MouseEvent.CLICK, removeButton); 
   }

   Pour obtenir une description détaillée de la liste d’affichage, voir le chapitre « Programmation de l’affichage » du manuel Programmation avec ActionScript 3.0 .