Indizierte Arrays

Array- oder Vector-Instanzen können mit mehreren Verfahren erstellt werden. Die Techniken zur Erstellung der einzelnen Array-Typen unterscheiden sich jedoch etwas.

Am einfachsten können Sie einem indizierten Array ein Element hinzufügen, indem Sie den Array-Zugriffsoperator ( [] ) verwenden. Um den Wert eines Elements in einem indizierten Array festzulegen, verwenden Sie den Namen des Array- oder Vector-Objekts und die Indexnummer auf der linken Seite einer Zuweisungsanweisung:

songTitles[5] = "Happy Birthday";

Wenn im Array- oder Vector-Objekt noch kein Element an dieser Indexposition vorhanden ist, wird die Indexposition erstellt und der Wert wird an dieser Position gespeichert. Ist bereits ein Wert an dieser Indexposition vorhanden, wird der vorhandene Wert durch den neuen Wert ersetzt.

Mithilfe eines Array-Objekts können Sie an jeder Indexposition ein Element erstellen. Dagegen ist es mit einem Vector-Objekt nur möglich, eine vorhandene Indexposition oder der nächsten verfügbaren Indexposition einen Wert zuzuweisen. Die nächste verfügbare Indexposition entspricht der length -Eigenschaft des Vector-Objekts. Die sicherste Methode, einem Vector-Objekt ein neues Element hinzuzufügen, wird im folgenden Codebeispiel veranschaulicht:

myVector[myVector.length] = valueToAdd;

Mithilfe von drei Methoden der Array- und Vector-Klassen – push() , unshift() und splice() – können Sie Elemente in ein indiziertes Array einfügen. Mit der push() -Methode werden ein oder mehrere Elemente am Ende eines Arrays angehängt. Mit anderen Worten, das letzte mithilfe der push() -Methode in das Array eingefügte Element weist die höchste Indexnummer auf. Mit der unshift() -Methode werden ein oder mehrere Elemente am Anfang eines Arrays eingefügt, und zwar immer bei Indexposition 0. Mit der splice() -Methode wird eine beliebige Anzahl von Elementen an einer bestimmten Indexposition in einem Array eingefügt.

Im folgenden Beispiel werden alle drei Methoden veranschaulicht. Ein Array namens planets wird erstellt, um die Namen der Planeten in der Reihenfolge ihrer Nähe zur Sonne zu speichern. Als Erstes wird die push() -Methode aufgerufen, um das erste Element, Mars , hinzuzufügen. Dann wird die unshift() -Methode aufgerufen, um das Element Mercury (Merkur) am Anfang des Arrays einzufügen. Schließlich wird die splice() -Methode aufgerufen, um die Elemente Venus und Earth (Erde) nach Mercury , jedoch vor Mars einzufügen. Mit dem ersten an splice() übergebenen Argument, der Ganzzahl 1, wird angegeben, dass die Elemente an der Indexposition 1 eingefügt werden sollen. Mit dem zweiten an splice() gesendeten Argument, der Ganzzahl 0, wird angegeben, dass keine Elemente gelöscht werden sollen. Bei dem dritten und vierten Argument, Venus und Earth , die an splice() gesendet werden, handelt es sich um die einzufügenden Elemente.

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

Mit den Methoden push() und unshift() wird jeweils eine vorzeichenlose Ganzzahl zurückgegeben, die die Länge des geänderten Arrays angibt. Wenn die splice() -Methode zum Einfügen von Elementen verwendet wird, wird ein leeres Array zurückgegeben. Dies ist auf die Vielseitigkeit der splice() -Methode zurückzuführen. Sie können die splice() -Methode nicht nur zum Einfügen von Elementen in ein Array, sondern auch zum Entfernen von Elementen aus einem Array verwenden. Wenn die splice() -Methode zum Entfernen von Elementen verwendet wird, wird ein Array mit den entfernten Elementen zurückgegeben.

Am einfachsten können Sie den Wert eines Elements aus einem indizierten Array abrufen, indem Sie den Array-Zugriffsoperator ( [] ) verwenden. Um den Wert eines Elements in einem indizierten Array abzurufen, verwenden Sie den Namen des Array- oder Vector-Objekts und die Indexnummer auf der rechten Seite einer Zuweisungsanweisung:

var myFavoriteSong:String = songTitles[3];

Es kann versucht werden, den Wert von einem Array- oder Vector-Objekt mithilfe eines Indexes abzurufen, an dem keine Elemente existieren. In diesem Fall gibt ein Array-Objekt den Wert „undefined“ zurück und ein Vector-Objekt gibt eine RangeError-Ausnahme aus.

Mit drei Methoden der Array- und Vector-Klassen – pop() , shift() und splice() – können Sie Elemente entfernen. Mit der pop() -Methode wird ein Element am Ende eines Arrays entfernt. Dies bedeutet, dass das Element mit der höchsten Indexnummer entfernt wird. Mit der shift() -Methode wird ein Element am Anfang eines Arrays entfernt. Dies bedeutet, dass immer das Element an Indexposition 0 entfernt wird. Mit der splice() -Methode, die auch zum Einfügen von Elementen verwendet werden kann, wird eine beliebige Anzahl von Elementen entfernt, angefangen bei der Indexposition, die durch das erste an die Methode gesendete Argument angegeben ist.

Im folgenden Beispiel werden Elemente mithilfe aller drei Methoden aus einer Array-Instanz entfernt. Ein Array namens oceans (Ozeane) wird erstellt. In diesem Array sollen die Namen großer Gewässer gespeichert werden. Einige der Elemente im Array sind Seen und keine Meere und sollen daher entfernt werden.

