TileListData  - AS3 Flash

package 
{
    import fl.controls.TileList;
    import fl.controls.listClasses.ImageCell;
    import fl.controls.listClasses.TileListData;
    import fl.data.DataProvider;
    import fl.events.ListEvent;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;    
    
    public class TileListDataExample extends Sprite
    {
        var sourceClasses:Array = [ RedBox, GreenBox, BlueBox ];
        var myTileList:TileList;
        var tf:TextField;

        public function TileListDataExample() {
            createList();

            tf = new TextField();
            tf.x = 10;
            tf.y = 10;
            tf.autoSize = TextFieldAutoSize.LEFT;
            addChild(tf);
        }
        private function createList():void {
            myTileList = new TileList();
            myTileList.move(10,40);
            myTileList.addEventListener(ListEvent.ITEM_CLICK,itemSelected);
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            for(i=0; i<42; i++) {
                dp.addItem( { label:"Item " + i, source:getRandomImageCellSource() } );
            }
            myTileList.dataProvider = dp;
            myTileList.rowCount = 3;
            myTileList.columnCount = 7;
            
            addChild(myTileList);
        }
        private function itemSelected(e:ListEvent):void {
            var renderer:ImageCell = myTileList.itemToCellRenderer(e.item) as ImageCell;
            var listData:TileListData = renderer.listData as TileListData;

            tf.text = "You have clicked an item that uses " + listData.source + " for a source.";
        }
        private function getRandomImageCellSource():Class {
            return sourceClasses[Math.floor(Math.random()*sourceClasses.length)];
        }
    }
}

import flash.display.Sprite;

class RedBox extends Sprite {
    public function RedBox() {
        graphics.beginFill(0x990000);
        graphics.drawRect(0,0,100,100);
    }
}
class GreenBox extends Sprite {
    public function GreenBox() {
        graphics.beginFill(0x009900);
        graphics.drawRect(0,0,100,100);
    }
}    
class BlueBox extends Sprite {
    public function BlueBox() {
        graphics.beginFill(0x000099);
        graphics.drawRect(0,0,100,100);
    }
}