Personalización del componente FLVPlaybackCaptioning

Para empezar a utilizar rápidamente el componente FLVPlaybackCaptioning, se puede optar por utilizar los valores predeterminados de FLVPlaybackCaptioning, que colocan la subtitulación directamente sobre el componente FLVPlayback. Es posible personalizar el componente FLVPlaybackCaptioning para desactivar la subtitulación del vídeo.

El código siguiente muestra cómo crear dinámicamente un objeto FLVPlayback con el conmutador de subtitulación:

  1. Coloque el componente FLVPlayback en el escenario en la posición 0,0 y proporcione el nombre de instancia player .

  2. Coloque el componente FLVPlaybackCaptioning en el escenario en la posición 0,0 y asígnele el nombre de instancia captioning .

  3. Coloque el componente CaptionButton en el escenario.

  4. En el siguiente ejemplo de código, establezca la variable testVideoPath:String en un archivo FLV (mediante una ruta relativa o absoluta).

    Nota: el ejemplo de código establece la variable testVideoPath en una muestra de vídeo Flash, caption_video.flv . Cambie esta variable por la ruta del componente de vídeo de subtitulación al que está añadiendo un componente de botón de texto.

  5. En el siguiente ejemplo de código, establezca la variable testCaptioningPath:String en un archivo XML de texto temporizado adecuado (utilizando una ruta relativa o absoluta).

    Nota: el ejemplo de código establece la variable testCaptioningPath en el archivo XML de texto temporizado caption_video.xml . Cambie esta variable por la ruta del archivo XML de texto temporizado que contiene textos para el vídeo.

  6. Guarde el siguiente código como FLVPlaybackCaptioningExample.as en el mismo directorio que el archivo FLA.

  7. Establezca DocumentClass del archivo FLA en FLVPlaybackCaptioningExample. 

    package 
{ 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import fl.video.FLVPlayback; 
    import fl.video.FLVPlaybackCaptioning; 
     
    public class FLVPlaybackCaptioningExample extends Sprite { 
 
        private var testVideoPath:String = "http://www.helpexamples.com/flash/video/caption_video.flv"; 
        private var testCaptioningPath:String = "http://www.helpexamples.com/flash/video/caption_video.xml"; 
         
        public function FLVPlaybackCaptioningExample() { 
            player.source = testVideoPath; 
            player.skin = "SkinOverAllNoCaption.swf"; 
            player.skinBackgroundColor = 0x666666; 
            player.skinBackgroundAlpha = 0.5; 
 
            captioning.flvPlayback = player; 
            captioning.source = testCaptioningPath; 
            captioning.autoLayout = false;  
            captioning.addEventListener("captionChange",onCaptionChange); 
        } 
        private function onCaptionChange(e:*):void { 
            var tf:* = e.target.captionTarget; 
            var player:FLVPlayback = e.target.flvPlayback; 
 
            // move the caption below the video 
            tf.y = 210;  
        } 
    } 
}

    Para obtener más información sobre todos los parámetros de FLVPlaybackCaptioning, consulte la Referencia de ActionScript 3.0 para Flash Professional .