Movieclip-Beispiel: RuntimeAssetsExplorer

Damit über den Explorer ordnungsgemäß auf eine SWF-Bibliothek zugegriffen werden kann, muss die Struktur der Laufzeit-Elementbibliotheken formalisiert werden. Dies erfolgt durch Erstellen einer Schnittstelle. Diese ähnelt einer Klasse, da sie einen Entwurf der Methoden enthält und die zu erwartende Struktur festlegt. Im Gegensatz zu einer Klasse wird jedoch nicht der Methodenrumpf angegeben. Über die Schnittstelle kann eine Verbindung zwischen der Laufzeitbibliothek und dem Explorer hergestellt werden. Jede SWF-Datei mit Laufzeitelementen, die im Browser geladen wird, implementiert diese Schnittstelle. Weitere Informationen zu Schnittstellen und ihren Verwendungsmöglichkeiten finden Sie im Abschnitt zu Schnittstellen im ActionScript 3.0 – Arbeitshandbuch .

Die RuntimeLibrary-Schnittstelle ist sehr einfach. Es wird lediglich eine Funktion benötigt, über die im Explorer ein Array mit Klassenpfaden verfügbar ist, damit die Symbole exportiert werden und in der Laufzeitbibliothek zur Verfügung stehen. Zu diesem Zweck enthält die Schnittstelle eine einzige Methode: getAssets() .

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

Mit der Definition der RuntimeLibrary-Schnittstelle können mehrere SWF-Dateien für die Elementbibliothek erstellt werden, die in eine andere SWF-Datei geladen werden können. Die Erstellung einer SWF-Datei für die Elementbibliothek umfasst vier Aufgaben:

• Erstellen einer Klasse für die SWF-Datei der Elementbibliothek

• Erstellen von Klassen für einzelne Elemente in der Bibliothek

• Erstellen der eigentlichen grafischen Elemente

• Verknüpfen der grafischen Elemente mit Klassen und Veröffentlichen der SWF-Datei für die Bibliothek

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

In einem letzten Schritt muss die Benutzeroberfläche für den Elemente-Explorer erstellt werden. In diesem Beispiel ist der Pfad für die Laufzeitbibliothek in der Variablen ASSETS_PATH hartkodiert (fest vorgegeben). Alternativ können Sie mithilfe der FileReference-Klasse beispielsweise eine Benutzeroberfläche erstellen, über die nach einer bestimmten SWF-Datei auf der Festplatte gesucht wird.

Nach dem erfolgreichen Laden der Laufzeitbibliothek wird die runtimeAssetsLoadComplete() -Methode in Flash Player aufgerufen:

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

In dieser Methode wird die geladene SWF-Datei durch die Variable „rl“ dargestellt. Im Code wird die getAssets() -Methode der geladenen SWF-Datei aufgerufen; damit wird die Liste der verfügbaren Elemente abgerufen. Anhand dieser Elemente wird durch Aufrufen der populateDropDown() -Methode eine ComboBox-Komponente mit der Liste verfügbarer Elemente gefüllt. Mit dieser Methode wird wiederum der vollständige Klassenpfad jedes Elements gespeichert. Durch Klicken auf die Schaltfläche „Add“ der Benutzeroberfläche wird die addAsset() -Methode ausgelöst:

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

Dadurch werden der Klassenpfad des derzeit in der ComboBox-Komponente ( assetNameCbo.selectedItem.data ) ausgewählten Elements sowie mithilfe der getDefinitionByName() -Funktion (aus dem flash.utils-Paket) ein Verweis auf die Klasse des Elements abgerufen, sodass eine neue Instanz des Elements erstellt wird.