Methoden für das Verwenden regulärer Ausdrücke bei Strings

Flash Player 9 und höher, Adobe AIR 1.0 und höher

Die RegExp-Klasse umfasst zwei Methoden: exec() und test().

Zusätzlich zu den Methoden exec() und test() der RegExp-Klasse enthält die String-Klasse die folgenden Methoden, mit denen Sie reguläre Ausdrücke in Strings suchen können: match(), replace(), search(), and splice().

test()-Methode

Mit der test()-Methode der RegExp-Klasse wird überprüft, ob der angegebene String eine Übereinstimmung mit dem regulären Ausdruck enthält, wie im folgenden Beispiel dargestellt:

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

exec()-Methode

Die exec()-Methode der RegExp-Klasse überprüft den angegebenen String auf eine Übereinstimmung mit dem regulären Ausdruck und gibt ein Array mit den folgenden Elementen zurück:

  • übereinstimmender Teilstring

  • übereinstimmende Teilstrings aller in Klammern eingeschlossenen Gruppen im regulären Ausdruck

Das Array enthält zudem eine index-Eigenschaft, mit der die Indexposition am Anfang des übereinstimmenden Teilstrings angegeben wird.

Betrachten Sie den folgenden Beispielcode:

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

Führen Sie die exec()-Methode mehrfach aus, um mehrere Teilstrings zu suchen, wenn im regulären Ausdruck das g-Flag (global) gesetzt ist:

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

String-Methoden mit RegExp-Parametern

Bei den folgenden Methoden der String-Klasse können reguläre Ausdrücke als Parameter verwendet werden: match(), replace(), search() und split(). Weitere Informationen zu diesen Methoden finden Sie unter Suchen von Mustern in Strings und Ersetzen von Teilstrings.