Laden von Videodateien

Flash Player 9 und höher, Adobe AIR 1.0 und höher

Der Vorgang zum Laden von Videos mithilfe der NetStream- und NetConnection-Klasse umfasst mehrere Schritte. Da sich dies bewährt hat, wird empfohlen, die Schritte zum Hinzufügen des Video-Objekts zur Anzeigeliste, zum Hinzufügen des NetStream-Objekts zur Video-Instanz und zum Aufrufen der play() -Methode des NetStream-Objekts in der angegebenen Reihenfolge auszuführen:

  1. NetConnection-Objekt erstellen. Wenn Sie eine Verbindung zu einer lokalen Videodatei oder zu einer Datei, die keinen Server wie zum Beispiel Adobes Flash Media Server 2 verwendet, herstellen, übergeben Sie null an die connect() -Methode, um die Videodateien von einer HTTP-Adresse oder einem lokalen Laufwerk abzuspielen. Wenn Sie eine Verbindung zu einem Server herstellen, setzen Sie den Parameter auf den URI der Anwendung auf dem Server, die die Videodatei enthält. 

    var nc:NetConnection = new NetConnection(); 
nc.connect(null);

  2. Erstellen Sie ein neues Video-Objekt, das das Video anzeigt, und fügen Sie es zur Anzeigeliste der Bühne hinzu wie im folgenden Codefragment: 

    var vid:Video = new Video(); 
addChild(vid);

  3. Erstellen Sie ein NetStream-Objekt und übergeben Sie dabei das NetConnection-Objekt als ein Argument an den Konstruktor. Das folgende Codefragment verbindet ein NetStream-Objekt mit der NetConnection-Instanz und richtet die Ereignisprozeduren für den Stream ein: 

    var ns:NetStream = new NetStream(nc); 
ns.addEventListener(NetStatusEvent.NET_STATUS,netStatusHandler); 
ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 
 
function netStatusHandler(event:NetStatusEvent):void 
{ 
    // handle netStatus events, described later 
} 
 
function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
    // ignore error 
}

  4. Fügen Sie das NetStream-Objekt zum Video-Objekt hinzu, indem Sie die attachNetStream() -Methode des Video-Objekts verwenden wie im folgenden Codefragment: 

    vid.attachNetStream(ns);

  5. Rufen Sie die play() -Methode des NetStream-Objekts mit der URL der Videodatei als Argument auf, um die Videowiedergabe zu starten. Mit dem folgenden Codefragment wird die Videodatei „video.mp4“ in demselben Verzeichnis wie die SWF-Datei geladen und abgespielt: 

    ns.play("video.mp4");