Zusammenstellen und Transformieren von XML-Objekten

Flash Player 9 und höher, Adobe AIR 1.0 und höher

Mithilfe der prependChild()-Methode oder der appendChild()-Methode können Sie eine Eigenschaft am Anfang oder am Ende der Eigenschaftenliste eines XML-Objekts einfügen, wie im folgenden Beispiel dargestellt ist:

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Verwenden Sie wie folgt die insertChildBefore()-Methode oder die insertChildAfter()-Methode, um eine Eigenschaft vor oder nach einer bestimmten anderen Eigenschaft einzufügen:

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Wie im folgenden Beispiel veranschaulicht wird, können Sie auch die geschweiften Klammern ({ und }) als Operator verwenden, um beim Erstellen von XML-Objekten Daten als Verweis (aus anderen Variablen) zu übergeben:

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Mithilfe des =-Operators können Sie einem XML-Objekt Eigenschaften und Attribute zuweisen:

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Auf diese Weise wird dem XML-Objekt x Folgendes zugewiesen:

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Mit den Operatoren „+“ und „+=“ lassen sich XMLList-Objekte verketten:

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Auf diese Weise wird dem XMLList-Objekt xList Folgendes zugewiesen:

<a>test1</a> 
<b>test2</b> 
<c>test3</c>