Taskleisten-Symbol in AIR

Sie können dem standardmäßigen Dock-Menü Befehle hinzufügen, indem Sie ein NativeMenu-Objekt, das die Befehle enthält, erstellen und der NativeApplication.nativeApplication.icon.menu -Eigenschaft zuweisen. Elemente im Menü werden über den standardmäßigen Dock-Symbolmenüelementen angezeigt.

Durch Aufrufen der NativeApplication.nativeApplication.icon.bounce() -Methode können Sie das Dock-Symbol zum Springen veranlassen. Wenn Sie den bounce() priority -Parameter auf „informational“ einstellen, springt das Symbol einmal. Wenn Sie es auf „critical“ einstellen, springt das Symbol, bis der Benutzer die Anwendung aktiviert. Konstanten für den priority -Parameter sind in der NotificationType-Klasse definiert:

Wird auf das Dock-Symbol geklickt, löst das NativeApplication-Objekt ein invoke -Ereignis aus. Falls die Anwendung nicht ausgeführt wird, wird sie vom System gestartet. Andernfalls wird das invoke -Ereignis an die ausgeführte Anwendungsinstanz gesendet.

Sie können dem Infobereich-Symbol ein Menü hinzufügen, indem Sie ein NativeMenu-Objekt erstellen und es der NativeApplication.nativeApplication.icon.menu -Eigenschaft zuweisen (vom Betriebssystem wird kein Standardmenü bereitgestellt). Klicken Sie mit der rechten Maustaste auf das Symbol, um das Infobereich-Symbolmenü aufzurufen.

Fügen Sie einem Symbol eine QuickInfo hinzu, indem Sie die tooltip-Eigenschaft wie folgt einstellen:

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

Das SystemTrayIcon-Objekt, auf das die NativeApplication.nativeApplication.icon-Eigenschaft verweist, löst ein „ScreenMouseEvent“ für click -, mouseDown -, mouseUp -, rightClick -, rightMouseDown - und rightMouseUp -Ereignisse aus. Mithilfe dieser Ereignisse und einem Symbolmenü können Sie Benutzern die Interaktion mit Ihrer Anwendung ermöglichen, wenn sie keine sichtbaren Fenster hat.

Im folgenden Beispiel wird eine AIR-Anwendung erstellt, die über ein Infobereich-Symbol, aber keine sichtbaren Fenster verfügt. (Die visible -Eigenschaft der Anwendung darf im Anwendungsdeskriptor nicht auf true gesetzt werden, andernfalls ist das Fenster beim Starten der Anwendung sichtbar.)

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

Wenn sich ein Fenster im Hintergrund befindet, können Sie den Benutzer informieren, dass im Zusammenhang mit diesem Fenster ein Ereignis aufgetreten ist. Unter Mac OS X können Sie den Benutzer durch ein Springen des Anwendungssymbols im Dock informieren (siehe Springen des Dock-Symbols ). Unter Windows und Linux können Sie die Fensterschaltfläche in der Taskleiste hervorheben, indem Sie die notifyUser() -Methode der NativeWindow-Instanz aufrufen. Mit dem an die Methode übergebenen type -Parameter wird die Dringlichkeit der Benachrichtigung bestimmt:

• NotificationType.CRITICAL : Das Fenster-Symbol blinkt, bis der Benutzer das Fenster in den Vordergrund stellt.

• NotificationType.INFORMATIONAL : Das Fenster-Symbol wird durch Änderung der Farbe hervorgehoben.

  Hinweis: Unter Linux werden nur informative Benachrichtigungen unterstützt. Wenn Sie einen Wert des einen oder anderen Typs an die notifyUser() -Funktion übergeben, wird derselbe Effekt erzielt.

  Mit der folgenden Anweisung wird die Schaltfläche eines Fensters in der Taskleiste hervorgehoben:

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  Wird die NativeWindow.notifyUser() -Methode unter einem Betriebssystem aufgerufen, dass die Benachrichtigung auf Fensterebene nicht unterstützt, hat dieser Aufruf keine Wirkung. Mithilfe der NativeWindow.supportsNotification -Eigenschaft können Sie feststellen, ob diese Art der Benachrichtigung unterstützt wird.

Unter Windows werden Fenster, die mit den Typen utility oder lightweight erstellt wurden, nicht in der Taskleiste angezeigt. Unsichtbare Fenster werden ebenfalls nicht in der Taskleiste angezeigt.

Da das erste Fenster zwangsläufig den Typ normal aufweist, müssen Sie dieses erste Fenster schließen oder unsichtbar belassen, wenn Sie eine Anwendung erstellen möchten, deren Fenster nicht in der Taskleiste angezeigt werden. Um alle Fenster in der Anwendung zu schließen, ohne die Anwendung zu beenden, müssen Sie die autoExit -Eigenschaft des NativeApplication-Objekts auf false einstellen, bevor Sie das letzte Fenster schließen. Um zu verhindern, dass das erste Fenster jemals sichtbar wird, fügen Sie <visible>false</visible> zum <initalWindow> -Element der Anwendungsdeskriptordatei hinzu. Außerdem sollten Sie die visible -Eigenschaft nicht auf true einstellen oder die activate() -Methode des Fensters aufrufen.

Stellen Sie in neuen, von der Anwendung geöffneten Fenstern die type -Eigenschaft des NativeWindowInitOption-Objekts, das an den Fensterkonstruktor übergeben wird, auf NativeWindowType.UTILITY oder NativeWindowType.LIGHTWEIGHT ein.

Unter Mac OS X werden minimierte Fenster in der Dock-Taskleiste angezeigt. Sie können die Anzeige des minimierten Symbols vermeiden, indem Sie das Fenster nicht minimieren, sondern ausblenden. Im folgenden Beispiel wird auf ein nativeWindowDisplayState -Änderungsereignis gewartet; es wird abgebrochen, falls das Fenster minimiert wird. Stattdessen stellt die Prozedur die visible -Eigenschaft des Fensters auf false ein:

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

Wird ein Fenster im Mac OS X-Dock minimiert angezeigt, wenn Sie die visible -Eigenschaft auf false einstellen, dann wird das Dock-Symbol nicht entfernt. Ein Benutzer kann nach wie vor auf das Symbol klicken, um das Fenster wieder anzuzeigen.