Übersicht über die Implementierung

Öffnen Sie in Flash Builder das CreateCorrespondence-Projekt in der Ansicht Paket-Explorer.

Navigieren Sie zu CreateCorrespondence > src > com.adobe.solutions.cmg.Create Correspondence > presentation.

Erstellen Sie eine ActionScript-Klasse, z. B. SaveAsDraftActionHandler, die die Klasse com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler erweitert. Damit die neu hinzugefügte Aktion unterstützt wird, sind die folgenden zwei Punkte erforderlich:

1. Die Logik für das Aktivieren/Deaktivieren der neu hinzugefügten Aktion, indem die Funktion actionEnabled(extraParams:Object=null):Boolean überschrieben wird

2. Die Verarbeitung der Aktion, wenn ein Benutzer auf die Schaltfläche klickt, indem die Implementierung für function handleAction(extraParams:Object=null):void überschrieben wird

   Das folgende Beispiel veranschaulicht die Implementierung von com.adobe.solutions.cmg.ccr.presentation.SaveAsDraftActionHandler, die den CCRDefaultActionHandler erweitert:

   package com.adobe.solutions.cmg.ccr.presentation 
   { 
       import com.adobe.acm.solutions.ccr.domain.extensions.CCRDefaultActionHandler; 
       import com.adobe.icc.external.dc.ExternalApi; 
       import com.adobe.icc.external.dc.InvokeParams; 
       import com.adobe.icc.services.ServiceProvider; 
       import com.adobe.icc.services.submit.ISubmitService; 
       import com.adobe.icc.util.Debug; 
       import com.adobe.icc.util.UrlHelper; 
        
       import flash.net.URLRequest; 
       import flash.net.navigateToURL; 
        
           import mx.controls.Alert; 
       import mx.rpc.events.FaultEvent; 
       import mx.rpc.events.ResultEvent; 
       import mx.utils.ObjectUtil; 
        
       public class SaveAsDraftActionHandler extends CCRDefaultActionHandler 
       { 
           public static const SAVE_AS_DRAFT_ACTION:String = "SaveAsDraft"; 
            
           public function SaveAsDraftActionHandler() 
           { 
               super(); 
               var htmlUrl:String = ExternalApi.getInstance().htmlGetUrl(); 
               Debug.info("invoke url: " + htmlUrl); 
               invokeParams = new InvokeParams(htmlUrl); 
                
           } 
            
           /** 
            * Called when the user clicks an action 
            * @param extraParams additional arguments that may be passed to handler (For future use) 
            * 
            */ 
           override public function handleAction(extraParams:Object=null):void 
           { 
               if(action && action.name == SAVE_AS_DRAFT_ACTION) 
               { 
                   //Additional logic to show popup to ask file save name goes here. 
                   var saveName:String = letterVO.name; 
                   submitLetter(saveName); 
               } 
           } 
            
           [Bindable(event="actionEnabledChange")] 
           /** 
            * Should the action be enabled in toolbar 
            * @param extraParams 
            * @return flag indicating whether the action should be enabled 
            * 
            */ 
           override public function actionEnabled(extraParams:Object=null):Boolean 
           { 
               //Always enable the Action. 
               return true; 
           } 
            
           private function submitLetter(saveName: String):void 
           { 
               var service:ISubmitService = ServiceProvider.getSubmitService(); 
                
               var params:Object = new Object(); 
               if(action.actionConfig) 
                   params = ObjectUtil.copy(action.actionConfig); 
               params["cm_actionName"] = action.name; 
               //Add additional custom params here which is available under <icc:meta> tag. 
               params["cm_saveName"] = saveName; 
                
               var reload:Boolean = false; 
               if(!(invokeParams.letterId) && !(invokeParams.letterName)) 
               { 
                   //If Letter is loaded without letterName or letterId then it must be reload 
                   reload = true; 
               } 
               //Invoke the default letter post process 
               service.submitLetterWithParams(letterVO, letterData, 
                   false, invokeParams.useLatest, reload, null, params).addHandlers 
                   ( 
                       // result handler 
                       function(event:ResultEvent):void 
                       { 
                           var response:Object = event.result as Object; 
                           //Redirect to success page if mentioned 
                           if (response.redirect) 
                           { 
                               // redirect via new window or else the user is prompted to close the DC window before proceeding 
                               if (UrlHelper.isValid(response.redirect)) 
                                   navigateToURL((new URLRequest(response.redirect)), "_blank"); 
                               else 
                                   Debug.error("server returned invalid redirect URL: " + response.redirect); 
                           } 
                                                   Alert.show("Save Successful"); 
                       }, 
                       // fault handler 
                       function(event:FaultEvent):void 
                       { 
                           Debug.error("failed to submit " + letterVO + ":\n\t", event); 
                                                   Alert.show("Save Failed"); 
    
                       } 
                   ); 
                
           } 
       } 
   }

Deklarieren Sie in der Datei CreateCorrespondence > src > com.adobe.solutions.cmg.Create Correspondence > presentation > CCRApplication.as eine private Variable des Typs „SaveAsDraftActionHandler“. Mit dieser Variable wird sichergestellt, dass die neue Klasse in Flash Builder kompiliert wird.

private var saveActionHandler:SaveAsDraftActionHandler;

Erstellen Sie zum Anzeigen der Änderungen die Lösungsvorlage neu und stellen Sie sie erneut bereit. Informationen zum erneuten Erstellen und Bereitstellen finden Sie unter Lösungsvorlage erstellen und bereitstellen.