Utilisation du composant Slider

Lorsqu’une occurrence du composant Slider a le focus, les touches suivantes permettent de la contrôler :

Pour plus d’informations sur le contrôle du focus, voir l’interface IFocusManager et la classe FocusManager dans le Guide de référence d’ActionScript 3.0 pour Flash Professional et Utilisation de FocusManager .

L’aperçu en direct des occurrences de Slider reflète les modifications apportées aux paramètres dans l’Inspecteur des propriétés ou l’Inspecteur des composants pendant la programmation.

Dans l’Inspecteur des propriétés ou l’Inspecteur des composants, vous pouvez définir les paramètres de création suivants pour chaque occurrence du composant Slider : direction , liveDragging , maximum , minimum , snapInterval , tickInterval et value . A chacun de ces paramètres correspond une propriété ActionScript du même nom. Pour plus d’informations sur les valeurs gérées de ces paramètres, voir la classe Slider dans le Guide de référence d’ActionScript 3.0 pour Flash Professional .

L’exemple suivant crée une occurrence du composant Slider afin de permettre à l’utilisateur d’exprimer son degré de satisfaction à l’égard d’un événement hypothétique. L’utilisateur tire le curseur vers la gauche ou vers la droite pour indiquer un niveau de satisfaction plus ou moins élevé.

1. Créez un document de fichier Flash (ActionScript 3.0).

2. Faites glisser un composant Label du panneau Composants vers le centre de la scène.

   • Nommez cette occurrence valueLabel .

   • Attribuez la valeur 0 percent au paramètre text .

3. Faites glisser un composant Slider du panneau Composants et centrez-le sous value_lbl .

   • Nommez cette occurrence aSlider .

   • Attribuez-lui une largeur (W:) de 200 .

   • Attribuez-lui une hauteur (H:) de 10 .

   • Attribuez une valeur de 100 au paramètre maximum .

   • Attribuez une valeur de 10 aux paramètres snapInterval et tickInterval .

4. Faites glisser une autre occurrence de Label du panneau Bibliothèque et centrez-la sous aSlider.

   • Nommez cette occurrence promptLabel .

   • Attribuez-lui une largeur (W:) de 250.

   • Attribuez-lui une hauteur (H:) de 22.

   • Entrez Veuillez indiquer votre niveau de satisfaction comme valeur du paramètre text .

5. Ouvrez le panneau Actions, sélectionnez l’image 1 dans le scénario principal et entrez le code ActionScript suivant :

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Choisissez Contrôle > Tester l’animation.

   Dans cet exemple, à mesure que vous déplacez le curseur d’un intervalle vers un autre, un écouteur de l’événement SliderEvent.CHANGE met à jour la propriété text de valueLabel afin d’afficher le pourcentage correspondant à la position du curseur.

L’exemple suivant crée un composant Slider à l’aide d’ActionScript. Cet exemple télécharge l’image d’une fleur et utilise le composant Slider pour permettre à l’utilisateur de rendre l’image plus pâle ou plus vive en modifiant sa propriété alpha en fonction de la valeur du composant Slider.

1. Créez un document de fichier Flash (ActionScript 3.0).

2. Faites glisser le composant Label et le composant Slider du panneau Composants vers le panneau Bibliothèque du document en cours.

   Cette opération permet d’ajouter les composants à la bibliothèque, mais elle ne permet pas de les rendre visibles dans l’application.

3. Ouvrez le panneau Actions, sélectionnez l’image 1 dans le scénario principal et entrez le code suivant pour créer et positionner les occurrences de composant :

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Sélectionnez Contrôle > Tester l’animation pour exécuter l’application.

5. Déplacez le curseur du composant Slider vers la gauche pour rendre l’image pâle et vers la droite pour la rendre plus vive.