Mithilfe der splice() -Methode werden zunächst die Elemente Aral und Superior entfernt sowie die Elemente Atlantic und Indian eingefügt. Mit dem ersten an splice() gesendeten Argument, der Ganzzahl 2, wird angegeben, dass der Vorgang beim dritten Element in der Liste starten soll, an Indexposition 2. Mit dem zweiten Argument, 2, wird angegeben, dass zwei Elemente entfernt werden sollen. Die restlichen Argumente, Atlantic und Indian , sind die Werte, die bei Indexposition 2 eingefügt werden sollen.

Mithilfe der pop() -Methode wird dann das letzte Element, Huron , im Array entfernt. Schließlich wird mithilfe der shift() -Methode das erste Element, Victoria , im Array entfernt.

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

Bei den Methoden pop() und shift() werden jeweils die entfernten Elemente zurückgegeben. Bei einer Array-Instanz hat der Rückgabewert den Object-Datentyp, da Arrays Werte eines beliebigen Datentyps enthalten können. Bei einer Vector-Instanz entspricht der Datentyp des Rückgabewertes dem Vector-Basistyp. Die splice() -Methode gibt ein Array oder einen Vektor mit den Werten zurück, die entfernt wurden. Sie können das oceans -Array so ändern, dass das zurückgegebene Array durch Aufrufen von splice() einer neuen Array-Variablen zugewiesen wird, wie im folgenden Beispiel gezeigt:

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

Möglicherweise stoßen Sie auf Code, bei dem der delete -Operator für ein Array-Objektelement verwendet wird. Mit dem delete -Operator wird der Wert eines Array-Elements auf undefined gesetzt, das Element wird jedoch nicht aus dem Array entfernt. Im folgenden Codebeispiel wird der delete -Operator für das dritte Element des oceans -Arrays verwendet, die Länge des Arrays bleibt jedoch unverändert bei 5:

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

Sie können ein Array oder einen Vektor mithilfe der length -Eigenschaft kürzen. Wenn Sie die length -Eigenschaft eines indizierten Arrays auf eine geringere Länge als die derzeitige Array-Länge einstellen, wird das Array gekürzt. Dabei werden die Elemente an den Indexpositionen entfernt, die den neuen Wert für length minus 1 übersteigen. Wenn das oceans -Array beispielsweise so sortiert ist, dass alle gültigen Einträge sich am Anfang des Arrays befinden, können Sie die length -Eigenschaft verwenden, um alle Einträge am Ende des Arrays zu entfernen, wie im folgenden Codebeispiel gezeigt:

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

Mithilfe von drei Methoden – reverse() , sort() und sortOn() – können Sie die Reihenfolge in einem indizierten Array ändern, indem Sie die Elemente sortieren oder die bestehende Reihenfolge umkehren. Mit allen diesen Methoden wird ein vorhandenes Array geändert. In der folgenden Tabelle werden diese Methoden sowie ihr Verhalten bei Array- und Vector-Objekten zusammengefasst:

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

Mit vier Methoden der Array- und Vector-Klassen – concat() , join() , slice() und toString() – werden Daten im Array abgefragt, jedoch keine Änderungen am Array vorgenommen. Bei den Methoden concat() und slice() werden jeweils neue Arrays zurückgegeben, während bei den Methoden join() und toString() jeweils Strings zurückgegeben werden. Bei der concat() -Methode wird als Argument ein neues Array oder eine Liste mit Elementen mit dem vorhandenen Array verbunden, um ein neues Array zu erstellen. Die slice() -Methode verfügt über zwei Parameter mit den treffenden Bezeichnungen startIndex und endIndex und gibt ein neues Array zurück, das eine Kopie eines Teils der Elemente aus dem vorhandenen Array enthält. Der Teil beginnt mit dem Element bei startIndex und endet mit dem Element vor endIndex . Noch einmal zur Klarstellung: Das Element bei endIndex ist nicht Bestandteil des Rückgabewerts.

Im folgenden Beispiel werden mithilfe von concat() und slice() neue Arrays mit Elementen aus anderen Arrays erstellt:

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

Mithilfe der Methoden join() und toString() können Sie ein Array abfragen und den entsprechenden Inhalt in einem String zurückgeben. Wenn bei der join() -Methode keine Parameter verwendet werden, sind beide Methoden identisch, d. h., sie geben einen String mit einer durch Kommas getrennten Liste aller Elemente im Array zurück. Im Gegensatz zur toString() -Methode kann bei der join() -Methode der delimiter -Parameter übergeben werden, über den Sie das Symbol auswählen können, das im zurückgegebenen String als Trennzeichen zwischen den einzelnen Elementen verwendet wird.

Im folgenden Beispiel wird ein Array namens rivers (Flüsse) erstellt, für das join() und toString() aufgerufen werden, um die Werte im Array als String zurückzugeben. Die toString() -Methode wird verwendet, damit durch Kommas getrennte Werte zurückgegeben werden ( riverCSV ). Die join() -Methode wird verwendet, damit Werte zurückgegeben werden, die durch + -Zeichen getrennt sind.

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

Beachten Sie, dass verschachtelte Array- oder Vector-Instanzen bei der join() -Methode immer mit durch Kommas getrennten Werten zurückgegeben werden, unabhängig davon, welches Trennzeichen für die Hauptelemente im Array angegeben wird, wie im folgenden Beispiel gezeigt:

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e