Métodos para utilizar expresiones regulares con cadenas

El método test() de la clase RegExp comprueba simplemente la cadena suministrada para ver si contiene una coincidencia para la expresión regular, como se indica en el siguiente ejemplo:

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

El método exec() de la clase RegExp comprueba la cadena suministrada para detectar una coincidencia con la expresión regular y devuelve un conjunto con lo siguiente:

• La subcadena coincidente

• La subcadena detecta grupos entre paréntesis en la expresión regular

El conjunto también incluye una propiedad index, que indica la posición del índice del inicio de la subcadena coincidente.

Por ejemplo, observe el siguiente código:

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

El método exec() se utiliza varias veces para detectar varias subcadenas cuando se establece el indicador g (global) para la expresión regular:

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

Los siguientes métodos de la clase String toman como parámetros expresiones regulares: match(), replace(), search() y split(). Para más información sobre estos métodos, consulte Búsqueda de patrones en cadenas y sustitución de subcadenas